Find2重使用後のFindNextの使用について

質問

Excel2003にて
シート2に記載されている表のD列の中からFindを使用し、条件に該当するものを検索した後、該当する行のE列の値を取り出し、それを条件にしてシート3のL列をFindを使用し検索する。次に該当した行のQ列の値を取り出し、シート2のH列に記載するといった感じの内容をFindNextを使い繰り返すVBAを組んでいるのですが、FindNextを使用した際に検索結果がNothingになってしまいます。Findを2回使用しているのが原因なんでしょうかね？なにか有効な対策方法はないでしょうか？ご教授願います。

＜イメージ＞
検索条件１：2-1
(シート2)
　　D　　　E　　　　　H
1　2-1　田中　　　兵庫　　←　H列にシート3で検索した住所を記載させたい。
2　2-2　吉田
3 2-3 山田
4　2-1 田上

検索条件2：(シート2で2-1の条件で検索された)田中
(シート3)
　　 L　　　Q
1　吉田　大阪
2　田中　兵庫
3　田上　大阪
4　山田　奈良

＜コード＞
Sub add()
Dim class(1 To 10) As String
class(1) = "2-1"
class(2) = "2-2"
class(3) = "end"

i = 1
Do Until class(i) = "end"
Set objFind = Worksheets(2).Columns("D").Find(class(i), LookIn:=xlValues)
If Not objFind Is Nothing Then
Do Until oldaddress > objFind.Row
class_sh2_YLine = objFind.Row
class_nm = Cells(class_sh2_YLine, "E")
Set objFind2 = Worksheets(3).Columns("L").Find(class_nm, LookIn:=xlValues)
If Not objFind2 Is Nothing Then
class_sh3_YLine = objFind2.Row
class_add = Worksheets(3).Range("Q" & class_sh3_YLine)
Worksheets(3).Rows(class_sh3_YLine).Delete
Worksheets(2).Cells(class_sh2_YLine, "H") = class_add
Else
MsgBox "該当する住所がありません"
End If
oldaddress = objFind.Row
Set objFind = Worksheets(2).Range("D:D").FindNext(objFind)
Loop
End If
i = i + 1
Loop
End Sub

回答No.1

myRange · ベストアンサー

>Findを2回使用しているのが原因なんでしょうかね

Findを何回使ってもいいのですが、FindNextの使い方に間違いがあります。
というより、今回は、FindNextは使えません。
また、他の部分にも若干おかしいところがありますのでちょっこと修正したコードをアップしてみます。

'----------------------------------------------　
Sub add()
　Dim class(1 To 10) As String
　class(1) = "2-1"
　class(2) = "2-2"
　class(3) = "end"

　i = 1

　Do Until class(i) = "end"
　　　Set objFind = Worksheets(2).Range("D:D").Find(class(i), LookIn:=xlValues)
　　　If Not objFind Is Nothing Then
　　　　　OldAddress = objFind.Row

　　　　　Do
　　　　　　　class_sh2_YLine = objFind.Row
　　　　　　　class_nm = Cells(class_sh2_YLine, "E")
　　　　　　　Set objFind2 = Worksheets(3).Columns("L").Find(class_nm, LookIn:=xlValues)
　　　　　　　If Not objFind2 Is Nothing Then
　　　　　　　　　class_sh3_YLine = objFind2.Row
　　　　　　　　　class_add = Worksheets(3).Range("Q" & class_sh3_YLine)
　　　　　　　　　'Worksheets(3).Rows(class_sh3_YLine).Delete
　　　　　　　　　Worksheets(2).Cells(class_sh2_YLine, "H") = class_add
　　　　　　　Else
　　　　　　　　　MsgBox "該当する住所がありません"
　　　　　　　End If

　　　　　　　Set objFind = Worksheets(2).Range("D:D").Find(class(i), objFind)

　　　　　Loop While OldAddress <> objFind.Row
　　　End If

　　i = i + 1
　Loop
End Sub
'---------------------------------------------

（確認事項）
提示のシート２のデータ、Ｄ列には、２－１が２つありますが、それでいいのですね。
ま、FindNextを使っていることから判断すればそれは分かることですが。

さらに言うと、
シート３のＬ列名前には同じ名前はないのでしょうか。
もし、あったらどう処理されるのでしょうか
いまのシート３のレイアウトでは、どちらの名前の県名を取得すればいいのか分かりませんが。

それから、なぜ今回は、FindNextが使えないのかちょと考えてみてください。
詳しくはヘルプ参照のこと。

お礼

すばやい回答ありがとうございました。myRangeさん記載のコードで無事動作しました。
VBは独学＆周りに聞ける人がいないので助かりました。

確認事項について
御察しの通りD列に複数の同一データがあるためにFindNextを使おうと思っていました。

シート3には同一の名前が複数あります。しかし実際のシート3とシート2のデータの順番は同じなので、単純に上から検索しヒットした物を当てはめ、一度検索した行は削除するという方法でやっています。(例では順番はばらばらになっていますが・・・)

FindNextが使用できなかったのは、2回目のFindの検索条件を引きずっているからなのでしょうか？

回答No.2

myRange

上手くいったようで、何より。

>FindNextが使用できなかったのは、2回目のFindの検索条件を引きずっているからなのでしょうか？

そうです。
Set objFind2 = Worksheets(3).Columns("L").Find(class_nm, LookIn:=xlValues)
この２つ目の検査値class_nmでFind（Next）してることになります。

それから、今回のFindメッソドは質問者のコードをそのまま使いましたが、
実際は、引数LookAtもセットしておかないと思わぬ結果になることがあります。

そこらもヘルプに書いてありますのでじっくりと眺めてみてください。

尚、お気づきでしょうが、当方がアップしたコードでは
　'Worksheets(3).Rows(class_sh3_YLine).Delete
これをコメントアウトしてますので、’を削除願います。

お礼

了解です。色々丁寧に回答＆アドバイスしていただき、ありがとうございました。