VBAに関して

質問

VBA超初心者の者ですが、ある一つのシートにいくつかの別のファイルを開いて順にコピーして貼り付けていくというプログラムを作成したいと思っています。
Sub naka()
Dim k As Integer
Dim r As String

k = InputBox("ファイル数を記入してください")
r = InputBox("範囲を指定してください")
Call s1(k, r)
End Sub

Sub s1(i As Integer, rangearea As String)

Dim v As Integer
Dim x As String
For v = 1 To i
Dim OpenFileName As String
With OpenFileName = Application.GetOpenFilename("Microsoft Excelブック,*.xls")
ThisWorkbook.Sheets(1).Range("rangearea").Copy
ActiveSheet.Range("1+(rangearea.rows.count*(v-1)),1").PasteSpecial
End With
Next v
End Sub
こんな感じでかいてみたものの全く異なったものをかいているようです。同じフォルダ内にコピーするファイルが存在しているものと仮定していますが、マイ　ドキュメント内のファイルとしたいです。コピーすべきシートは１としています。大変分かりづらい文章ですが、おかしい部分の指摘、見本等示していただけたらありがたいです。

回答No.1

n-jun · ベストアンサー

Sub test()
Dim wb As Workbook
Dim r As Range, rr As Range
Dim i As Integer, v As Integer
Dim OpenFilename As String

Set rr = ThisWorkbook.ActiveSheet.Range("A1")

i = Application.InputBox("ファイル数を記入してください", Type:=1)
Set r = Application.InputBox("範囲を指定してください", Type:=8)

For v = 1 To i

OpenFilename = Application.GetOpenFilename("Microsoft Excelブック,*.xls")
Workbooks.Open Filename:=OpenFilename
Set wb = ActiveWorkbook
wb.Worksheets(1).Range(r.Address).Copy rr
Set rr = rr.Offset(r.Rows.Count)
wb.Close False

Next
End Sub
こうゆう事とは違いますか？

お礼

ほしかったものを得ることができ、また、VBA超初心者の私にとっては非常に勉強になりました。ご協力ありがとうございました。