excelでデータの並び替えができません。

質問

こんばんは。
エクセルについて、データの並び替えがうまくできず、悩んでいます。

以下のように、A列がキーになっているデータがあります。

A列 | B列
uni　|　1
uni　|　2
ika　|　11
ebi　|　21
ebi　|　22
ebi　|　23

これを、以下のように、キーごとにグルーピングして、さらに縦→横に並べたいと考えています。

C列 | D列 | E列 | F列・・・
uni　|　1　|　2
ika　|　11
ebi　|　21　|　22　|　23

キーとなるA列のデータは、1個のときがあれば複数個の時もあり、
関数を駆使して頑張ってみたのですが、うまく出来ませんでした・・・。

良い方法がありましたら、教えていただけないでしょうか？？
宜しくお願いします。

回答No.1

mitarashi · ベストアンサー

dictionary（最近の回答はこればっかりですが．．．）の使用例です。連想配列という立派な名前がある事を最近知りました。今日は出先の、Excell2007環境で作成しておりますが、動作いたしました。
追加の情報は、VBA dictionaryで検索すると、結構ヒットすると思います。
Sub test()
Dim targetRange As Range, destRange As Range
Dim myDic As Object, myKey As Variant
Dim i As Long, j As Long
Dim keyString As String
Dim area As Range
Dim myCell As Range

Set targetRange = ActiveSheet.Range("A1").CurrentRegion
Set myDic = CreateObject("Scripting.Dictionary")
For i = 1 To targetRange.Rows.Count
keyString = targetRange.Cells(i, 1).Value
If Not myDic.exists(keyString) Then
myDic.Add keyString, targetRange.Cells(i, 2)
Else
Set myDic.Item(keyString) = Union(myDic.Item(keyString), targetRange.Cells(i, 2))
End If
Next i
myKey = myDic.keys
Set destRange = ActiveSheet.Range("F1")
For i = 0 To myDic.Count - 1
j = 1
For Each area In myDic(myKey(i))
For Each myCell In area.Cells
destRange.Value = myKey(i)
destRange.Offset(0, j).Value = myCell.Value
j = j + 1
Next
Next area
Set destRange = destRange.Offset(1, 0)
Next i
Set myDic = Nothing
End Sub

お礼

mitarashi様、こんにちは。

すごーいっ、一発で出来ました！
まさに期待したとおりの動きです。

Excelは使わない日はないのに、ちょっと難しいことにぶつかると、途端にできなくなってしまいます。

キー数が不特定なので、ループを使わないといけないのかな、
ということは、Excel関数の組み合わせでは実現できないのかな、と薄々思っていましたが、
VBAも勉強しないと、とあらためて思いました。

本当に助かります。
ありがとうございました☆

回答No.2

mitarashi

ANo.1です。最後の方のループが変でしたので、差し替え願います。（同じ見出しを何度も上書きしていた）
For i = 0 To myDic.Count - 1
j = 1
destRange.Value = myKey(i)
For Each area In myDic(myKey(i))
For Each myCell In area.Cells
destRange.Offset(0, j).Value = myCell.Value
j = j + 1
Next
Next area
Set destRange = destRange.Offset(1, 0)
Next i

お礼

再び回答くださったループ処理部分を差し替えて、試させていただきました。

朝早くから外出しているのに、mitarashi様のほうで動作も確認してくださって、
本当にありがとうございました☆