Excel VBA CSVを文字型で読みたいのです

質問

お世話になります。
Excel2013のVBAでCSVの全項目を文字型として取り込む処理を作ろうとしているのですが、
うまくいきません。 数値項目のゼロが消えてしまいます。
サンプルcsvと、取り込む所だけ抽出したソースを見て頂いて、なんとかなりますでしょうか？
よろしくお願いします。

sub test()
'csvのオープンダイアログ
varFileName = Application.GetOpenFilename(FileFilter:="CSVファイル(*.csv),*.csv", _
Title:="CSV形式(csv形式)の選択")
'ファイル名を取得していなければ終了
If varFileName = False Then Exit Sub

'拡張子除いたファイル名でシート作成

pos = InStrRev(varFileName, "\")
sname = Mid(varFileName, pos + 1) 'フルパスからファイル名抽出

pos = InStrRev(sname, ".") '最後の.位置を抽出
sname = Mid(sname, 1, pos - 1) 'ファイル名から拡張子除去

'本流ブックに新シートを作成し命名
Set WS1 = Worksheets.Add(After:=Worksheets(Worksheets.Count))
WS1.name = sname

'csvをtmpブックで開く(アクティブ周りの処理の関係で位置を注意)
'お形式で全項目文字で取得Ver

Workbooks.OpenText Filename:=varFileName, _
DataType:=xlDelimited, comma:=True, _
fieldinfo:=Array( _
Array(1, 2), Array(2, 2))

end sub

test.csv ----------------------
管理番号　,注文分類　
"0000041836","受注"
"0000041841","受注"
"0000041842","受注"

回答No.2

f272 · ベストアンサー

Workbooks.OpenText Filename:=varFileName, _
DataType:=xlDelimited, comma:=True, _
fieldinfo:=Array( _
Array(1, 2), Array(2, 2))
これを
With ActiveSheet.QueryTables.Add( _
Connection:="TEXT;" & varFileName, _
Destination:=Range("A1"))
.AdjustColumnWidth = False
'.TextFilePlatform = 932
.TextFileCommaDelimiter = True
.TextFileColumnDataTypes = Array(xlTextFormat, xlGeneralFormat)
.Refresh BackgroundQuery:=False
.Delete
End With
これに変更したらどうかな。

お礼

たしか「マクロの記録」でQueryTables.Add()は出てきたのですが、
そのときは、0から新しい仕組みを調べる手間と、リンクがつながったままで
対処法が分からない忌避感で避けていましたが、回答で.Deleteを勉強できました。

今回の環境では拡張子を変えれない為、こちらを採用させて頂く事になりそうです。
お返事ありがとうございました。BAとさせて頂きます。

回答No.1

emsuja

拡張子は CSV でなければいけないのですか？

とりあえず提示された VBA サンプルとファイル名の CSV を TXT と書き換えたらうまく動いたのですが。

お礼

な、なんだこの仕様…
おかげさまで訳の分からないExcelの仕様が
また一つ勉強になりました。

お返事ありがとうございました。