表示

質問

特定の月日(特定の週)を入力すると、それに該当した作業を全て検索して、一覧表示するための表を作成しました。

(例１)参照表
セルA　　　　B　　　　　　　　　　C
　週 　作業 　　　　該当する項目の表示
第2土 　階段
第2土 　排水溝
第3日 　Ｓフード　　　　 該当　　←　一覧表の「第何曜日」と同じ曜日なら「該当」表示
第3日 　フィルター　　　　　該当
第3日　　床面 　　　　　　該当
第3日　 ジュウタン　　　　　　該当

(例2)一覧表

日付を入力する　　　　日付を入力すると、第何曜日として表示される
↓　　　　　　　　　　　↓
5月20日　　　　　　　　第3日　　　　　　　　

本日の作業は・・・

Ｓフード　　
フィルター 　←該当した日付(特定の週)の作業が全て表示する
床面 　　　
ジュウタン

　質問につきましては、「該当」と表示された項目全てを、一覧表へ表示させたいのですが、方法について、何卒ご教授を宜しくお願いいたします。

回答No.3

noname#204879

[No.1お礼]へのコメント、

》 セルの書式設定のどちらに数式を入れるのでしょうか？

その日本語、チト変です。
書式設定も数式も同じセル(Sheet2!A5)ですよ、当然のことながら。

回答No.2

keithin

ムズカシイ配列数式を使っても出来ますが、お手前でやろうとすると必ず破綻します。
できるだけ簡単な数式だけで添付図のように作成してみます。

Ｂ、Ｃ列に作業予定日と作業内容を列記
Ａ２：
=IF(B2="","",B2&COUNTIF($B$2:B2,B2))
以下コピー

Ｅ２に作業日を記入
Ｅ３に
=TEXT(INT((DAY(E2)+6)/7),"第0")&TEXT(E2,"aaa")
と記入

Ｆ２に
=IF(ROW(F1)>COUNTIF(B:B,$E$3),"",VLOOKUP($E$3&ROW(F1),A:C,3,FALSE))
以下コピー。

お礼

返事が遅れてしまい、申し訳有りませんでした。

　希望通りの表を作成することが出来ました。

　追加で質問よろしいでしょうか？
　毎月一度の定期作業のほかに、下記のような条件も有ります。

Ａ列

1月第四火曜日1
3月第四火曜日1
5月第四火曜日1
7月第四火曜日1
9月第四火曜日1
11月第四火曜日1

　「何月第何曜日に実施」と「毎月何曜日に実施」を併せて表示するとしたらどうすればよいのでしょうか？

回答No.1

noname#204879

添付図参照
Sheet2!B2: ="第"&ROUNDUP(DAY(A2)/7,0)&TEXT(A2,"aaa")
Sheet1!C3: =IF(A3=Sheet2!B$2,"該当","")
Sheet1!D3: =IF(C3="該当",ROW(),"")
Sheet2!A5: 末尾に示した[条件付き書式]を設定後、
　　　　　　式 =INDEX(Sheet1!B:B,SMALL(Sheet1!D:D,ROW(Sheet1!A1))) を入力

　　　　　　数式が　　　=ISERROR(A5)
　　　　　　フォント色　白

お礼

アドバイスして頂き、ありがとうございました。

Sheet2!A5: 末尾に示した[条件付き書式]を設定後、

　セルの書式設定のどちらに数式を入れるのでしょうか？