こんな事が出来る関数はありますか？

質問

エクセル２００３を使用しています。
数字を合計していって、それぞれ一万、二万、三万ときりのいい数字を越えたところでその数を表示するようにしたいのです。たとえば、
　Ａ　　　　　Ｂ
1　6500
2　3580　　　10080
3　2000
4　7000　
5　5000　　　24080

Ａ１～Ａ５に入力した時にＢ２，Ｂ５を表示させたいのです。
そのような関数は、ありますでしょうか？
数字を累計していくのでＢのどこのセルでその数を越えるのかは、そのたびに変わることになります。
初心者ですので、わかりやすく教えていただけるとありがたいです。

回答No.2

imogasi · ベストアンサー

A2:C９　（第１行目のC1は空白にする）
A列　　B列　　　　C列
8000 8000
3000 11000 11000
3000 14000
5000 19000
6000 25000 25000
6000 31000 31000
4000 35000
8000 43000 43000
A列元データ
B列累積値
式はB2に=SUM($A$2:A2)　下方向に複写。
C列が求めるもの
C2の式　=IF(B2>=(INT(MAX($C$1:C1)/10000)+1)*10000,B2,"")
と入れて最終行まで式を複写。
B列作業列を入れているが、なくして
=IF(SUM($A$2:A2)>=(INT(MAX($C$1:C1)/10000)+1)*10000,SUM($A$2:A2),"")
とすれば、なくせる。
多分質問は、＃１のご回答よりこっちのほうでしょう。

お礼

そうです、そうです。
まさに、Ｃ列のように表示させたかったのです。
ＩＮＴの関数がどのようなものかちょっと勉強してこの式を使ってみようと思います。
ありがとうございました。

回答No.3

maron--5

◆こんな方法もありますよ
B1=IF(A1>=10000,A1,"")
B2=IF(INT(SUM($A$1:A2)/10000)-INT(SUM($A$1:A1)/10000)=1,SUM($A$1:A2),"")
★B2の式を下にコピー

お礼

回答ありがとうございます。
色々な考え方があるんですね。
ＮＯ.２の方の式とあわせて、お答えの式も試してみようと思います。

回答No.1

mshr1962

B2に
=IF(INT(SUM($A1:A2)/10000)>INT(SUM($A1:A1)/10000),SUM($A1:A2),"")
として下方にコピーしてください。

お礼

回答ありがとうございました。
早速試してみます。