エクセルマクロ インプットボックスの使い方

質問

エクセル2013です。
マクロの途中で作業者にマウスで列を選択してもらい
その取得した列番号を使って、いろいろ処理を行うマクロを作りました。

Sub　実験（）

Dim マウス選択 As Range
Dim 選択列
Dim 選択月表示
Dim 質問
Dim 最終列
Dim 最終行

最終列 = Cells(8, Columns.Count).End(xlToLeft).Column '8行目の最終列を取得
最終行 = Cells(Rows.Count, 1).End(xlUp).Row 'A列の最終行を取得

On Error GoTo myError
Set マウス選択 = Application.InputBox("編集したい月の列を選択してください", Type:=8)
選択列 = マウス選択.Column
選択月表示 = Cells(8, 選択列).Value

質問 = MsgBox("選択した月は " & 選択月表示 & "　です。いいですか？", vbYesNo)
If 質問 = vbYes Then
MsgBox "処理を行います"
Else
MsgBox "プログラムを中断します"
Exit Sub
End If

---処理内容----

myError:
MsgBox "キャンセルが押されました。プログラム終了します。"

End　Sub

通常列を選択してくれればインプットボックス内には
$V:$V
などと表示されますが

行を選択されると
$35:$35
などと表示され

セルの一部を選択されると
$D$40
などと表示されます。

行やセルを選択してもエラーなく最後まで進みますが選択した場所によっては
とんでもない結果になってしまいます。

基本、列以外を選択したらメッセージボックスでアラームするか
プログラムを停止させたいのですがどのような方法が有りますでしょうか？
よろしくお願いします。

回答No.1

mitarashi · ベストアンサー

こんな感じでいかがでしょうか。ご参考まで。
Sub test()
Dim マウス選択 As Range
Set マウス選択 = Application.InputBox("編集したい月の列を選択してください", Type:=8)
If マウス選択.Columns.Count > 1 Then
MsgBox "1列を選択してね"
Exit Sub
End If
Set マウス選択 = マウス選択.EntireColumn
Debug.Print マウス選択.Address
End Sub

お礼

教えて頂いた内容にて
行を選択した場合は回避できましたが
セルを選択した場合には回避できなかったので
教えていただいたのを改良して
セルを選択しても回避できるようにしてみました。
どうもありがとうございました。

On Error GoTo myError 'INPUT-BOXでキャンセルを選択した時の回避

Set マウス選択 = Application.InputBox("編集したい月の列を選択してください", Type:=8)
If マウス選択.Columns.Count > 1 Then '選択したしたのが列で有り1列であるか確認
MsgBox "選択したのは列ではありません。又は2列以上を選択しています"
MsgBox "プログラムを中断します"
Exit Sub 'プログラム停止
End If

If マウス選択.Rows.Count > 1 Then '選択したのが行の場合の処理
Else
MsgBox "セルを選択しています。1列を選択してください"
MsgBox "プログラムを中断します"
Exit Sub 'プログラム停止
End If

Set マウス選択 = マウス選択.EntireColumn
Debug.Print マウス選択.Address

選択列 = マウス選択.Column 'INPUT-BOXで選択した列を数字に置き換える
選択月表示 = Cells(8, 選択列).Value '選択した列の8行目のセルの値を格納

Call データ更新3

Exit Sub 'エラーが出なかった時のmyErrorの回避用

myError: 'INPUT-BOXでキャンセルを押した時の処理
MsgBox "キャンセルが押されました。プログラム終了します。"
Exit Sub

End Sub

回答No.2

eden3616

セル範囲の行数がエクセルの最大セル数と一致すれば行選択されている
とかで判定したらどうでしょうか？

Sub 判定()
If Range("A:B").Rows.Count <> Rows.Count Then
　MsgBox "列を選択してください"
End If
End Sub

ちなみに以下のコードを実行するとイミディエイトウィンドウでは
× - A1
× - $A$1
○ - A:A
× - 1:1
× - A1:B1000
のように出力されます。

Sub 判定2()
Dim myRng As Variant
myRng = Array("A1", "$A$1", "A:A", "1:1", "A1:B1000")
For i = 0 To UBound(myRng)
　If Range(myRng(i)).Rows.Count = Rows.Count Then
　　Debug.Print "○ - " & myRng(i)
　Else
　　Debug.Print "× - " & myRng(i)
　End If
Next i
End Sub

お礼

ちょっと使いこなすのには
私にはハードルが高い見たいです。
ありがとうございました。