VBAでの処理分岐方法を教えてほしいです

質問

VBAの分岐処理で悩んでおります。
誰かお助けお願いします。

A列に昇順で番号があります。
1
2
4
4
5
6
9

欠番や重複した数値があります。
やりたいことは欠番箇所に行を挿入し、連番にしたいです。
この例で言うと、3行目に1行を挿入し番号を3と入れる、6行目に2行挿入し7,8と連番にする。
連番になった後に、重複した数値に色を付けます。

以下私が作成したコードです。callで呼び出す予定です。

Sub 欠番判定数式()
Dim i As Integer
For i = 2 To Cells(Rows.Count, 1).End(xlUp).Row
Cells(i, 3) = "=if(iserror(if(A" & i & "-A" & i - 1 & ">1,""○"","" "")),"""",if(A" & i & "-A" & i - 1 & ">1,""○"","" ""))"
Next
End Sub

Sub 行挿入()
Dim c As Range, Target As Range
For Each c In Range("C2:C" & Cells(Rows.Count, 1).End(xlUp).Row)
If c = "○" Then
If Target Is Nothing Then ''(1)
Set Target = c
Else
Set Target = Union(Target, c) ''(2)
End If
End If
Next c
If Not Target Is Nothing Then Target.Select
Selection.EntireRow.Insert , copyorigin:=xlFormatFromLeftOrAbove
End Sub

Sub 空白連番入力()
Dim i As Integer
For i = 2 To Cells(Rows.Count, 1).End(xlUp).Row
If Cells(i, 1) = "" Then
Cells(i, 1) = (Cells(i, 1).Offset(1, 0).Value) - 1
End If
Next
End Sub

Sub 番号重複確認()
Dim i As Integer
For i = 2 To Cells(Rows.Count, 1).End(xlUp).Row
If Application.WorksheetFunction.CountIf(Range("$A$2:$A$" & Cells(Rows.Count, 1).End(xlUp).Row), Range("A" & i)) <> 1 Then
Cells(i, 1).Interior.ColorIndex = 3
End If
Next
End Sub

このコードを順に全て実行した時、1回目の処理で3行目と5行目に行挿入、そして番号が3と7と入力され連番に色が設定されます。
再度「欠番判定数式」を行い、次は8行目に行挿入し8と連番を入力させ処理を繰り返しさせたいです。
欠番は例として最高2個にしてますが、これから2個以上の可能性もあります。
一度全処理終了後、再度最初の処理（欠番判定数式）に戻り、欠番がある場合は行挿入させという処理を行わせ、欠番がない場合は次の処理に進めるという分岐方法を教えてほしいです。

よろしくお願いいたします

回答No.1

Asahi2001 · ベストアンサー

参考までに。

Dim i As Long
Dim n As Long

n = 1 '連番用
i = 2　'開始位置
'前処理のセル背景色クリア
Columns(1).Interior.ColorIndex = xlNone

'Ａ列が空白になるまでループ
Do While Cells(i,1) <> ""

Select Case n

Case Is = Cells(i,1)
'セル値の重複チェック
If n = Cells(i+1,1) Then
'セル背景色変更
Cells(i,1).Interior.ColorIndex = 35
Cells(i+1,1).Interior.ColorIndex = 35
Else
n=n+1
End If

Case Is < Cells(i,1)
'行の挿入
Rows(i).Insert shift:=xlDown
'連番記載
Cells(i,1).Value = n
n=n+1

End Select
i=i+1
Loop

お礼

Asahi2001　さん

ご回答ありがとうございます。
希望とおりの動きです！
連番ではない時の行の挿入方法にだいぶ悩んでおりましたが、このような方法でこんな短いコードとは今の自分の知識では考えつきませんでした。
勉強になりました。
本当にありがとうございました！
とても助かりました。
またよろしくお願いします。