コマンドボタンの色をパレットを表示して選ばせたい

質問

• コマンドボタンを押すと、カラーパレットを表示し、色を選択したらそのボタン自身の色を選択した色に変更するマクロを作る必要があります。
• デザインモードで、コマンドボタンのプロパティ「BackColor」を変更する時に表示されるようなパレットを、マクロで表示し、選択させたタイルの色コードを取得し、そのコマンドボタンの色を変える、という処理になります。
• 可能なら、もうちょっとスマートなやり方があるとよいのですが。

回答No.4

mitarashi

#1～です。しつこくてすみません。ご質問文にあったダミーセルに着色する方法も試してみました。
Application.Dialogs(xlDialogPatterns).Show
の方が良さそうです。ご参考まで。

Private Sub CommandButton1_Click()
Dim workCell As Range
Dim oldColor As Long
Dim noColorFlag As Boolean

Set workCell = ActiveCell
Application.ScreenUpdating = False
If workCell.Interior.Pattern = xlNone Then
noColorFlag = True
Else
oldColor = workCell.Interior.color
End If
'Cellに保護がかかっているとエラーになります。その場合は、
'ActiveCellでなくて、適当な作業セルを指定して下さい。
On Error GoTo errhandle
Application.Dialogs(xlDialogPatterns).Show
' Application.Dialogs(xlDialogColorPalette).Show
Me.CommandButton1.BackColor = workCell.Interior.color
If noColorFlag Then
workCell.Interior.Pattern = xlNone
Else
workCell.Interior.color = oldColor
End If
errhandle:
Application.ScreenUpdating = True
If Err.Number <> 0 Then MsgBox "Error " & CStr(Err.Number) & vbCrLf & Err.Description
End Sub

お礼

なるほど。Excel VBAらしい手法だと思います。勉強になります。
この度は、本当にありがとうございました。