Excel VBE 検索結果がない時の対処方法

質問

いつもお世話になっております。
Excelで簡単な文字当てゲーム的なものを作っています

文字列（１００個程度）の中から、ある文字列を探し出して、そのセルの文字色を塗り替えるというマクロを組んでいます。
検索部分は下記のように記述してあります。
検索文字列がある時にはうまく動作しますが
検索文字列がない時にはエラーになります。
検索文字列がない時の対処方法を教えて下さい。
よろしくお願いします。

kaitou = Range("g2").Value
Range("G2").Select
Selection.Copy

Columns("B:B").Select
Selection.Find(What:=kaitou, After:=ActiveCell, LookIn:=xlFormulas, _
LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
MatchCase:=False, MatchByte:=False, SearchFormat:=False).Activate

回答No.1

hana-hana3 · ベストアンサー

＞検索文字列がない時にはエラーになります。

エラー処理をしましょう。
エラーを無視するだけで良いなら、On Error Resume Next とします。

http://www.geocities.co.jp/Technopolis/2082/Soft/Excel_b.htm#errorroutine
http://www.k1simplify.com/vba/tipsleaf/leaf242.html

Sub test()

kaitou = Range("g2").Value

On Error GoTo errJob

Columns("B:B").Select
Selection.Find(What:=kaitou, After:=ActiveCell, LookIn:=xlFormulas, _
LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
MatchCase:=False, MatchByte:=False, SearchFormat:=False).Activate

errJob:

If Err.Number <> 0 Then
If Err.Number = 91 Then
MsgBox "検索値" & "[" & kaitou & "]が見つかりません。"
Else
MsgBox "エラーが発生しました。"
End If
Else
MsgBox "[" & kaitou & "] が見つかりました。"
End If

End Sub

お礼

早速の回答ありがとうございました。うまく動作しました

回答No.2

Wendy02

こんにちは。

こんな感じかしら？

>検索文字列がない時の対処方法を教えて下さい。

一旦、Range型の変数で受けて、変数が空かどうかを調べます。
ただし、入力が数字の場合は、LookAt:=xlPart　は、不向きです。

以下は、イベント・ドリブン型にしましたので、G2 を入れるとマクロが動きます。少し、気になる点も残っていますが、B列に同じものがなければ、問題はないと思っています。

'シートモジュールに入れてください。
Private Sub Worksheet_Change(ByVal Target As Range)
Dim r As Range
If Target.Address <> "$G$2" Then Exit Sub　　'除外条件
If IsEmpty(Target.Value) = True Then Exit Sub　'除外条件
Columns("B:B").Interior.ColorIndex = xlNone
Application.EnableEvents = False
Set r = Columns("B:B").Find(What:=Target.Value, _
　　　　　　　　　　　 LookIn:=xlValues, _
　　　　　　　　　　　 LookAt:=xlPart, _
　　　　　　　　　　　 SearchOrder:=xlByRows, _
　　　　　　　　　　　 SearchDirection:=xlNext, _
　　　　　　　　　　　 MatchCase:=False, _
　　　　　　　　　　　 MatchByte:=False, _
　　　　　　　　　　　 SearchFormat:=False)

　　If r Is Nothing Then
　　　　MsgBox "見つかりません", vbInformation
　　Else
　　　　r.Interior.ColorIndex = 34 '薄い水色
　　End If
Application.EnableEvents = True
End Sub