actionscript 3.0 勉強中のもです。

質問

よろしくお願いします。
ある右へ動いていく四角をクリックするとそれ自体のvisibleプロパティに変化（消える）を起こす事を意図して以下のような、プログラムを作りました。しかしながら、横移動の動作を確認しましたが、クリックをしても横移動を続けるだけでした。_mc.addEventListener(Event.ENTER_FRAME,onGo)を抜かした状態で見てみると、しっかり消えることを確認しました。しかし_mc.addEventListener(Event.ENTER_FRAME,onGo)
を加えると上記のようになります。２つのイベントリスナーをつなげて書く事は間違った事ではないと思っています。どのように考えて書き直したらしたらよろしいのでしょうか？お心当たりございましたらどうぞよろしくお願いします。

package
{
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
public class Main extends Sprite
{
var _mc:Sprite = new Sprite;

function Main()
{
_mc.graphics.beginFill(0x334455);
_mc.graphics.drawRect(0,0,120,120);
_mc.graphics.endFill();
_mc.x= 130;
_mc.y= 220;

addChild(_mc);

_mc.addEventListener(MouseEvent.CLICK,onClick2);
_mc.addEventListener(Event.ENTER_FRAME,onGo);
}
function onClick2(event:MouseEvent):void
{
trace(event.target.name + "をクリックしました。");
_mc.visible= !(_mc.visible);
}
function onGo(event:Event):void
{
if(_mc.visible=true)
{
_mc.x += 1
}
}
}
}

回答No.1

BlurFiltan · ベストアンサー

２つのイベントリスナーがどうしたこうしてではなくて
単なる凡ミスですね。

最後の関数 function onGo 内 の if文 の () 内↓

if(_mc.visible=true)

この「=」は代入演算子です。

つまりこのままでは
「_mc を表示させろ！」という意味になり，
それを ENTER_FRAME で実行させるわけですから，
「何が何でも _mc を表示させ続けろ！」
みたいな動作命令をしていることになります。

だから _mc は表示されっぱなしになるのです。

「等しいかどうか？」の判断に使うのは
等価演算子の「==」です。
　　↓修正↓
if(_mc.visible == true)

「Adobe ActionScript 3.0 演算子」
・等価演算子
http://help.adobe.com/ja_JP/ActionScript/3.0_ProgrammingAS3/WS5b3ccc516d4fbf351e63e3d118a9b90204-7fd1.html#WS5b3ccc516d4fbf351e63e3d118a9b90204-7f64

※それと思うのですが...
　 質問カテゴリも凡ミスしていらっしゃいませんか？

お礼

BlurFiltan様
いつもありがとうございます。
一筋縄ではいかないようですね（汗。
もう少し考え方をつかんでいくにはまだ時間がかかりそうです。
今しばらくおつきあいいただければ幸いです。
ありがとうございました。

補足

BlurFiltan様
いつもありがとうございます。引き続き質問をさせてください。以下のように、_mc.visibleプロパティーがtrueの時には、横移動を続け且つ,_mcをクリックすると
visibleプロパティーがfalse（否定され）になり、逆に_mc.visibleプロパティーがfalseの時は、stageをクリックするとvisibleプロパティーがtrueになる事を意図して、記述をしました。しかし
TypeError: Error #1034: 強制型変換に失敗しました。flash.events::Event@35d28ec1 を flash.events.MouseEvent に変換できません。
と出力にでます。どのようにしたらよろしいのでしょうか？よろしくお願いします。

package
{
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
public class Main extends Sprite
{
var _mc:Sprite = new Sprite;

function Main()
{

_mc.graphics.beginFill(0x334455);
_mc.graphics.drawRect(0,0,120,120);
_mc.graphics.endFill();
_mc.x= 130;
_mc.y= 220;

addChild(_mc);

_mc.addEventListener(MouseEvent.CLICK,onClick2);
_mc.addEventListener(Event.ENTER_FRAME,onGo);
stage.addEventListener(MouseEvent.CLICK,onClick3)
}

function onClick2(event:MouseEvent):void
{
if(_mc.visible==true)
{
trace(event.target.name + "をクリックしました。");
_mc.visible= !(_mc.visible);
}
}
function onGo(event:MouseEvent):void
{
if(_mc.visible==true)
{
_mc.x += 1
}
}
function onClick3(event:MouseEvent):void
{
if(_mc.visible==false)
{
_mc.visible= !(_mc.visible);
}
}
}
}

回答No.2

BlurFiltan

＃１ です。

まずエラーメッセージの件からです。

> TypeError: Error #1034: 強制型変換に失敗しました。
> flash.events::Event@35d28ec1 を
> flash.events.MouseEvent に変換できません。
> と出力にでます。

これはそのエラーメッセージの通りしょう。

_mc.addEventListener(Event.ENTER_FRAME,onGo);

ここ↑で
_mc に対して Event.ENTER_FRAME (毎フレーム実行) で
関数「onGo」 を実行させ続けようとされていますが，
それを受ける 関数「onGo」 の仮引数の型が
MouseEvent になっているからです↓。

function onGo(event:MouseEvent)

Event.ENTER_FRAME (毎フレーム実行) はマウスイベントではありません。
というわけで修正↓。

function onGo (event:Event)

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝

次です。

> _mcをクリックすると
> visibleプロパティーがfalse（否定され）になり、
> 逆に_mc.visibleプロパティーがfalseの時は、
> stageをクリックするとvisibleプロパティーが
> trueになる事を意図して、
> 記述をしました。

「_mc」は「stage の中」に存在するわけです。
つまり
「_mc」をクリックする ＝ 「stage」もクリックする
ということになります。

ですから
最初のエラーを修正しても，
説明されているような動作にはなりません。

とりあえずは「_mc」をクリックしても「_mc」は消えません。
これは「_mc」をクリックすると同時に「stage」もクリックしていることになるからです。
(「_mc」クリックで「_mc」は消えても，「stage」クリックによってまた表示される。)

この件に関しては
次のようにするのが１つの対処法でしょうか。

◎第１案

//============================
package
{
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
public class Main extends Sprite
{
var _mc:Sprite = new Sprite();

//_mc をクリックしたかどうかのフラグを用意
var click_flag:Boolean = false;

function Main ()
{
_mc.graphics.beginFill (0x334455);
_mc.graphics.drawRect (0,0,120,120);
_mc.graphics.endFill ();
_mc.x = 130;
_mc.y = 220;

addChild (_mc);

_mc.addEventListener (MouseEvent.CLICK,onClick2);
_mc.addEventListener (Event.ENTER_FRAME,onGo);
stage.addEventListener (MouseEvent.CLICK,onClick3);
}

function onClick2 (event:MouseEvent):void
{
//_mc は無条件に表示
_mc.visible = false;
// _mc クリックフラグを true にする
click_flag = true;
}

function onGo (event:Event):void
{
if (_mc.visible)
{
_mc.x += 1;
}
}

function onClick3 (event:MouseEvent):void
{
//_mc の visible が false であり
if (!_mc.visible)
{
//なおかつ _mc クリックフラグが true のとき
if (click_flag)
{
//_mc クリックフラグを false にする
click_flag=false;

}
else
{
//それ以外(フラグが false)のときに限って _mc を表示
_mc.visible=true;
}
}
}
}
}
//============================

全く別の考え方ですが
次のような方法もアリかもしれません↓。

◎第２案

//============================
package
{
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
public class Main extends Sprite
{
var _mc:Sprite = new Sprite();

function Main ()
{
_mc.graphics.beginFill (0x334455);
_mc.graphics.drawRect (0,0,120,120);
_mc.graphics.endFill ();
_mc.x = 130;
_mc.y = 220;

addChild (_mc);

stage.addEventListener (MouseEvent.CLICK,onClick2);
_mc.addEventListener (Event.ENTER_FRAME,onGo);
}

function onClick2 (event:MouseEvent):void
{
// _mc の visible が false のとき
if (! _mc.visible)
{
// _mc を表示
_mc.visible = true;
// それ以外で もし _mc がマウスとヒットしていれば
} else if (_mc.hitTestPoint(stage.mouseX,stage.mouseY,true))
{
// _mc を非表示にする
_mc.visible = false;
}
}

function onGo (event:Event):void
{
if (_mc.visible)
{
_mc.x += 1;
}
}

}
}
//============================

どちらにしても
中学数学の集合のややこしい版みたいですね。。。