loadMovieで呼び出したswfの不具合

質問

Flash初心者です。
環境は、OSはWindowsXPで、FlashのヴァージョンはCS3です。

loadMovieで呼び出したswfファイルが正常動作しません。

表示枠用に四角形の枠を書き、
ムービークリップシンボルに変換、
シンボル名は「load.mc」
インスタンス名も同じく「load.mc」とし、
タイムラインの1フレーム目に
this.load_mc.loadMovie("●●●.swf");
と記述し、プレビューしたところ
呼び出したswfファイルが正常に動作しませんでした。

また、
on(press){
this.load_mc.loadMovie("●●●.swf");
}
と記述したボタンでも結果は同様でした。

呼び出したswfファイルは、
いくつかの任意の角度から撮影した物体の画像をタイムライン上に並べ
画像の360度回転、拡大縮小をスライダーでコントロールするというもので
因みに、これはMdNムックの
「プロが教えるFlashアイデア工房」の127ページに掲載されていたものの流用です。

尚、掲載されていたサンプルのswfファイルを
試しに同様にloadMovieで呼び出してみたところ結果は同じでした。

swfファイル単独では正常に動作するのですが
loadMovieで呼び出すと、
記述されたスクリプトがクリアされてしまうのか全く動作しません。
何が問題なのか全くわからず途方に暮れています。
どなたかご教授ください。

以下は、
呼び出すswfファイルに記述されたスクリプトです。

＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿

※画像のムービークリップに記述したスクリプト
↓↓↓

this.onLoad = function() {
rtK = 0.3;//ズームスピード
minSC = 30//縮小時の最小値;
maxSC = 180//拡大時の最大値;
//回転初期設定
frK = 0.3;//回転スピード
maxFr = _totalframes;//最大フレーム数の設定
};

this.onEnterFrame = function() {
//////画像サイズ//////
tarSC = _root.sliderZ.zmSlider()*(maxSC-minSC)/100+minSC;//0で最小、100で最大になるよう変換
vSC = (tarSC-_xscale)*rtK;//目標の値に近づく
this._xscale += vSC;//表示
this._yscale += vSC;//表示
//////画像回転位置//////
tarFr = _root.sliderR.rtSlider()*maxFr/100;//0で最小、100で最大になるよう変換
vFr = (tarFr-curFr)*frK;//目標の値に近づく
curFr += vFr;
tmpFr = Math.floor(curFr);
tmpFr %= maxFr;
if (tmpFr<0) tmpFr += maxFr;//負の値の場合
gotoAndStop(tmpFr+1);//表示
};

this.onLoad();

※回転用スライダーのムービークリップに記述したスクリプト
↓↓↓

this.onLoad = function() {
//回転初期設定
range = 234;//スライダーのドラッグ範囲
minX = 92;//スライダーのX座標の最小値
maxX = minX+range;//スライダーのX座標の最大値
curX = _x;
btPress = false;//ドラッグ中か否か

}

function rtSlider(){
if (btPress) curX = _parent._xmouse;//スライダーのドラッグ
curX = Math.min(curX, maxX);//ドラッグ範囲
curX = Math.max(curX, minX);//ドラッグ範囲
_x = curX;//移動
//
//画像の回転
rtVal = (curX-minX)*100/range;//0から100の値に変換
return(rtVal);
}

this.onPress = function() {
btPress = true;
};

this.onRelease = this.onReleaseOutside=function () {
btPress = false;
};

this.onLoad();

回答No.1

DPE · ベストアンサー

_root という表現が、いくつかあるようですが。
_root が指す対象が、読み込まれた後に変わってしまうことが原因だと思います。

ActionScript では、関数や変数、ムービークリップなどには全て、持ち主がいると考えます。
スクリプトで指示を出す時は、必ず、誰が持っているものに対して指示を出すのか、その持ち主を指定しなければなりません。
持ち主の指定のことを”ターゲットパス”といいます。

_root はターゲットパスを記述する時の表現の１つで、通常はメインのタイムラインを表します。
例えば

　_root.sliderZ.zmSlider()

は、メインのタイムラインに sliderZ という名前のムービークリップか変数があるかと思いますが、それが持っている zmSlider 関数を呼び出す、との意味です。

swf ファイルを読み込んだ場合、読み込みを行った側にもメインのタイムラインがあり、読み込まれた swf ファイル内で使われている _root は、読み込みを行った側のメインのタイムラインを指すようになります。
そして、読み込まれた側のメインのタイムラインは、ムービークリップ load_mc に読み込んだ時は load_mc のタイムラインに変わります。

読み込まれた時はこのように、_root が指す対象やメインのタイムラインと称していたタイムラインが変化します。
そのため、_root を使ったターゲットパスでは持ち主を正確に指定できなくなり、単体では動くのに読み込むと動かなくなる問題が起こります。

loadMovie を実行する側を FlashPlayer 7 以上でパブリッシュするのであれば、_lockroot というプロパティを使って、読み込まれる swf ファイル内の _root が指しているタイムラインを保護することができます。
読み込むスクリプトを、次のように変更してみてください。

（↓　各行頭に全角のスペースが入っています。コピーする際は、全て半角のスペースかタブに置き換えてください）

//＊＊＊

　//読み込むswfファイルの_rootが指す対象を保護する
　load_mc._lockroot = true;

　//ファイルを読み込む
　load_mc.loadMovie( "●●●.swf" );

//＊＊＊

他にも、読み込まれる swf ファイルで、メインのタイムラインを _root ではなく this や _parent を使った相対表現で表わす、といった方法もあります。

お礼

ご回答いただきありがとうございます。

早速、
スクリプトを変更してみたところ
問題なく正常に動作しました！
どうもありがとうございましたm(_ _)m

this や _parent を使った相対表現も
後で試してみます。

*　*　*　*　*

実は、
お答えをいただく間に
自力で何とかしようと試行錯誤の末、
別な形ではありますが、一応の納得できる形には
出来上がったのですが。。。

とりあえず出来たのはいいのですが
どうしてそうなるのか？が
全く理解できずに
頭がモヤモヤしていました。

*画像の回転縮小のムービークリップ部分と
*コントロール部分を分割し
*コントロール部分を呼び出す側に、
*画像の回転縮小部分を呼び出される側に
*配置したところ何とかなってしまいました。

*　*　*　*　*

今回は、
丁寧に解説いただきありがとうございました。
かみくだいたわかりやすい表現で
スムーズに頭に入ってきました。
感謝いたします。