マクロ 2つのブック 条件一致 転記

質問

2つのエクセルブックがあります。

1つがIDデータ表になって、IDと払い出し内容と日付の３つがあります。
もう１つがID管理票で、IDを担当ごとに管理している票です。

IDデータ表のIDとID管理票のIDを一致したら
IDデータ表の払い出し区分の単語を基準に（新規・変更・廃止）

ID管理票.xlsに乗っているIDの横に
払い出し区分の単語の条件で

新規の場合,ID右隣に日付を転記
変更の場合,IDの２つ右隣に日付を転記
廃止の場合,IDの３つ右隣に日付を転記を行いたいのですが

FINDメソッドを使い、行のB列の区分で判定して、日付を書き入れるのと
Offセットでセルの位置を指定するのと「IDデータ表」.xlsの特定の範囲のデータを繰り返す
というアドバイスをもらいましたが
繰り返し処理（ForやLoop）をよく理解していないからだと思います。
どなたかご教示くださいますでしょうか。

下記に簡素でありますが構成状態と
処理の概要と画像添付させて頂きます

IDデータ表.xls

　　 A列　　　 　　　　 B列　　　　　　　C列
1　　ID番号　　　　 払い出し区分　　　日付
2　 110001241　　　 　　新規　　　　　　10/2
3　 120000065　　　 　　変更　　　　　　10/3
4　 190000036　　　 　　廃止　　　　　　10/4
　　　 ↓

以下100行くらい続いています

ID管理票.xls

ID番号の場所がバラバラで
AO列にあったりBC列にあったりしています。
また、ID管理票にすでに日付が入っていることもありますが
それはそのまま上書きで問題ありません。

110001241,　10/2　　　　　　　（新規区分なのでIDの右隣に日付を転記）
120000065,　空白 10/3　　　　 （変更区分なのでIDの右２つ目に日付を転記）
190000036,　空白,空白,10/4　　 (廃止区分なのでIDの右３つ目に日付を転記）

お手数ですがよろしくお願いいたします

回答No.1

keithin · ベストアンサー

順繰り拾って、探して確認して記入する、だけです。

sub macro1()
　dim w0 as worksheet, w1 as worksheet
　dim h as range, Target as range

　set w0 = workbooks("IDデータ表.xls").worksheets("シート名")
　set w1 = workbooks("ID管理表.xls").worksheets("シート名")

’データ表のＡ列を巡回する
　for each h in w0.range("A2:A" & w0.range("A65536").end(xlup).row)
　’管理表から探す
　　set target = w1.cells.find(what:=h.value, lookin:=xlvalues, lookat:=xlwhole)
　’見つけたら処理を行う
　　if not target is nothing then
　　　select case h.offset(0, 1).value
　　　case "新規"
　　　　target.offset(0, 1) = h.offset(0, 2).value
　　　case "変更"
　　　　target.offset(0, 2) = h.offset(0, 2).value
　　　case "廃止"
　　　　target.offset(0, 3) = h.offset(0, 2).value
　　　case else
　　　　'do nothing
　　　end select
　　end if
　next
end sub

＃「新規」や「変更」などが間違いなく記入されてる前提のご相談になってますが、そうでない場合とかも考えます。

お礼

keithin様

拙い説明の中コードを記述して頂きありがとうございます！！
分岐の所をifで条件を分けないと駄目だという固定観念に囚われて
CASEを使う事,全体で検索する方法等、コードを読み解き参考にさせて頂きます！！
ベストアンサーに選ばさせて頂きます

＃「新規」や「変更」などが間違いなく記入されてる前提のご相談になってますが、
そうでない場合とかも考えます。

新規,変更,廃止はシステムからcsv出力するので決まっています・・・が
文言が違った場合　適宜対応させて頂きます。

お忙しい中　ありがとうございました！！！