データベースから取得した値を文字で表示する

質問

office2010　Oracle12C

Oracle12CのデータベースからexcelへデータをもってくるマクロをWEB参照しながら作成しました。
しかしながら、配列構成でひっぱると、”文字列”で表示したい内容が”標準”の書式になってしまいます。
マクロは下記です。

Sub shutoku()
'ADO用のオブジェクト変数の宣言
Dim cn As New ADODB.Connection 'コネクション
Dim rs As New ADODB.Recordset 'レコードセット
Dim rownum As Long
Dim colnum As Integer
Dim jissekiArr()

Application.ScreenUpdating = False
'クリア
Worksheets("Sheet1").Cells.Clear
'dwhへ接続
cn.Open "Provider=OraOLEDB.Oracle;Data Source= dwh ;User ID=dwh;Password=dwh;", "dwh", "dwh"

'ADOレコードセットの生成（全データを返すレコードセットの生成）
'DBから条件で抽出する
rs.Open "select * from TABLE_NAME where CD = 'コード'", cn, adOpenDynamic, adLockOptimistic, adCmdText

'配列の初期化
rsCount = 0
Do Until rs.EOF
rs.MoveNext
rsCount = rsCount + 1
Loop
ReDim jissekiArr(rsCount, rs.Fields.Count)

'データレコードを最初に戻す
rs.MoveFirst

'フィールド名の表示
For colnum = 0 To rs.Fields.Count - 1
jissekiArr(0, colnum) = rs(colnum).Name
Next

'データの表示
rownum = 0
Do Until rs.EOF
For colnum = 0 To rs.Fields.Count - 1

jissekiArr(rownum + 1, colnum) = rs(colnum).Value

Next

rs.MoveNext
rownum = rownum + 1
Loop

'配列をシートに出力する。
Sheets("Sheet1").Select
Range(Cells(1, 1), Cells(rsCount + 1, rs.Fields.Count)) = jissekiArr

'オブジェクトのクローズ
rs.Close
cn.Close

'各種オブジェクトの開放
Set rs = Nothing
Set OraDatabase = Nothing
Set OraSession = Nothing
Erase jissekiArr

End Sub

これだと日時のデータが
20161221151143
の部分が
2016E+13

先頭に0があるコード
0601000
が
601000
の様に表示されてしまいます。

Dim jissekiArr()
の部分を
Dim jissekiArr() as string
とすると、
jissekiArr(rownum + 1, colnum) = rs(colnum).Value
の部分が黄色く表示され、
実行時エラー'94'
Nullの使い方が不正です。
となります。
どうしたら、文字のまま抽出できるか教えて頂きたく。

※貼り付けるシートsheet1を全て文字列にしておいても、標準に変更されてしまいます。

回答No.1

imogasi · ベストアンサー

ＯＲＡＣＬＥから持ってきた数値データ（変数の）前（先頭）にアポストロフィを結合して、シートのセルに代入すれば（代入する前に先頭に’を使たデータ化する）仕舞ではないか。
セルＡ１に0012　　があるとする。（ＯＲＣＬＥ（ＳＱＬ）が小生は使えないので、このようにしてテスト）
エクセルＶＢＡですが
Sub test01()
Cells(2, "A") = "'" & Range("A1 ")
End Sub
を実行する。
普通なら（＝手入力では）１２になるところ
00012
となった。
なおＯＲＡＣＬＥ側での文字列結合は concat関数か、｜｜を使うのだと思う。
何しろ当方は、ＯＲＡＣＬＥのテスト環境がないのでうまく行かなければ後免。
＞どうしたら、文字のまま抽出できるか教えて頂きたく。
エクセル側の数値データ表示の（特徴あるクセ）問題だと思う。

お礼

ありがとうございます。助かりました。

補足

jissekiArr(rownum + 1, colnum) = rs(colnum).Value
の部分を
jissekiArr(rownum + 1, colnum) = "'" & rs(colnum).Value
にすることで、文字列表示出来ました。

回答No.3

bunjii

>これだと日時のデータが
>20161221151143
>の部分が
>2016E+13
日時のデータは"2016/12/21 15:11:43"のように加工してからセルへ代入しないと14ケタの整数になるでしょう。（標準形式では指数表示のため2.01612E+13となる）

>先頭に0があるコード
>0601000
>が
>601000
>の様に表示されてしまいます。
代入するセルの表示形式を"@"（文字列）に指定してから値を代入してみると良いでしょう。

>Dim jissekiArr()
>の部分を
>Dim jissekiArr() as string
>とすると、
配列変数のサイスを固定する必要があるようです。
例：Dim jissekiArr(1000,100) as string

>※貼り付けるシートsheet1を全て文字列にしておいても、標準に変更されてしまいます。
配列変数（jissekiArr）を一挙にSheet1へ代入せずにforループで1セルずつ代入されると解決するかも知れません。（代入の直前で表示形式を文字列に変更する）

回答No.2

tsubu-yuki

列が決まっているなら
取り込む前に数値の表示形式を「文字列」にしてしまうのもあり？
　　Columns("B").NumberFormatLocal = "@"
などのように。

同様、オラクルの環境がないので、
テストはしてません。

補足

Columns("C").NumberFormatLocal = "@"
Columns("AJ").NumberFormatLocal = "@"
Columns("AP").NumberFormatLocal = "@"
Columns("AV").NumberFormatLocal = "@"
Columns("AY").NumberFormatLocal = "@"

'データの表示
の前に上記設定をして、文字列表示出来ました。