Pasteで増やしたフレーム内のボタン操作（続）

質問

• UserForm1を起動させた際、Frame1が5個コピペされます。各Frame内のボタンを押下するとそのFrame内のTextBox３つが消去されるようにできました。
• 新規Excelファイルで.xlsm形式で保存した後、まったく同じ内容のフォームとVBAを記述したところ、一番右側のTextBoxしか消去されない問題が発生しました。一度全てのExcelファイルを保存して閉じた後、再度開いたら正常動作が確認できました。
• PC1とPC2のExcelバージョンにより、VBAの動作に差がある可能性があります。VBAの書き方に誤りがあるかどうか確認してください。

回答No.7

kkkkkm

TextBoxが5個、ComboBoxが15個で試してみたコードです。時間があれば試してみて下さい。

Private mCmdButton() As Class1
'↑必ず先頭に

'大外フレームの外側にコマンドボタンを作成の時
Private Sub ClearCommandButton_Click()
Dim i As Long

For i = 1 To (5 + 1) * 5
Me.Controls("TextBox" & i).Value = ""
Next
For i = 1 To (5 + 1) * 15
Me.Controls("ComboBox" & i).Value = ""
Next

End Sub

Private Sub UserForm_Initialize()
Dim j As Long
Dim i As Long
Dim mBoxNameF(5) As String
Dim mComboNameF(15) As String

Me.Frame1.SetFocus
Me.大外フレーム.Copy
For i = 1 To 5
mBoxNameF(i) = "TextBox" & i
Next
For i = 1 To 15
mComboNameF(i) = "ComboBox" & i
Next
Call Make_Event(1, mBoxNameF(), mComboNameF())

For j = 1 To 5
Me.大外フレーム.Paste
With Me.Controls("Frame" & j + 1)
.Caption = "Frame" & j + 1
.Left = Me.Frame1.Left
.Top = Me.Frame1.Top + Me.Frame1.Height * j
End With
Me.Controls("TextBox" & j * 5 + 1).Value = Me.Controls("TextBox" & j * 5 + 1).Name
Me.Controls("TextBox" & j * 5 + 2).Value = Me.Controls("TextBox" & j * 5 + 2).Name
Me.Controls("TextBox" & j * 5 + 3).Value = Me.Controls("TextBox" & j * 3 + 3).Name
Me.Controls("TextBox" & j * 5 + 4).Value = Me.Controls("TextBox" & j * 5 + 4).Name
Me.Controls("TextBox" & j * 5 + 5).Value = Me.Controls("TextBox" & j * 5 + 5).Name
Me.Controls("CommandButton" & j + 1).Caption = Me.Controls("CommandButton" & j + 1).Name
For i = 1 To 5
mBoxNameF(i) = "TextBox" & j * 5 + i
Next
For i = 1 To 15
mComboNameF(i) = "ComboBox" & j * 15 + i
Next
Call Make_Event(j + 1, mBoxNameF(), mComboNameF())
Next
Me.大外フレーム.ScrollHeight = Me.大外フレーム.ScrollHeight + Me.Frame1.Height * j 'j=(Past回数+1)

For i = 1 To (5 + 1) * 15
Me.Controls("ComboBox" & i).Value = Me.Controls("ComboBox" & i).Name
Next

End Sub

Function Make_Event(ByVal i As Long, ByRef mBoxNameX() As String, ByRef mComboNameX() As String)
ReDim Preserve mCmdButton(i)
Set mCmdButton(i) = New Class1
mCmdButton(i).SetCtrl Me("CommandButton" & i), mBoxNameX(), mComboNameX()
End Function

クラス

Private WithEvents Target As MSForms.CommandButton
Private mBoxName(5) As String
Private mComboName(15) As String

'新しくイベントを作成し、変数の値をセット
Public Sub SetCtrl(New_Ctrl As MSForms.CommandButton, ByRef mBoxNameX() As String, ByRef mComboNameX() As String)
Dim i As Long

Set Target = New_Ctrl
For i = 1 To 5
mBoxName(i) = mBoxNameX(i)
Next
For i = 1 To 15
mComboName(i) = mComboNameX(i)
Next
End Sub

Private Sub Target_Click()
Dim i As Long

For i = 1 To 5
UserForm1.Controls(mBoxName(i)).Value = ""
Next
For i = 1 To 15
UserForm1.Controls(mComboName(i)).Value = ""
Next

End Sub

お礼

kkkkkm様、お知らせいただきましたTextBox5個、ComboBox15個のパターンですが期待通りの動きをしてくれました。有難うございます。
現在はテストファイルなので明日、本番ファイルに適用してみようと思います。大外フレームリセットについても活用させていただきます。

ところで1つ（本当は1つではありませんが）疑問な箇所がございましたので宜しければご教示ください。
今回のNo7以前はComboBoxの.nameは15個分書いていた（TextBox分と合わせて20行）のですが
No7でお知らせいただいたスクリプトには下記の通り
For i = 1 To (5 + 1) * 15
Me.Controls("ComboBox" & i).Value = Me.Controls("ComboBox" & i).Name
Next
となっており、非常にスッキリしてて良いと感じました。
しかしFor文のTo以降の　(5+1)*15　となっている理由がどうしても分からないのです。90と書くのと何か違いがあるのでしょうか？またFrame数が増えますとComboBox数も比例して増え、90または(5+1)*15を超えてしまうと思うのですが、なんのために　(5+1)*15　となっているのか後学のためにお知らせいただけますと幸いです。

お礼メッセージなのに質問してしまいまして申し訳ございませんが、お手すきの際にもう少しお付き合いの程、宜しくお願い致します。

～No7以前に書いていた15行～
Me.Controls("ComboBox" & j * 15 + 1).Value = Me.Controls("ComboBox" & j * 15 + 1).Name
・・・中略・・・
Me.Controls("ComboBox" & j * 15 + 15).Value = Me.Controls("ComboBox" & j * 15 + 15).Name