エクセルで曜日指定のセル連続データを作りたい

質問

ウィンドウズ版のエクセル９７を使ってます。
曜日指定の日付の入ったセルを作りたいのですが、セルの連続データのフィルハンドルでうまく行きません。簡単に出来る方法を教えて下さい。
具体例　　 ２月　２日(土)
　　　　　　２月　５日(火)
　　　　　　２月　７日(木)
　　　　　　２月　９日(土)
　　　　　　２月１２日(火)
　　　　　　２月１５日(木)
　　　　　　２月１７日(土)
　　　　　　　　・
　　　　　　　　・
　　　　　　　　・

回答No.6

nishi6

#2 は日付書式の質問と勘違いしていました。日付が飛んでいましたね。
質問の曜日間隔は例だと思いますので、自由に曜日指定できるようユーザー定義関数を作ってみました。

最初のセル（例えばA1）に最初の日付を入れます。
その下のセル（A2になります）に例えば =youbiFil(A1,"火","木","土") とします。

ユーザー定義関数の引数は、参照するセル、曜日サイクルです。
曜日サイクルは、『"火","木","土"』のように設定します。
『"月","火","水","木","金"』なら土日は出ません。『"土"』しか設定しなければ土曜日しか出しません。
３つ目の日付以降はフィルハンドルを引っ張れば出てきます。列方向もできます。

Public Function youbiFil(rgUp As Range, ParamArray myYoubi())
　　'曜日のパターンを登録していなければ何もしない
　　If UBound(myYoubi) < 0 Then
　　　　youbiFil = "": Exit Function
　　End If

　　Dim yb As Integer '前のセルは指定した曜日サイクルの何番目？
　　Dim maeYoubi As Integer '前のセルの曜日
　　Dim curYoubi As String 'カレントセルの曜日
　　Dim curDay As Date 'カレントセルの日付
　　'最初の日付の曜日が、指定した曜日サイクルと違っていれば何もしない
　　maeYoubi = -1
　　For yb = 0 To UBound(myYoubi)
　　　　If myYoubi(yb) = Format(rgUp, "aaa") Then
　　　　　　maeYoubi = yb
　　　　　　Exit For
　　　　End If
　　Next
　　If maeYoubi = -1 Then youbiFil = "": Exit Function

　　'前のセルの曜日の次は曜日サイクルのどこにあるか調べる
　　If maeYoubi < UBound(myYoubi) Then
　　　　curYoubi = myYoubi(maeYoubi + 1)
　　Else
　　　　curYoubi = myYoubi(0)
　　End If
　　'曜日が一致するまで日付を進める
　　curDay = rgUp + 1
　　While Format(curDay, "aaa") <> curYoubi
　　　　curDay = curDay + 1
　　Wend
　　youbiFil = curDay
End Function

お礼

ありがとうございました。
未熟者なのでまた質問をした時は、宜しくお願い致します。