excelの表で。。。

質問

ピポットテーブルの形式のデータがあります。
これを普通のデータ形式にしたのですが。。。

例
　　　　ａ店　ｂ店
たまご　100 50
牛乳 50 30

これを

たまご　ａ店　100
たまご　ｂ店　 50
牛乳　　ａ店　 50
牛乳　　ｂ点　 30

のようにしたいのです。

よろしくお願い致します。

回答No.1

ja7awu · ベストアンサー

マクロを使わないとちょっと難しいのではないかと思います。

もし、マクロで宜しかったら、詳しい手順を書きますのでテストしてみてください。

データシートを表示した状態で、このマクロを実行すると、そのシートの右側に新しい
シートが作られて、変換したデータが表示されます。

そのシート名は、現在のシート名に "(変換)" が付加された名前です。
何回実行しても、新しいデータで上書きされます。

[マクロの設定方法]

１．Alt + F11 で VBE(Visual Basic Editor)を開きます。
２．VBE のメニューから[挿入] -->[標準モジュール] を指定します。
３．モジュールウィンドウに下記コードをコピーして貼り付けます。
　（必要により、コードの２～３行目を実情に合わせ設定変更します。）
４．Alt + Q （または、右上隅の×）でウィンドウを閉じ、シートに戻ります。
５．メニューから[ツール]-->[マクロ]-->[セキュリティ]で「セキュリティレベル」を
　「中」にして[OK]します。
６．実行するときは、Alt ＋ F8 (メニューから[ツール]-->[マクロ]-->[マクロ])で
　「データ変換」を指定し、[実行]ボタンを押します。

これで如何でしょうか。

Sub データ変換()
Const YRetu = "A" '<----- 列(品名)指定（Ｙ軸）
Const XGyou = 1 '　<----- 見出し行を指定（Ｘ軸）
Dim Sh1 As Worksheet
Dim Sh2 As Worksheet
Dim Rng As Range
Dim RngC As Range
Dim Rw As Long
Dim Col As Integer
Dim N As Integer
If InStr(ActiveSheet.Name, "(変換)") > 0 Then
　　MsgBox "変換対象のシートではありません。", vbCritical
　　Exit Sub
End If
Set Sh1 = ActiveSheet
For N = 1 To Worksheets.Count
　　If ActiveSheet.Name & "(変換)" = Worksheets(N).Name Then
　　　　Worksheets(N).Move After:=Sh1
　　　　Set Sh2 = Worksheets(N)
　　　　Exit For
　　End If
Next N
If N > Worksheets.Count Then
　　Sheets.Add After:=Sh1
　　Set Sh2 = ActiveSheet
　　Sh2.Name = Sh1.Name & "(変換)"
End If
Sh2.Cells.ClearContents
Sh1.Select
Rw = 1
For Each Rng In Range(YRetu & XGyou + 1, Range(YRetu & 65536).End(xlUp))
　　Col = 1
　　For Each RngC In Range(Rng.Offset(, 1), Range("IV" & Rng.Row).End(xlToLeft))
　　　　Sh2.Cells(Rw, 1).Value = Rng.Value
　　　　Sh2.Cells(Rw, 2).Value = Sh1.Cells(XGyou, YRetu).Offset(, Col).Value
　　　　Sh2.Cells(Rw, 3).Value = RngC.Value
　　　　Rw = Rw + 1: Col = Col + 1
　　Next RngC
Next Rng
Set Sh1 = Nothing
Set Sh2 = Nothing
Beep: Beep: Beep
MsgBox "変換完了!!"
End Sub

お礼

うぉー。すごい。できました。

助かりました。本当に。

有難うございました。