MT4 スローストキャスティクスについて

質問

下記MT4のスローストキャスティクスのプログラムなのですが、クロスした際にサウンドを鳴らすには、
どのようにプログラムを変えたら良いのでしょうか？どなたか詳しい方、ご教授願います。
詳しい方からすれば、なんてことないことなのですが、全くの初心者で困っています。
どなたか、どうぞよろしくお願いします。

#property copyright "Copyright ?2004, MetaQuotes Software Corp."
#property link "http://www.metaquotes.net"
#property indicator_separate_window
#property indicator_minimum 0
#property indicator_maximum 100
#property indicator_buffers 2
#property indicator_color1 LightSeaGreen
#property indicator_color2 Red
//---- input parameters
extern int KPeriod=42;
extern int DPeriod=3;
extern int Slowing=3;
//---- buffers
double KBuffer[];
double DBuffer[];
double MainBuffer[];
double SignalBuffer[];
double HighesBuffer[];
double LowesBuffer[];
//----
int draw_begin1=0;
int draw_begin2=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int init()
{
string short_name;
//---- 2 additional buffers are used for counting.
IndicatorBuffers(6);
SetIndexBuffer(2, HighesBuffer);
SetIndexBuffer(3, LowesBuffer);
SetIndexBuffer(4, MainBuffer);
SetIndexBuffer(5, SignalBuffer);
//---- indicator lines
SetIndexStyle(0,DRAW_LINE);
SetIndexBuffer(0, KBuffer);
SetIndexStyle(1,DRAW_LINE);
SetIndexBuffer(1, DBuffer);
//---- name for DataWindow and indicator subwindow label
short_name="SlowKD("+KPeriod+","+DPeriod+","+Slowing+")";
IndicatorShortName(short_name);
SetIndexLabel(4,short_name);
SetIndexLabel(5,"Signal");
//----
draw_begin1=KPeriod+Slowing;
draw_begin2=draw_begin1+DPeriod;
SetIndexDrawBegin(0,draw_begin1);
SetIndexDrawBegin(1,draw_begin2);
//----
return(0);
}
//+------------------------------------------------------------------+
//| Stochastic oscillator |
//+------------------------------------------------------------------+
int start()
{
int i,k;
int counted_bars=IndicatorCounted();
double price;
//----
if(Bars<=draw_begin2) return(0);
//---- initial zero
if(counted_bars<1)
{
for(i=1;i<=draw_begin1;i++) MainBuffer[Bars-i]=0;
for(i=1;i<=draw_begin2;i++) SignalBuffer[Bars-i]=0;
}
//---- minimums counting
i=Bars-KPeriod;
if(counted_bars>KPeriod) i=Bars-counted_bars-1;
while(i>=0)
{
double min=1000000;
k=i+KPeriod-1;
while(k>=i)
{
price=Low[k];
if(min>price) min=price;
k--;
}
LowesBuffer[i]=min;
i--;
}
//---- maximums counting
i=Bars-KPeriod;
if(counted_bars>KPeriod) i=Bars-counted_bars-1;
while(i>=0)
{
double max=-1000000;
k=i+KPeriod-1;
while(k>=i)
{
price=High[k];
if(max<price) max=price;
k--;
}
HighesBuffer[i]=max;
i--;
}
//---- %K line
i=Bars-draw_begin1;
if(counted_bars>draw_begin1) i=Bars-counted_bars-1;
while(i>=0)
{
double sumlow=0.0;
double sumhigh=0.0;
for(k=(i+Slowing-1);k>=i;k--)
{
sumlow+=Close[k]-LowesBuffer[k];
sumhigh+=HighesBuffer[k]-LowesBuffer[k];
}
if(sumhigh==0.0) MainBuffer[i]=100.0;
else MainBuffer[i]=sumlow/sumhigh*100;
i--;
}
//---- last counted bar will be recounted
if(counted_bars>0) counted_bars--;
int limit=Bars-counted_bars;
//---- signal line is simple movimg average
for(i=0; i<limit; i++)
KBuffer[i]=iMAOnArray(MainBuffer,Bars,Slowing,0,MODE_SMA,i);
for(i=0; i<limit; i++)
DBuffer[i]=iMAOnArray(KBuffer,Bars,DPeriod,0,MODE_SMA,i);
//----
return(0);
}
//+------------------------------------------------------------------+

回答No.2

fhat6014 · ベストアンサー

ANo.1です。

確かに「サウンドを鳴らすには」とありました。
他の事でAlert表示を使っていたので、勝手に脳内で読み替えてしまったようです。
すいませんでした。

追加箇所として書いた

static datetime lastAlertTime;
if( AlertON && Time[0] > lastAlertTime ){
if( KBuffer[1] >= DBuffer[1] && KBuffer[2] < DBuffer[2] ){
Alert("Stochastic Cross Alert UP "+Symbol());
lastAlertTime = Time[0];
}
if( KBuffer[1] <= DBuffer[1] && KBuffer[2] > DBuffer[2] ){
Alert("Stochastic Cross Alert DOWN "+Symbol());
lastAlertTime = Time[0];
}
}

この部分を変更してください。

static datetime lastAlertTime;
if( AlertON && Time[0] > lastAlertTime ){
if( ( KBuffer[1] - DBuffer[1] ) * ( KBuffer[2] - DBuffer[2] ) < 0 ){
PlaySound("Alert");
lastAlertTime = Time[0];
}
}

これでクロスしたときに一度だけ音がなります。
クロスが成立している間音を鳴らし続けたければ、こちらに変更。

if( AlertON ){
if( ( KBuffer[1] - DBuffer[1] ) * ( KBuffer[2] - DBuffer[2] ) < 0 ){
PlaySound("Alert");
}
}

プログラムの勉強方法ですが、この２冊が「読むべき本」としてよく紹介されています。
ただ、多少プログラムに関する予備知識がないと難しい本のようです。

FXメタトレーダー入門　最先端システムトレードソフト使いこなし術
FXメタトレーダー実践プログラミング　高機能システムトレードソフト超活用術

最近出た本のなかでは、これが評判が良いです。
この本で組めるようになったという話も聞きます。
質問サイトでもこの本の影響と思われる質問もよく見かけます。

iCustomで変幻自在のメタトレーダー　EAをコピペで作る方法

ある程度理解できるようになったら、このサイトで調べることが増えると思います。
直訳の日本語が読みづらいですが、慣れると大変便利です。

メタトレーダー４ MQL言語リファレンス日本語翻訳マニュアル
http://www.metasys-seeker.net/MQL4_Reference_ver1/MQL4_Reference_Contents.html

お礼

早速の回答ありがとうございます。
Bestです。こんなに速やかにすぐプログラムを変更できる
貴殿の能力が羨ましいです。
また、助けてください。
以上

回答No.1

fhat6014

プログラムの最初「#property」の下

//---- input parameters
extern int KPeriod=42;
extern int DPeriod=3;
extern int Slowing=3;

の部分に追加

//---- input parameters
extern bool AlertON = true;//---追加箇所
extern int KPeriod=42;
extern int DPeriod=3;
extern int Slowing=3;

プログラムの最後

for(i=0; i<limit; i++)
KBuffer[i]=iMAOnArray(MainBuffer,Bars,Slowing,0,MODE_SMA,i);
for(i=0; i<limit; i++)
DBuffer[i]=iMAOnArray(KBuffer,Bars,DPeriod,0,MODE_SMA,i);
//----
return(0);

の部分に追加

for(i=0; i<limit; i++)
KBuffer[i]=iMAOnArray(MainBuffer,Bars,Slowing,0,MODE_SMA,i);
for(i=0; i<limit; i++)
DBuffer[i]=iMAOnArray(KBuffer,Bars,DPeriod,0,MODE_SMA,i);
//---ここから追加箇所
static datetime lastAlertTime;
if( AlertON && Time[0] > lastAlertTime ){
if( KBuffer[1] >= DBuffer[1] && KBuffer[2] < DBuffer[2] ){
Alert("Stochastic Cross Alert UP "+Symbol());
lastAlertTime = Time[0];
}
if( KBuffer[1] <= DBuffer[1] && KBuffer[2] > DBuffer[2] ){
Alert("Stochastic Cross Alert DOWN "+Symbol());
lastAlertTime = Time[0];
}
}
//----追加箇所ここまで
//----
return(0);

お礼

こんにちは。早速、試してみてビックリしました。
ご教授いただいたのに申し訳ありませんが、Alertではなく、音（Sound)を
鳴らすには、どうしたらよいのでしょうか。
（私の記載がまずくて申し訳ないのですが・・・）
それと、貴殿のようにMT4のプログラム（変更・作成）に詳しくなるには、
どうしたらよいのでしょうか？
何か書籍か何かあるのでしょうか？
本当にありがとうございました。
また、お時間があれば、教えていただけるとありがたいです。
以上