ナビゲーションウインドウにあるすべてのオブジェク

質問

アクセスのVBAで
ナビゲーションウインドウにあるすべてのオブジェクトを取得したいのですが

Sub Sample()
Dim cn As New ADODB.Connection
Dim catx As New ADOX.Catalog
Dim v As Variant
Dim sPath As String

sPath = CurrentProject.FullName

cn.Open "Provider = Microsoft.ACE.OLEDB.12.0;Data Source=" & sPath & ";"
Set catx.ActiveConnection = cn

For Each v In catx.Tables
Debug.Print v.Name
Next

For Each v In catx.Forms
Debug.Print v.Name
Next

For Each v In catx.Procedures
Debug.Print v.Name
Next

cn.Close
Set cn = Nothing
End Sub

だと、.Formsがコンパイルエラーになります。

なので、
For Each v In catx.Forms
Debug.Print v.Name
Next
を抜かして実行すると

*********************
~TMPCLP425901
MSysAccessStorage
MSysAccessXML
MSysACEs
MSysComplexColumns
MSysNameMap
MSysNavPaneGroupCategories
MSysNavPaneGroups
MSysNavPaneGroupToObjects
MSysNavPaneObjectIDs
MSysObjects
MSysQueries
MSysRelationships
MSysResources
*********************
と、
テーブルとクエリの一覧は取得されますが、
Proceduresは取得されません。

私の予想としては
Proceduresはモジュールの一覧だと思ってました。

とりあえずテーブルとクエリは取得できたので
残りのフォーム、レポート、モジュールを取得するにはどうすればいいでしょうか？

オブジェクトブラウザーでCatalogのクラスを見るとフォーム等がありません。

回答No.1

NotFound404 · ベストアンサー

DAO でも構わなければ・・・。

Sub test()
'参照設定 要 Microsoft Office x.xx Access database engine object library
'か
'Microsoft DAO x.x Object Library
Dim db As DAO.Database
Dim tdf As DAO.TableDef
Dim i As Long

Set db = CurrentDb
Debug.Print , "テーブル"
For i = 0 To db.TableDefs.Count - 1
Debug.Print i, db.TableDefs(i).Name
Next

Debug.Print , "クエリー"
For i = 0 To db.QueryDefs.Count - 1
Debug.Print i, db.QueryDefs(i).Name
Next

Debug.Print , "フォーム"
For i = 0 To CurrentProject.AllForms.Count - 1
Debug.Print i, CurrentProject.AllForms(i).Name
Next

Debug.Print , "レポート"
For i = 0 To CurrentProject.AllReports.Count - 1
Debug.Print i, CurrentProject.AllReports(i).Name
Next

Debug.Print , "モジュール"
For i = 0 To CurrentProject.AllModules.Count - 1
Debug.Print i, CurrentProject.AllModules(i).Name
Next

End Sub

お礼

ありがとうございました。