(VBA)ブックを閉じるプログラム

質問

表題の通りで、マクロを使ってブックを閉じるプログラムが作りたいです。
具体的には、
"終了"というボタンを作って、このボタンを押したときのみ変更を保存せずに、ブックを閉じる。
右上のXマークを押して閉じようとした場合は、"終了ボタンで終了して下さい"とメッセージを
表示させて、必ず終了ボタンで閉じる。
のようなプログラムです。
ネットで調べ、みよう見まねでプログラムを組んでみましたが、完全にブックが消えません。
また×ボタンを押した場合にブックを閉じない様にするプログラムが分かりません。
<組んでみたプログラム>
Sub test2()
Application.DisplayAlerts = False
Workbooks("Book1.xls").Close
Application.DisplayAlerts = True
End Sub

ご教授お願い致します。

回答No.1

cj_mover · ベストアンサー

こんにちは。
モジュール、【標準モジュール】と【ThisWorkbookモジュール】
を間違えないようにしてください。
また、２択、３択の部分は、運用面から選んでください。
（コメントブロックを付けたり外したり、それぞれ１つを選ぶということです）

' ' ＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
' ' 【標準モジュール】

　　Public blnEnClose As Boolean

Sub test2() '（１／２択）マクロの一覧に表示する
'Private Sub test2() '（２／２択）マクロの一覧に表示しない
　　blnEnClose = True
　　Workbooks("Book1.xls").Close SaveChanges:=False '（１／３択）ブックを名前指定で閉じる
'　　ThisWorkbook.Close SaveChanges:=False '（２／３択）自ブックを閉じる
'　　Application.Quit '（３／３択）アプリケーションごと閉じる。
End Sub

' ' ※ Private Sub にした場合の呼び出し方は、Application.Run "test2"

' ' ＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
' ' 【ThisWorkbookモジュール】

Private Sub Workbook_BeforeClose(Cancel As Boolean)
　　If Not blnEnClose Then
　　　　Cancel = True
　　　　MsgBox "終了ボタンで終了して下さい", vbInformation
　　End If
End Sub

' ' ＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝

お礼

お礼遅くなりました。
解決しました。
有難う御座いました。

回答No.2

keithin

当該のブックを開く
ＡＬＴ＋Ｆ１１を押す
プロジェクトエクスプローラから当該のブックのVBAProjectの中に含まれているThisWorkbookをＷクリックして開く
現れたシートに下記をコピー貼り付ける

private sub Workbook_BeforeClose(cancel as boolean)
　if flg then exit sub
　msgbox "CLICK EXIT BUTTON"
　cancel = true
end sub

さらに挿入メニューから標準モジュールを挿入し、下記をコピー貼り付ける

public flg as boolean

sub macro1()
　flg = true
　thisworkbook.close savechanges:=false
end sub

ファイルメニューから終了してエクセルに戻る
シート上にオートシェイプ等を使って終了ボタンを作成、右クリックしてマクロの登録でマクロ１を登録する。

お礼

お礼遅くなりました。
解決しました。
有難う御座いました。