ブックの終了がうまくいきません

質問

Excel2003 でマクロ作成中の超初心者です。マクロ完成まであと一歩になりました。次から進みません。お願いします。
ブックＡ　ブックＢ　ブックＣの３個のブックがあります。
ブックＡのコマンドボタン→　ブックＢに飛びます。
ブックＢには、フォームコントロール（終了するコマンドボタン）と、特定セルにコントロールが張り付けてあります。

ブックＡ→ブックＢの終了ボタン　→正常に終了します。
ところが、ブックＢのコントロールから、ブックＣに移り、
ここからも一度ブックＢに戻って終了ボタンを押すとＢブックは終了するものの、Ｃブックが閉じられません。なぜでしょうか？

-----Ｂブックのセルに貼り付けたコントロールのマクロ-----
Sub ブックＣへ()
Application.ScreenUpdating = False
Dim wb As Workbook
On Error Resume Next
'開いて作業中の場合。
Set wb = Workbooks("21年計算01.xls")
On Error GoTo 0
If wb Is Nothing Then
Set wb = Workbooks.Open(ThisWorkbook.Path & "\21年計算01.xls")
End If

'開いて作業中の場合。
Workbooks("21年計算01.xls").Activate
ActiveWindow.WindowState = xlMaximized - ---最大化
Worksheets(12).Select
End Sub

-----Ｂブックのフォームコントロールのマクロ-----

Private Sub CommandButton5_Click()
Unload Me
ActiveWorkbook.Close SaveChanges:=True
End Sub

-----Ｃブックのフォームコントロールのマクロ-----
Private Sub データ入力_Click()
Unload Me
Application.ScreenUpdating = False
On Error GoTo err:
Workbooks("21年計算02.xls").Activate
Exit Sub
err:
Workbooks.Open Filename:=ThisWorkbook.Path & "\21年計算02.xls"
'''データ処理.Show
Application.ScreenUpdating = True
End Sub

回答No.7

onlyrom · ベストアンサー

またまたまた、登場、onlyromです。

当方のコードとは違いますよ。
よーく見てください。
先ず、ブックＣをCloseして
次に、ブックＢをCloseしないといけません。

ブックＢ＝■Workbooks("21年計算02.xls")■
ブックＣ＝■Workbooks("21年計算01.xls")■

となっている時に質問者のコードでは、次のようなことが起こります
'--------------------------------------------
Private Sub CommandButton5_Click()
Unload Me
On Error Resume Next
Workbooks("21年計算02.xls").Close True　
On Error GoTo 0

●ブックＢが先にCloseされてるので
ここから以降に書いてあるコードは実行されない、

Workbooks("21年計算01.xls").Close True
End Sub
'------------------------------------------

ようするにコードの書いてあるブックから先にcloseしてしまうと
それ以降のコードは実行されないということです。

で、以下のように、
"21年計算▲０１▲.xls"（ブックＣ）から先にCloseする

'----------------------------------------------
Private Sub CommandButton5_Click()
　Unload Me
　On Error Resume Next
　　　Workbooks("21年計算01.xls").Close True　
　On Error GoTo 0
　　　Workbooks("21年計算02.xls").Close True
End Sub
'---------------------------------------

お試しください。

お礼

あああああなるほど！Ｃブックを閉じてからでないといけないのですか！！！のどの骨がやっととれました。見事に終了することができました。ありがとーーーーうです。感謝感激です。今後ともよろしくお願いします。

回答No.6

mt2008

No.1です。
Cブックが開かれているかを調べて、開いて居たら保存終了。
Aブックをアクティブにして、
最後にBブックをクローズ
こんな流れでよさそうですね。

Private Sub CommandButton5_Click()
　Unload Me
　For Each Work In Application.Workbooks
　　If Work.Name = "C.xls" Then
　　　Workbooks("C.xls").Close True
　　　Exit For
　　End If
　Next
　Workbooks("A.xls").Activate
　Workbooks("B.xls").Close True
End Sub

Aブックが開かれていない場合などは考慮していません。

お礼

今実験しましたら、見事に終了することができました。ありがとうございました。これで思っていることができました。ほかのみなさまもありがとうございました。

回答No.5

onlyrom

またまた登場、onlyromです。

＞ブックＡ＝ランチャーみたいにコマンドボタンの配置
＞ブックＢ＝■Workbooks("21年計算02.xls")■
＞ブックＣ＝■Workbooks("21年計算01.xls")■

で、あれば上手くいくはずです。

ブックＢのWorkbook_BeforeCloseやBeforeSaveイベントなどで
ブックＣのOpenやCloseのキャンセルをしてるとこはありませんか？
ブックＣでも同様。

それから、Unload Me がありますがこれ何をしているのでしょうか。
質問にはUserFormを使っているとは一言も書いてありませんが。。

ま、何れにしろ、実際のコードをアップするのが早道です。
【端折らず】にアップ願います。

補足

わかりました。次のとおりです。

Aブックのボタン
Private Sub CommandButton4_Click()
Application.ScreenUpdating = False
Unload Me
計算2（注　ブックを開くコード）
Worksheets(1).Activate
ActiveWindow.DisplayWorkbookTabs = False
Range("A1").Select
Application.ScreenUpdating = True
End Sub
--------------------------------------------------
Ｂブックのボタン　　先ほど教えていただいたコード
　　　　　　　　　　ただし、21年計算01.xlsは終了できない。
Private Sub CommandButton5_Click()
Unload Me
On Error Resume Next
Workbooks("21年計算02.xls").Close True
On Error GoTo 0
Workbooks("21年計算01.xls").Close True
End Sub
-----------------------------------------------------
Ｂブックのシートに貼り付けたコントロール
Sub 個人Ａへ()
Application.ScreenUpdating = False
Dim wb As Workbook
On Error Resume Next
'開いて作業中の場合。
Set wb = Workbooks("21年計算01.xls")
On Error GoTo 0
If wb Is Nothing Then
Set wb = Workbooks.Open(ThisWorkbook.Path & "\21年計算01.xls")
End If

'開いて作業中の場合。
Workbooks("21年計算01.xls").Activate
ActiveWindow.WindowState = xlMaximized - ---最大化
Worksheets(8).Select　　’シートは20まであり
End Sub
--------------------------------------------------------------
Ｂブックに戻るためにＣブックの戻るボタンに書いたコード
Private Sub データ入力_Click()
Unload Me
Application.ScreenUpdating = False
On Error GoTo err:
Workbooks("21年計算02.xls").Activate
Exit Sub
err:
Workbooks.Open Filename:=ThisWorkbook.Path & "\21年計算02.xls"
Application.ScreenUpdating = True
End Sub
-----------------------------------------------------------------

Ａブックにある終了ボタン
Private Sub CommandButton3_Click()
Application.ScreenUpdating = False
保存して終了
Application.ScreenUpdating = True
End Sub

回答No.4

onlyrom

回答２，３のonlyromです。

質問のコードを見てちょと気づいた点。

ブックＢで、ブックＣ■Workbooks("21年計算01.xls")■を開き
ブックＣで、別ブック■Workbooks("21年計算02.xls")■を開いてますよね。

で、全部開いている状態だと、
ブックＡ，ブックＢ、"21年計算01.xls"、"21年計算02.xls"
の４ブックが開いていることになりますが、
ブックＢのクローズボタンでは、ちゃんとブックＡを除いた３ブックをクローズしていますか？

ブックＣで開いた■Workbooks("21年計算02.xls")■が残ってるのでは？

補足

ブックＡ＝ランチャーみたいにコマンドボタンの配置
ブックＢ＝■Workbooks("21年計算02.xls")■
ブックＣ＝■Workbooks("21年計算01.xls")■

ブックＣで、■Workbooks("21年計算02.xls")■に戻るだけです。。

で、全部開いている状態だと、
ブックＡ，"21年計算01.xls"、"21年計算02.xls"
の3ブックが開いていることになります。

何でこんなことをするかというと、"21年計算01.xls"には２０シートがあり、そこに入力したデータが"21年計算02.xls"にリンクされ
一覧表みたいに集計されるのです。ですから頻繁に21年計算01.xls　と　21年計算02.xlsの間を行き来しなければなりません。
しかも21年計算02.xlsには２０シートへ直行するコントロールボタンを配しています。

ブックＢ　の終了ボタンで計算処理を終了し、Ａブックに戻りそこについている終了ボタンでExcel を終了します。

回答No.3

onlyrom

＞Ｂブックが閉じた瞬間にＣブックが現れＣブックを閉じることができませんでした

実際のコードを見ないとコメントのしようがありませんので
実際のコードをアップして下さい。

みんなで解決しましょう。

補足

ありがとうございます。質問欄に書いたコード以外に表示すべきコードはないとおもうのですが・・・。

回答No.2

onlyrom

＞開いているいないに拘わらず、ＣブックもCloseしてやればいいのでは？

'----------------------------------
　On Error Resume Next
　　　Workbooks("C.xls").Close True
　On Error GoTo 0
　　　Workbooks("B.xls").Close True
'----------------------------------

補足

今Ｂブックに上のマクロを貼り付けて実行しましたところ、Ｂブックが閉じた瞬間にＣブックが現れＣブックを閉じることができませんでした。どうしてか不思議です。

回答No.1

mt2008

Bブックの閉じるボタンを押した時の処理が、「アクティブなブックを保存終了」になっているため、アクティブなBブックだけを保存終了しています。
ここを、「アクティブなブックを保存」+「アプリケーション(Excel)を終了」にして見てください。

Private Sub CommandButton5_Click()
　Unload Me
　ActiveWorkbook.Save 'アクティブなブックを保存
　Application.Quit 'アプリケーション(Excel)を終了
End Sub

補足

説明不足で申し訳ありません。
Ｂブックの終了ボタン単独ですと、Ｂブックの終了ができＡブックに戻ります。Ｂブックから一旦Ｃブックに飛び、またＢブックに戻った時に、Ａ・Ｂ・Ｃブックが開いています。このときＢブックの終了ボタンでＢ・Ｃブックを同時に閉じ、Ａブックに戻りたいのです。
Ｂブックの終了ボタンに
１）Ｃブックが開いていないときはすぐＢブックを終了し、Ａブックを表示。
2）Ｃブックが開いている時はＢブックとＣブックを終了し、Ａブックを表示。
という条件マクロを作りたいのです。よろしくお願いします。