グリッドについて，エクセルのアドインについて

質問

• グリッド上で文字を直接入力する方法や、エクセルのようにグリッド上をクリックしたらテキスト入力モードになる方法について教えてください。
• 垂直スクロールバーの幅を得る方法を教えてください。スクロールバーを表示させるとグリッドの右端が切れてしまうため、幅を調整する必要があります。
• ＶＢからエクセルのソルバーアドインを使用することはできますか？複雑な回帰分析を行いたいので、エクセルのアドインをそのまま活用したいです。

回答No.2

TAGOSAKU7

１番についてです。
DataGrid or Excel どちらでしょう？
ちなみにフレキシブルグリッドはグリッドのマージ（結合）や色を付けたりするのに適してます。
DataGridはエクセルのような直接グリッド内を編集できますが、マージは無理で、色付けの設定はグリッド単位では指定できません。
Excelは説明を省略します。

全てのパターンの使用例は勘弁してください・・・(^^;)
とりあえず、何がしたいのかが知りたいです。
ちなみにエクセルでの機能を使用する時点で、VBAのみの処理にした方がいいような気もします。。。

３番についてです。
処理としては
１．エクセル起動
２．エクセルブックを開く
３．エクセルブックにデータを出力
３．エクセルブック内の関数を呼ぶ（エクセル内にマクロを用意）
４．解析データを得る（サンプルではメッセージボックスをコメント化してます）
といった要領です。

解析は得意ではないので、エクセル側の関数「subAnalysis」は自分で編集してくださいね。
エクセルのヘルプのキーワードで「solver」と打ち込むと使用方法が出ています。

VBのプロジェクトの参照設定で
[Microsoft Excel x.0 Object Liblary]
を指定することが必要です。
それ以外に、エクセルのブックを一つ用意して(サンプルではC:\Test.xls)VBA画面でツールの参照設定から
C:\Program Files\Microsoft Office\Office\Library\Solver\SOLVER.XLA
を指定しておく必要があります。これはソルバーの関数ライブラリなので、あらかじめ用意するブックに関連付けしておかなければなりません。ですので、参照設定をして保存してください。

エクセルブック内の関数ではデータ範囲が固定で書いてありますが、データ範囲の取得方法などがわからない場合は、別の質問で行ってください。本題から外れます。
解析データの出力先をシート２の先頭にしておくと、解析データを取得しやすいかもしれませんね。

-----VB側-----
Option Explicit

Sub Main()
　　Dim xlApp　 As Excel.Application
　　Dim xlBook　As Excel.Workbook
　　Dim xlSheet As Excel.Worksheet

　　'エクセル起動
　　Set xlApp = New Excel.Application
　　'ワークブックを開く
　　xlApp.Workbooks.Open ("c:\test.xls")
　　Set xlBook = xlApp.ActiveWorkbook

　　'シートを指定
　　Set xlSheet = xlBook.Worksheets(1)
　　xlSheet.Select

　　'データをセットする
　　Call xlsDataSet(xlSheet)

　　'表示する
　　xlApp.Visible = True

　　'解析を行う（エクセル任意）
　　Call xlApp.Run("subAnalysis")

　　'解析した値を読み込む(解析値の出力によってここは変わります)
　　'''''Call MsgBox(xlSheet.Cells(x, x).Value)

　　'閉じる時の「保存しますか」を表示させない
　　xlBook.Saved = True

　　Set xlSheet = Nothing
　　Set xlBook = Nothing
　　Set xlApp = Nothing
End Sub

'受けたシートにデータを出力（テスト用のダミーデータ）
Sub xlsDataSet(xlSheet As Excel.Worksheet)
　　Dim i　 As Long
　　Dim j　 As Long

　　For i = 1 To 30
　　　　For j = 1 To 30
　　　　　　xlSheet.Cells(i, j) = i & j
　　　　Next j
　　Next i
End Sub

-----EXCEL_VBA側-----
Sub subAnalysis()
　　Worksheets(1).Activate
　　With Worksheets(1)
　　　　Call SolverReset
　　　　Call SolverOptions(Precision:=0.001)
　　　　SolverOK SetCell:=Range("F4"), MaxMinVal:=1, ByChange:=Range("C4:E6")
　　　　Call SolverAdd(CellRef:=Range("F4:F6"), Relation:=1, FormulaText:=100)
　　　　Call SolverAdd(CellRef:=Range("C4:E6"), Relation:=3, FormulaText:=0)
　　　　Call SolverAdd(CellRef:=Range("C4:E6"), Relation:=4)
　　　　Call SolverSolve(UserFinish:=False)
　　　　Call SolverSave(SaveArea:=Range("A33"))
　　End With
End Sub

補足

再び早速のご回答，大変ありがとうございました。

> とりあえず、何がしたいのかが知りたいです。

大変申し訳ございませんでした。ご説明いたします。

今私は，大学の研究室で光学実験を行うためのプログラムを作成しております。具体的には，ステッピングモーター，シャッター，オシロスコープ等をGPIBで操作，また試料温度をのRS-232Cで制御し，入力された手順に従って測定，データ収集，データ解析を行うプログラムを作成しております。

プログラムの流れは大ざっぱに，
　１．測定手順の入力（ここで，入力用にグリッドを使用）
　２．自動測定，データ収集
　３．データの解析（ここで，エクセルの回帰分析を使用）
という感じで，この１の部分で，測定条件を各グリッド内に直接書かせようと考え，３の部分でエクセルに回帰分析を行わせようと考えました。なお回帰分析とは，n個の測定点 (xn,yn) が式 y = A * {sin(x - B)}^2 に合うように非線形最小二乗法を行って A と B を求めるという内容です。この部分は自分ではアルゴリズムが分からないため，エクセルに頼ろうと考えました。

> １番についてです。
> DataGrid or Excel どちらでしょう？

逆にお伺いする形になってしまい，申し訳ありません。グリッドはデータの直接入力機能と，コピー＆ペースト程度の編集機能さえあれば構わないのですが，その程度なら DataGrid でも十分でしょうか？　どちらかと言えば動作が軽い方がいいのですが…。

> ３番についてです。
> 処理としては
> １．エクセル起動
> ２．エクセルブックを開く
> ３．エクセルブックにデータを出力
> ３．エクセルブック内の関数を呼ぶ（エクセル内にマクロを用意）
> ４．解析データを得る（サンプルではメッセージボックスをコメント化してます）
> といった要領です。

ご指示の通り，やってみたいと思います。
ご丁寧に，大変ありがとうございました。