set文でエラーがでます

質問

以下のコードで
　実行エラー''9'「インデックスが有効範囲にありません。」が出る原因と対処方法を教えてください。

Set ws = Worksheets(FileName2)

FilewName2はローカルウインドウでは問題なく表示されています。

Sub 括弧及び括弧内文字削除()
'
'ダイアログでターゲットファイル（ｔｘｔ)を選択（読み込み) ---------------
Dim FileName As Variant
Dim FileName2 As String
Dim FilePath As String
Dim fso As New FileSystemObject

FileName = Application.GetOpenFilename(FileFilter:="Txtファイル,*.txt)
If FileName = False Then
Exit Sub
End If

'ターゲットファイルの拡張子無しのファイル名を取得
FileName2 = fso.GetBaseName(FileName)

'ターゲットファイルのパス取得
FilePath = Replace(FileName, Dir(FileName), "")
Workbooks.Open FileName

'括弧内文字列削除(括弧も含む）--------------------------------
Dim RegExp As Object
Dim Cell As Range
Dim tr As Long

'DATAを処理する行数
tr = Cells(Rows.Count, "A").End(xlUp).Row

Set RegExp = CreateObject("VBScript.RegExp")
RegExp.Global = True
RegExp.Pattern = "[（(].*[)）]"
'
Application.ScreenUpdating = False

Dim buf
Dim i As Long

With Range("A1", Cells(Rows.Count, "A").End(xlUp))
buf = .Value
For i = 1 To UBound(buf)
buf(i, 1) = RegExp.Replace(buf(i, 1), "")
Next
.Value = buf
End With

' Range(Cells(1, 1), Cells(tr, 1)).Select
' For Each Cell In Selection
' Cell = RegExp.Replace(Cell, "")
' Next

'新規に修正ファイルをテキストファイルに書き出す -------------

Dim ws As Worksheet
Set ws = Worksheets(FileName2)

Dim datFile As String
datFile = FilePath & FileName2 & "_mod.srt"

Open datFile For Output As #1

For i = 1 To tr
Print #1, ws.Cells(i, "A").Value
Next

Close #1
Application.ScreenUpdating = True

MsgBox datFile & "に書き出しました" & vbCrLf & _
"処理が終了したのでEXCELを閉じて終了です。"

'// Excelを終了する
Application.Quit

ActiveWorkbook.Close SaveChanges:=False
ThisWorkbook.Close SaveChanges:=False

End Sub

回答No.6

kkkkkm

> 最初のアプローチでブックを作成する事にしたのが悪かったみたいで

そんなに悪くは無いと思います一行ずつセルに読み込むよりOpenだけでいいのでコードは短くなりますし。

> 「括弧削除.xlsm」のみで処理する方が良さそうだと考えるようになりました。

ファイルをbufに読み込んでそのまま RegExp.してしまうのが早いとは思います。
コードも短くなると思います。

こんな感じでいけそうです。

Sub Test()
Dim FileName As Variant
Dim buf As String
Dim fso As New FileSystemObject
Dim RegExp As Object
Dim FileName2 As String
Dim FilePath As String
Dim datFile As String

FileName = Application.GetOpenFilename(FileFilter:="Txtファイル/Srtファイル,*.txt;*.srt")
If FileName = False Then
Exit Sub
End If

With fso.GetFile(FileName).OpenAsTextStream
buf = .ReadAll
.Close
End With

Set RegExp = CreateObject("VBScript.RegExp")
RegExp.Global = True
RegExp.Pattern = "[（(].*[)）]"
buf = RegExp.Replace(buf, "")

FileName2 = fso.GetBaseName(FileName)

FilePath = Replace(FileName, Dir(FileName), "")

datFile = FilePath & FileName2 & "_mod.srt"
With fso.OpenTextFile(datFile, 2, True)
.Write buf
.Close
End With

End Sub

お礼

他のブックを作成せずにテキストファイルをセルに書き出さずに一気に処理する方法をありがとうございます。

bufにに一気に読み込み、書き出す事が中々理解できずに時間がかかりました。

（ネットの情報を読み込んで何とかコードが少しは理解できるまでなりました。）

＞テキストファイルを直接操作する場合VBAでなくてもVBSとかVB.NETでやってしまえばいいような気もします。

ここで言う「VBS」とは、VBScriptの事ですよね。
「VB.NET」を含めて利用したことが無いので門外漢でほとんどEXCELのVBAで処理しています。
と言うか、昔、BASIC言語を少しやっただけの古い人間でそれ以外はむずかしそうで手が出せそうにありません。

Option Explicit

Sub 括弧及び括弧内の文字列削除_2()

Dim fso As Object
Set fso = CreateObject("Scripting.FileSystemObject")

Dim FileName As Variant
'処理するテキストファイルを指定 (text,srt)
FileName = Application.GetOpenFilename(FileFilter:="Txtファイル/Srtファイル,*.txt;*.srt")
If FileName = False Then
Exit Sub
End If

Dim buf As String
'テキストファイル内の全ての文字を読み込みモード(1)でデータを一気に読み込む
With fso.GetFile(FileName).OpenAsTextStream(1)
buf = .ReadAll
.Close
End With

Dim RegExp As Object
Set RegExp = CreateObject("VBScript.RegExp")

'buf文字列中から括弧内の文字列（含む括弧）を削除して　---> bufに書き戻す
RegExp.Global = True
RegExp.Pattern = "[（(].*[)）]"
buf = RegExp.Replace(buf, "")

Dim FileName2 As String
Dim FilePath As String
FileName2 = fso.GetBaseName(FileName)
FilePath = Replace(FileName, Dir(FileName), "")

Dim datFile As String
datFile = FilePath & FileName2 & "_mod.srt"

'テキストファイルを開いて一気に書き込む
' 書き込みモード= 2
' 新たに作成するときは = True
' (書き込み)format = 0 ---> ASCIIファイルで書き出す
With fso.OpenTextFile(datFile, 2, True, 0)
.Write buf 'bufの内容を書き出す
.Close
End With

Set fso = Nothing

End Sub