数字の並び替え。

質問

どなたかご存じでしたら回答をお願いします。
数字選択式宝くじのミニロト又はロト６の予想数字において、
予想数字として登場した数字を１～９、１０～１９、２０～２９、３０～３９、４０～４３
の５つに分ける方法が知りたいです。
例としては下記のような予想数字があるとします。

【予想数字】
06 08 18 21 34 43
02 19 24 26 38 40
12 16 28 33 39 42
07 15 25 30 35 41
05 14 23 29 32 37

これを、下記のように並べ替える。
02 05 06 07 08
12 14 15 16 18 19
21 23 24 25 26 28 29
30 32 33 34 35 37 38 39
40 41 42 43

【注意事項】
　・予想数字は１～４３までの数字を使用します。
　・予想数字に使用する数字に同じ数字の重複はありません。
　・予想数字に登場する数字は、文字タイプ、数字タイプどちらでもよいです。
　・エクセル２００７を使用します。

簡単に並べ替えれる方法が知りたいです。

よろしくお願いします。

回答No.3

keithin · ベストアンサー

Ａ：Ｆ列に予想数字を並べる

Ｈ１に
=IFERROR(SMALL(IF(LEFT(TEXT($A$1:$F$10,"00;;;"))=(ROW(H1)-1)&"",$A$1:$F$10),COLUMN(A1)),"")

と式を記入してコントロールキーとシフトキーを押しながらEnterで入力し，右に下にコピーする。

お礼

さっそくのご回答ありがとうございます。
随分とすっきりした式でできるんですね。
ちょっと試してみます。

回答No.5

MackyNo1

元データがA1:H5セルにあるなら、以下の式を入力して、Ctrl+Shift+Enterで確定し、右方向および下方向にオートフィルしてください。

=IFERROR(SMALL(IF(($A$1:$F$5<10*ROW(A1))*(($A$1:$F$5>=10*(ROW(A1)-1))),$A$1:$F$5),COLUMN(A1)),"")

お礼

いつもスマートな回答ありがとうございます。

回答No.4

noname#204879

添付図参照
H1: =IF(COUNTIF($A$1:$F$5,(ROW(A1)-1)*10+COLUMN(A1)-1),(ROW(A1)-1)*10+COLUMN(A1)-1,"")
H7: =IF(ISERROR(SMALL($H1:$Q1,COLUMN(A1))),"",SMALL($H1:$Q1,COLUMN(A1)))

お礼

ご回答ありがとうございます。
ちょっと試してみます。

回答No.2

某HN クロメート(Chromate)（@CoalTar）

文字列でも数字でもなく数値として

A8セル
=IF(SMALL($A$2:$F$6,COLUMN(A1))>=10,"",SMALL($A$2:$F$6,COLUMN(A1)))
A9セル
=IF(SMALL($A$2:$F$6,COUNT($A$8:$J8)+COLUMN(A$1))>=20,"",SMALL($A$2:$F$6,COUNT($A$8:$J8)+COLUMN(A$1)))
A10セル
=IF(SMALL($A$2:$F$6,COUNT($A$8:$J9)+COLUMN(A$1))>=30,"",SMALL($A$2:$F$6,COUNT($A$8:$J9)+COLUMN(A$1)))
A11セル
=IF(SMALL($A$2:$F$6,COUNT($A$8:$J10)+COLUMN(A$1))>=40,"",SMALL($A$2:$F$6,COUNT($A$8:$J10)+COLUMN(A$1)))
A12セル
=IF(COUNT($A$8:$J11)+COLUMN(A$1)>COUNT($A$2:$F$6),"",SMALL($A$2:$F$6,COUNT($A$8:$J11)+COLUMN(A$1)))
A8:A12セルを選択してJ列までオートフィル
添付図参照

お礼

さっそくのご回答ありがとうございます。
ちょっと試してみます。

回答No.1

tom04

こんばんは！
Sheet1のデータをSheet2に表示するようにしてみました。
一例です。

データはSheet1のA1セルからあるとします。
Sheet2の表示したいセルに
=IF(ISERROR(SMALL(IF(INT(Sheet1!$A$1:$F$5/10)=ROW(A1)-1,Sheet1!$A$1:$F$5),COLUMN(A1))),"",SMALL(IF(INT(Sheet1!$A$1:$F$5/10)=ROW(A1)-1,Sheet1!$A$1:$F$5),COLUMN(A1)))

これは配列数式になってしまいますので
Shift+Ctrlキーを押しながらEnterキーで確定！
この画面からコピー＆ペーストする場合は
セルに貼り付け後、数式バー内で一度クリック！
編集可能になりますので、Shift+Ctrlキーを押しながらEnterキーで確定！
数式の前後に｛　｝マークが入り配列数式になります。

これを列方向と行方向にオートフィルでコピーしてみてください。

※　他に良い方法があればごめんなさいね。m(_ _)m

お礼

さっそくのご回答ありがとうございます。
ちょっと試してみます。