GetOpenFilenamのパス指定

質問

Access2000VBAを使用するのが前提です。
「ダイアログを表示してファイルを選択しフォームに表示する」ファンクションがあります。（下記参考モジュール参照ください：excel 9.0 object Libraryを使用してます）
ダイアログを表示した際、指定のフォルダの内容を表示したいのですが、「(1)ChDir」も「(2)SetCurrentDirectory」を使用しても規定フォルダが表示され指定フォルダに移行しません。
何か手段はありますか？ダイアログ自体は問題なく機能してます。

Public Function ふぁいる選択()
Dim myFile As Variant, P
Dim exlDlg As New Excel.Application
P = CurrentProject.Path & "\"
ChDrive "C"
ChDir P '>>>>>>>(1)
Call SetCurrentDirectory(P)　　　'>>>>>>>>(2)
myFile = exlDlg.GetOpenFilename("CSVファイル(*.csv),*契約*.csv")

If (VarType(myFile) = vbBoolean) Or (myFile = "False") Then
ふぁいる選択 = ""
Else
ふぁいる選択 = myFile
End If
End Function

回答No.1

ushi2015 · ベストアンサー

こんにちは
Public Function ふぁいる選択()
　　Dim myFile As Variant, P
　　Dim exlDlg As New Excel.Application
　　Dim defPath As String

　　defPath = exlDlg.DefaultFilePath
　　P = CurrentProject.Path & "\"
　　exlDlg.DefaultFilePath = P
　　exlDlg.Quit
　　Set exlDlg = Nothing
　　Set exlDlg = CreateObject("Excel.Application")
　　myFile = exlDlg.GetOpenFilename("CSVファイル(*.csv),*契約*.csv")

　　If (VarType(myFile) = vbBoolean) Or (myFile = "False") Then
　　　　ふぁいる選択 = ""
　　Else
　　　　ふぁいる選択 = myFile
　　End If
　　exlDlg.DefaultFilePath = defPath
　　exlDlg.Quit
　　Set exlDlg = Nothing

End Function
こんな感じでしょうか？

Access2000って事は、FileDialogは使えないって事ですよね？
Public Function ふぁいる選択()
　　Dim P As String
　　Dim exlDlg As New Excel.Application
　　P = CurrentProject.Path & "\"
　　With exlDlg.FileDialog(1)
　　　　.InitialFileName = P
　　　　.Filters.Clear
　　　　.Filters.Add "CSVファイル", "*.csv"
　　　　.Show

　　　　If .SelectedItems.Count = 0 Then
　　　　　　MsgBox "キャンセルされました。"
　　　　　　ふぁいる選択 = ""
　　　　　　Exit Function
　　　　End If

　　　　ふぁいる選択 = .SelectedItems(1)

　　End With
End Function

お礼

早々にご回答頂きましてありがとうございました。
はい、思い通りの事が出来ました。
本当に感謝です。ありがとうございました！