ロードに失敗したら代替イメージをロードさせたい

質問

ロードに失敗したら代替イメージをロードさせたい
のですが、下記のようにしても
『読み込みが終わっていないローダーの情報は表示できません』
というようなエラーが出てはじかれてしまいます
こういうやり方で代替イメージをロードさせることはできないんでしょうか？

myLoader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR,function(e){
e.target.removeEventListener(e.type,arguments.callee);
e.target.loader.close();
e.target.loader.load(new URLRequest("dummy.jpg"));
})

よろしくお願いします

回答No.1

BlurFiltan · ベストアンサー

書かれていらっしゃるスクリプトですが，
Flash Player 10 用 SWF のパブリッシュ設定だとまったくそのままでOKで無事動作します。

Flash Player 9 用 SWF のパブリッシュ設定だと，

> Error: Error #2099: 読み込み中のオブジェクトは、
> 十分に読み込まれていないので、その情報を表示
> することができません。
>　　at flash.display::LoaderInfo/get loader()
>　　at MethodInfo-1()

と出ますね。

また次のようにすると，Flash Player 9 用 SWF のパブリッシュ設定でもOKです。

myLoader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR,function(e){
e.target.removeEventListener(e.type,arguments.callee);
myLoader.close();
myLoader.load(new URLRequest("dummy.jpg"));
})

結局 「e.target.loader」 の部分で詰まります。
Flash Player が e.target.loader を開示してくれませんね。

こんな逃げ方↓はどうでしょうか？

--------------------------------
function setOnError(LD:Loader):void {
LD.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR,function(e){
LD.removeEventListener(e.type,arguments.callee);
LD.close();
LD.load(new URLRequest("dummy.jpg"));
})
}

setOnError(myLoader);
--------------------------------

上記逃げ方の使用例↓

---------------------------------
var myLoader1:Loader = new Loader();
var myLoader2:Loader = new Loader();

function setOnError(LD:Loader):void {
LD.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR,function(e){
LD.removeEventListener(e.type,arguments.callee);
LD.close();
LD.load(new URLRequest("dummy.jpg"));
})
}

setOnError(myLoader1);
setOnError(myLoader2);

myLoader1.load(new URLRequest("genuine1.jpg"));
myLoader2.load(new URLRequest("genuine2.jpg"));

addChild(myLoader1);
myLoader1.x = 50;
addChild(myLoader2);
myLoader2.x = 100;
---------------------------------

お礼

ありがとうございます

１０では動くのですね‥‥

ちょうどクラス内に引数入れて
リスナー生成するための関数が用意してあるので
そいつにこいつのリスナーを
作らせるようにしようと思います