最適な関数式について

質問

添付ファイルのように、関数を入力しました。
パスワード変更日欄が未入力の場合にパスワード有効期限欄に変な表示になってしまいます。
そこで、パスワード変更日欄が空白の場合に、パスワード有効期限欄も空白に表示したいのですが、最適な関数式はないでしょうか？
ご教授のほどよろしくお願いします。

回答No.4

MarcoRossiItaly

No.3 です。連続ですみません。

No.3 の F16 の数式だけ、なぜか短くしてしまいました。そのせいで添付図でも、そこだけ表示されている時刻が異なっていますね。実際は、F4 や F10 と同様に、TIME 関数を加算してもらっても全く問題ありません。

他の箇所は、まずはコピペでもいいので回答どおりに記入してみて、確かにできるということを確認してください。例えば勝手に、「m/d;;」という書式記号から「;;」の部分を削除したりすると、失敗します。

回答No.3

MarcoRossiItaly

画像中の見せたい部分が小さ過ぎると見えないので、今後は注意してみてください。

最適云々とかについては知りませんが、添付図の数式や書式は、次のとおり。D5、D11、D17、F5、F11、F17 の各セルにも数式が記入されていますが、計算結果は非表示になっています。期限は 90 日という想定で計算してみました。

　　　　　　　　　　　　　　 数式　　　　　　　　　　　　　　通常のセルの書式　　 条件付き書式

通常のセルの書式と数式で非表示にする方法

C4 　2013/8/31　　　　　　　　　　　　　　　　　　　　　　　　　　　m/d;;　　　　　　 なし
D4 　=(c4<>"")*(date(year(c4),month(c4),day(c4)+90)-1)　　　　　　　m/d;;　　　　　　 なし
E4 　2013/8/31 6:54:00 pm　　　　　　　　　　　　　　　　　 m/d"　"h:mm am/pm;;　　　なし
F4 　=(e4<>"")*(date(year(e4),month(e4),day(e4)+90)+time(hour(e4),minute(e4),second(e4)))
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　 m/d"　"h:mm am/pm;;　　　なし

条件付き書式で非表示にする方法

C10　2013/8/31　　　　　　　　　　　　　　　　　　　　　　　　　　　m/d　　　　　　　 なし
D10　=date(year(c10),month(c10),day(c10)+90)-1　　　　　　　　　　　m/d　　　　　　　 あり
E10　2013/8/31 6:54:00 pm　　　　　　　　　　　　　　　　　 m/d"　"h:mm am/pm　　　　なし
F10　=date(year(e10),month(e10),day(e10)+90)+time(hour(e10),minute(e10),second(e10))
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　 m/d"　"h:mm am/pm　　　　あり

数式で空文字列を表示する方法

C16　2013/8/31　　　　　　　　　　　　　　　　　　　　　　　　　　　m/d　　　　　　　 なし
D16　=if(c16,date(year(c16),month(c16),day(c16)+90)-1,"")　　　　　 m/d　　　　　　　 なし
E16　2013/8/31 6:54:00 pm　　　　　　　　　　　　　　　　　 m/d"　"h:mm am/pm　　　　なし
F16　=if(e16,date(year(e16),month(e16),day(e16)+90),"")　　　m/d"　"h:mm am/pm　　　　なし

条件付き書式の設定の方法。D10:D11 のセル範囲をドラッグし、続いて Ctrl キーを押しながら F10:F11 をドラッグ。Enter や Tab を何回か押して、D10 をアクティブにする。その状態で条件付き書式のダイアログを開いて「数式が…」を選択し、条件式「=C10=""」を記入するとともに、同じダイアログにある「書式」ボタンでユーザー定義書式「;;」を記入。

＞パスワード変更日欄が未入力の場合にパスワード有効期限欄に変な表示になってしまいます。

Excel では、空白セルは 0 とみなされます。また、日付のシリアル値 0 は、「1900 年 1 月 0 日」（「1899 年 12 月 31 日」に相当）という日に割り振られています。変だと感じられるのは、そこから 90 日後などが表示されてしまっているためだと推察します。見えませんが。

回答No.2

aokii

画面が小さくて見えません。
パスワード変更日欄（仮にA1セルとすれば）が空白の場合に、パスワード有効期限欄（仮にB1セルとすれば）も空白に表示するなら、B1セルに、=IF(A1="","",ここに今のB1セルの式を入力してください)

回答No.1

kmetu

画像が大きすぎて状態がわかりませんが

> パスワード変更日欄が空白の場合に、パスワード有効期限欄も空白に表示したい

のでしたら、パスワード変更日欄のセルがA1としたらパスワード有効期限欄に

=If(A1="","",パスワード有効期限欄に入れた関数)

という関数を入力してください。