エクセル VLOOKUP関数について

質問

エクセルについて初心者なのですが、質問させて下さい。

【表１】　　
あ　　1　　　☆
い　　2　　　★
う　　3　　　★
え　　1
お　　2　　　☆
か　　3　　　☆
き　　1　　　★
く　　1
け　　2
こ　　3

【表２】
　　☆　　★
1　　あ　　き　
2 　 お　　い
3　　か　　う

【表１】のデータを基に【表２】のように常に表示するにはどんな関数が必要でしょうか？同じシート内で構いません。
色々検索してみましたが、VLOOKUPが目的に合っているように思うのですが、分かりませんでした。
詳しい方なら簡単なのかもしれませんが教えて頂けませんでしょうか？
申し訳ありませんが宜しくお願い致します。

回答No.5

mu2011

一例です。
表１をA1:C10範囲、表２をA20:C23とします。
B21に=INDEX($A$1:$A$10,SUMPRODUCT(($B$1:$B$10=$A21)*($C$1:$C$10=B$20)*ROW($A$1:$A$10)))を設定、縦横にコピー

回答No.4

某HN クロメート(Chromate)（@CoalTar）

ピボットテーブルではできそうもありませんでした
よって、ここではほとんど見かけない回答をしてみます。

データベースとして処理したいのでタイトル行(フィールド名)を設けます
E1:F2 がCriteriaになります
E4セルは =DGET(A1:C11,A1,E1:F2)
E4:G7セルを選択して データ - テーブル
行の代入セル $F$2
列の代入セル $E$2
添付図参照

作業列案をお勧めします
参考まで

回答No.3

tom04

こんばんは！
すでに回答は出ていますが・・・

他の方法での一例です。

↓の画像で説明させていただくと
まず、作業列として　D列を使います。
D2セル　=B2&C2
としてオートフィルで下へコピーします。
そのデータをもとにすれば右側の表のように表示できると思います。

G3セル　=INDEX($A$2:$A$11,MATCH($F3&G$2,$D$2:$D$11,0))
という数式をいれて、行方向と列方向にオートフィルでコピーします。
これで希望に近い形にならないでしょうか？

尚、エラー処理はしていません。

以上、参考になれば幸いです。m(__)m

お礼

とても参考になりました。
他にも条件抽出したいものがあるので応用出来そうです。
なるほどって感じでした。
ありがとうございます。

回答No.2

noname#204879

A　 B　C　 D　E　 F
1　 あ　1　☆　　 ☆　★
2　 い　2　★　　 あ　い
3　 う　3　★　　 お　う
4　 え　1　　　　 か　き
5　 お　2　☆　　
6　 か　3　☆　　
7　 き　1　★　　
8　 く　1　　　　
9　 け　2　　　　
10　こ　3　　　　
11

次の[条件付き書式]を設定したセル E2 に配列数式 {=INDEX($A$1:$A$100,SMALL(IF($C$1:$C$100=E$1,ROW(A$1:A$100),""),ROW(A1)))} を入力して、此れを右１列およびズズーッと下方にドラッグ＆ペースト

　　　数式が　　　　=ISERROR(E2)
　　　フォント色　　白

お礼

簡単に出来そうですね。
数式までありがとうございます。

回答No.1

Cupper

関数じゃないね
ピボットテーブルを使うと良い

お礼

ピッポトテーブルを上手く使えれば良いのですが・・・
応用力がないので汎用性に乏しい感じでした。
ありがとうございました。