エクセルで、文字列から文字を取り出す自動マクロを教えてください。

質問

住所の入った、エクセルのファイルを頂くのですが、Ｃ２せるから、Ｃ５０程度のセルまでに
「〒１２３－４５６７兵庫県○○市○○３－４－５」と
一つのセルに入っています。
これをマクロで、Ｃ列の前に、一列挿入して、自動的に、〒番号の部分を切り取って、貼り付けるという
操作を、マクロでくみたいのです。
データは毎週貰うのですが、件数は５件～５０件程度までと幅はあります。データは２行目から連続して並んでいます。「列を挿入して」「LEFT関数で取り出すという関数をＣ２に入力」「数式をデータが終わるところまでコピー」「元のデータから〒番号を消去」というマクロを組みたいのです。お手数ですが、初心者にでも分かるようにマクロを教えて頂けませんでしょうか？

回答No.3

KenKen_SP

こんにちは。KenKen_SP です。

＞元のデータから〒番号を消去...

と考えるとちょっと難しくなるので、

「元データの先頭から9文字、およびそれ以降を別々の場所に書き出して、
最後に元データを削除する」

とした方が処理としては楽だと思います。

また、郵便番号部が半角とか全角で統一されているなら、マクロを使わず
とも [データ]-[区切り位置]-[固定長...] で分解することもできますね。

Sub Sample()

　　Dim lngROWNUM As Long
　　Dim i　　　　 As Long
　　Dim Sh　　　　As Worksheet
　　Dim lngANSWER As Long

　　'対象シート定義 ※要書き換え
　　Set Sh = ThisWorkbook.Sheets("Sheet1")

　　With Sh
　　　　'最終行番号取得
　　　　lngROWNUM = .Cells(2, "C").End(xlDown).Row
　　　　'画面描写の停止
　　　　'Application.ScreenUpdating = False
　　　　'確認のため２列を元データの後ろへ挿入
　　　　.Columns("D:E").Insert
　　End With

　　'最終行までループ
　　For i = 2 To lngROWNUM
　　　　With Sh.Cells(i, "C")
　　　　　　'先頭に〒番号があるか？
　　　　　　If StrConv(.Value, vbNarrow) Like "〒###-####*" Then
　　　　　　　　'C列の1つ横D列に9文字抜き出したものを記入
　　　　　　　　.Offset(0, 1).Value = Left$(.Value, 9)
　　　　　　　　'C列の2つ横E列に残りを記入
　　　　　　　　.Offset(0, 2).Value = Mid$(.Value, 10)
　　　　　　End If
　　　　End With
　　Next i

　　'D:E列の列幅調整
　　Sh.Columns("D:E").AutoFit

　　'画面描写の停止解除
　　Application.ScreenUpdating = True
　　'削除確認
　　lngANSWER = MsgBox( _
　　　　Prompt:="郵便番号と住所を分離しました。" & vbCrLf & vbCrLf & _
　　　　　　　　"C列の分離前データを削除しますか？", _
　　　　Buttons:=vbQuestion Or vbYesNo Or vbDefaultButton2, _
　　　　Title:="削除確認")
　　If lngANSWER = vbYes Then
　　　　'元データのC列削除
　　　　ActiveSheet.Columns("C").Delete
　　End If

　　Set Sh = Nothing

End Sub

補足

>'対象シート定義 ※要書き換え
>　　Set Sh = ThisWorkbook.Sheets("Sheet1")
ここはどのように書き換えたらよろしいでしょうか？
一つのブックに「20051127」「20051102」などの
名前のシートが並んでいます。

>　　'最終行までループ
>　　For i = 2 To lngROWNUM
>　　　　With Sh.Cells(i, "C")
>　　　　　　'先頭に〒番号があるか？
>　　　　　　If StrConv(.Value, vbNarrow) Like "〒###-####*" Then
ここの「〒###-###*」の箇所ですが
〒番号は全角で入っています。

また住所の入っている列はＣ列だったりＤ列だったり
しているようです。
対象となる列のＣ２セルなりＤ２セルなりにカーソルが
有る状態にしてからのマクロの実行という操作に変更できますでしょうか？

お手数ですが、よろしくお願いします。