Adobe flashソフトを使ってゲームを作りた

質問

Adobe flashソフトを使ってゲームを作りたいのですが
アクションスクリプト（プログラム）がわかりません
内容はドラックアンドドロップです

シンボルを１つ作ります。
シンボル名は［block1］にします。

それを画面左に設置します。
そのシンボル［block1］にカーソルを合わせドラッグandドロップして画面右に何個も移動させるプログラミングを教えてください

回答No.1

BlurFiltan

ご使用の Flash 作成ソフトやそのバージョン
そしてActionScript のバージョンがないと回答不可能(回答困難)なのですが。

その辺がわからないと回答できないので
【この回答】では勝手に Flash MX 2004 以降をお使いで
ActionScript 2.0 を使用するものとした場合の説明を書きます。
(Flash MX 2004 以降…MX 2004，8，CS3，CS4，…)

新規ドキュメント作成より，
まずシンボル「block1」は
ムービークリップシンボルとして作成します。

ライブラリにあるその「block1」を右クリックするなどして
「プロパティ」より「シンボルプロパティ」パネルを出すか
または「リンケージ」より「リンケージプロパティ」パネルを出すかします。

その出したパネルの「リンケージ」の欄で
　□ ActionScript に書き出し
　□ 最初のフレームに書き出し
にチェックを入れます。

そして「識別子」となっている欄に
例えば「block1」という識別子を付けます。
※【添付図】↓

そして メインタイムライン の フレーム1 に
次のようなスクリプトを書きます。

//------------------------------
//「block1」を配置する座標の設定
var b1_x:Number = 50;
var b1_y:Number = 50;

//「block1」用カウンタを用意
var cnt1:Number = 0;

//「block1」を配置する関数 makeBlock1 の定義
function makeBlock1():Void {
//「block1」を「b1_mc○」というインスタンス名で
//_root の最高深度の指定座標に呼び出す
_root.attachMovie("block1", "b1_mc"+cnt1, _root.getNextHighestDepth());
_root["b1_mc"+cnt1]._x = b1_x;
_root["b1_mc"+cnt1]._y = b1_y;
//
//「b1_mc○」内にフラグ「flg」を用意
_root["b1_mc"+cnt1].flg = false;
//
//「b1_mc○」押下時の動作を定義
_root["b1_mc"+cnt1].onPress = function():Void {
//「b1_mc○」をドラッグを開始
this.startDrag();
//もし「b1_mc○」内のフラグ「flg」の値が false であれば
if (!this.flg) {
//カウンタに1を加算
cnt1++;
//関数 makeBlock1 の実行
makeBlock1();
//「b1_mc○」内のフラグ「flg」の値を true にする
this.flg = true;
}
//
//「b1_mc○」を最高深度に移動
this.swapDepths(_root.getNextHighestDepth());
};
//
//「b1_mc○」を放した時の動作を定義
_root["b1_mc"+cnt1].onRelease =
_root["b1_mc"+cnt1].onReleaseOutside=function ():Void {
//「b1_mc○」のドラッグを終了
this.stopDrag();
};
}

//「block1」を配置する関数 makeBlock1 を実行
makeBlock1();
//------------------------------

なお Flash CS3 以降をお使いで
ActionScript 3.0 を使用する場合の説明は
下記ご質問ページを参考にしてください。

「質問：プログラミング教えてください」
OKWaveの場合→ http://okwave.jp/qa/q8173134.html
教えて!gooの場合→ http://okwave.jp/qa/q8173134.html
などなど…の ＃２ の回答です。

なお今のところ(補足がなければ)
Adobe または Macromedia Flash 以外の Flash 作成ソフトの場合や
Macromedia Flash でも Flash MX 以下の場合などは知りません。
(Flex の場合や Flash Builder の場合や Suzuka の場合や ParaFla! の場合や… 場合が多すぎてそれぞれについて一々回答できません。)