ファイル読み込み時のエラー回避

質問

VB2010のプログラムで、ファイルを読み込む際に「System.IO.File.ReadAllLines」を利用していますが、そのファイルが他で使用されている場合に「別のプロセスで使用されているため、．．．」というエラーが発生していしまいます。
他でオープンされていてもエラーを発生させず開く方法はないでしょうか。
なければ、回避方法などを教えていただけるとありがたいです。

よろしくお願いします。

回答No.1

1050 円（@1050YEN） · ベストアンサー

http://www.atmarkit.co.jp/fdotnet/dotnettips/707shareread/shareread.html

Imports System.IO
Imports System.Text

Public Class Class1
　Public Shared Sub Main()
　　Dim l_strPath As String = "C:\test.csv"

　　Dim ss As String() = ReadLines(l_strPath)
　　For Each s As String In ss
　　　Console.WriteLine(s)
　　Next

　End Sub

　Public Shared Function ReadLines(ByVal p_strPath As String) As String()
　　'SJIS
　　Return ReadLines(p_strPath, Encoding.GetEncoding(932))
　End Function

　Public Shared Function ReadLines(ByVal p_strPath As String, ByVal p_enc As Encoding) As String()
　　Dim l_aryLines As New List(Of String)

　　'共有モードでオープン
　　Using l_fs As New FileStream(p_strPath, FileMode.Open, FileAccess.Read, FileShare.ReadWrite)
　　　Using l_sr As New StreamReader(l_fs)
　　　　l_aryLines.AddRange(Strings.Split(l_sr.ReadToEnd(), ControlChars.CrLf))
　　　End Using

　　End Using

　　'最終ラインの空文字を除外したい場合
　　If (l_aryLines.Count > 0) AndAlso (String.IsNullOrEmpty(l_aryLines.Item(l_aryLines.Count - 1))) Then
　　　l_aryLines.RemoveAt(l_aryLines.Count - 1)
　　End If

　　'結果を返却
　　Return l_aryLines.ToArray()
　End Function
End Class

お礼

実際に対応方法を記述していただきありがとうございます。
何か一文挟めば、読み取り専用のような開き方があるのかと期待していたのですが、甘かったようですね。
このやり方を試してみたいと思います。
ありがとうございました。

回答No.2

ToOrisugaru

回避案
１．上記理由でｉｏエラーになったファイルをコピーして、コピー先のファイルを読み込むように操作する
２．FileOpenのOpenModeにInput（入力モード）を指定し、読み込む。
３．上記ｉｏエラーを検出した場合、エラーになったファイルの属性を強制的に解除し（ファイルロックを解除）ファイルを読み込む。
上記方法は、読み込んだファイルをその後どうしたいのかにより、方法は変わってくると思いますが基本的にロック中のファイルを読み込み更新等行なった場合、元のファイルの情報は保証するれなくなることに注意してください。

なお、ソースは上記分中の言葉およびキーワードとして「vb.net」を含めることにより例がみつかることと思います。
なお、上記方法は論理的には行けると思いますが試してないので確認してみてください！。

お礼

ネットでいろいろ調べたのですが、よい回避方法が見つからなかったもので。。。
やはり、このやり方ではすんなりはできないようですね。
ありがとうございました。