エクセル、セーブ時自動でVBAを動かすには？

質問

エクセルのVBAモジュールに以下のマクロを登録してあります
Sub マクロ１()
　　 　Cells.Select
　　 ActiveSheet.Unprotect
　　 Selection.Locked = True
　　 Selection.FormulaHidden = False
　　 ActiveSheet.Protect
End Sub

シートに書き込みを禁止するようにしてあるのですが、
シートの枚数が20枚以上有って、どのシートをきちんと
保護したか分からなくなってきて、不便なのですが、
複数に渡るシートに対して、セーブしたときに上の保護が
かかるようにするにはどうすればいいですか？
もしくは、一つのシートの上で複数のシートに対して
保護をかけていくにはどのようにすればいいのでしょうか？
VBAの書き込む場所なども、sheetなのか、bookなのか、
モジュールなのかも教えていただければと思います。

回答No.1

KenKen_SP · ベストアンサー

ThisWorkbook モジュールで BeforeSave イベントを使います。
サンプルは保護にパスを使っていない前提です。

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)

　　Dim Sh As Worksheet
　　For Each Sh In ThisWorkbook.Worksheets
　　　　Sh.Unprotect
　　　　With Sh.Cells
　　　　　　 .Locked = True
　　　　　　 .FormulaHidden = False
　　　　End With
　　　　Sh.Protect UserInterfaceOnly:=True
　　Next

End Sub

お礼

ありがとうございます。
早速使わせていただきました。ありがとうございますー。
ちなみに、モジュール上で複数のシートを操作するのは
複雑になってしまうのでしょうか？

回答No.3

KenKen_SP

> モジュール上で複数のシートを操作するのは
> 複雑になってしまうのでしょうか？

モジュール上とは「標準モジュール」という意味ですか？

Save 時に自動実行する必要がなければ、そのまま標準モジュール
に同一内容のコードを置くだけです。

Sub ProtectAllSheets()

　　Dim Sh As Worksheet
　　For Each Sh In ThisWorkbook.Worksheets
　　　　Sh.Unprotect
　　　　With Sh.Cells
　　　　　　 .Locked = True
　　　　　　 .FormulaHidden = False
　　　　End With
　　　　Sh.Protect UserInterfaceOnly:=True
　　Next

End Sub

#1 は Save 時に自動実行するため、ThisWorkbook モジュールで
BeforeSave イベントを使ってます。これはイベントプロシージャ
といって、特別な意味があるものです。

標準モジュールに置く場合は、今回のコードは引数も不要ですし、
プロシージャ名は変更した方が良いでしょう。

お礼

なるほど、そういうことなのですね。
beforesaveイベントだからと言って書き方が
変わるわけではないのですね。
勉強になりました。
ありがとうございますー

回答No.2

x0000x

No1の方が記入した処理ですでにBOOK内の全シートを対象にしてます。

For Each Sh In ThisWorkbook.Worksheets

お礼

（^^ゝ
了解しましたー
ありがとうございますー