表から列と行を指定してその中から値を抽出する式

質問

なかなか言葉で説明しにくいのですが、エクセルの関数で、ある表の列と行を指定してその中から値を抽出する関数はあるでしょうか？
具体的に言うと、行が地域（北海道、東北、関東、、、）で列が箱数（1箱、2箱、3箱、、、）となっている表があってどの地域に何ケース届けると何円になるという表があります。
別シートに表を作って、例えば任意のセルに「北海道」、次の列に「2箱」などと入力規則で入力するようなところを作りました。そして、それぞれ「北海道」、「2箱」というのを見て、そのまた次の列に何円かを抽出する関数を入れたいと思っています。。。それが難しくて分かりません。有用な関数があったら教えてください。具体例などがあればURLなど教えていただけると助かります。
VLOOKUPなどがそれに近いかと思いますが、どうもうまくいきません。複合的に使えばうまくいくでしょうか？
よろしくお願いいたします。

回答No.4

EL-SUR · ベストアンサー

INDEX関数とMATCH関数、またはVLOOKUP関数とMATCH関数の組み合わせが一般的です。

元表が Sheet1の A1：F10の範囲の表で
地域が A2：A10
箱数が B1：F1にあるとして

Sheet2の A2セルに地域名、B2セルに箱数を入れ、C2セルに結果を出すとします。

Sheet2のC2：
■ VLOOKUP関数
=IF(COUNTA(A2:B2)<2,"",VLOOKUP(A2,Sheet1!$A$1:$F$10,MATCH(B2,Sheet1!$A$1:$F$1,0),FALSE))

■ INDEX関数
=IF(COUNTA(A2:B2)<2,"",INDEX(Sheet1!$B$2:$F$10,MATCH(A2,Sheet1!$A$2:$A$10,0),MATCH(B2,Sheet1!$B$1:$F$1,0)))

↓を参考にしてください。
http://homepage1.nifty.com/kenzo30/ex_kisotyu/ex_ks_tyukyu9_9_7.htm#検索/行列関数（INDEX関数）

お礼

ありがとうございます。
いろいろやり方があるんですね。
助かりました！

回答No.5

noname#204879

１．任意のシートに（例えば）下表を作成
　　　　　 北海道　東北　関東
　　　1箱　1000　　 800　 600
　　　2箱　1800　　1500　1100
　　　3箱　2500　　2200　1400

２．上表において、範囲全体に table、上端行に region、左端列に qnty という
　　名前をそれぞれ定義

３．任意のシートにおいて、地域、数量、価格を下表のように配置すれば
　　　　　 A　　　B　　 C　　　D
　　　1　地域　　数量　価格
　　　2　北海道　 3箱　2500
　　　3
　　セル C2 に次式を入力すればＯＫかと。
　　=INDEX(table,MATCH(B2,qnty,0),MATCH(A2,region,0))

お礼

ありがとうございます。
いろいろやり方があるんですね。
助かりました！

回答No.3

noname#15567

仮に、表の北海道、東北、関東、、、が入ったセル範囲に「地域」、
　表の1箱、2箱、3箱、、、が入ったセル範囲に「箱数」、
　表の左上の角のセル（北海道の上で、かつ、１箱の左）に「表左上」、
　地域を入力するセルに「入力_地域」、
　箱数を入力するセルに、「入力_箱数」
と名前を定義したとすると、
=OFFSET(表左上,MATCH(入力_地域,地域,0),MATCH(入力_箱数,箱数,0))
で出ると思います。

お礼

ありがとうございます。
いろいろやり方があるんですね。
助かりました！

回答No.2

imogasi

ＩＮＤＥＸ関数やＯＦＦＳＥＴ関数があります。ＯＫＷＡＶＥでも質問の回答にも良く出てきます。私も昨日ＩＮＤＥＸ関数を使って回答しました。
ＶＬＯＯＫＵＰ関数のだい３引数を相対化（変数化）すればできるかも知れない。
例データ　Ａ１：Ｄ６
１０箱 ２０箱 ３０箱
北海道 100 150 250
東北 90 140 230
信越 80 130 200
関東 70 100 180
中部 80 140 200
Ａ１１に地区
Ｂ１１に個数を入れると
Ｃ１１に式
=VLOOKUP(A11,$A$2:$D$6,B11/10+1,FALSE)
を入れる。
Ａ１１　Ｂ１１　Ｃ１１に
関東 30 180

のように求められます。
都合の良い例にしてルところはありますが、例えばの例です。

お礼

ありがとうございます。
いろいろやり方があるんですね。
助かりました！

回答No.1

aco_michy

index関数があります。
関数の種類で「検索／行列」の中にあります。

お礼

ありがとうございます。
いろいろやり方があるんですね。
助かりました！