Excelのシート移動

質問

初めまして。エクセル超初心者です。

　早速ですが、ここにBook1とBook2の二つのブックがあるとします。Book1で現在参照しているSheetをBook2の例えばSheet2の前に移動、というマクロ(VBA?)を作成し、ボタン一つで移動するようにしたいのですが、どの様にすればよいのでしょうか。お教えください。

回答No.4

Wendy02 · ベストアンサー

こんにちは。

単独で使ってみたかったら、

Private Sub ShCopy()のPrivate をとって
Sub ShCopy()　

を使ってみてください。シートの移動自体は、簡単なコードです。しかし、

＞ボタン一つで移動するようにしたいのですが

とお書きになっていますが、そのボタンをシート上に置くわけにはいきません。したがって、ツールバー、メニューバーになります。手動でつけることも可能ですが、それでは、ブックに常時残ってしまいます。それで、臨時でコマンド・ボタンをメニューに乗せるように、#3で私が考えました。

いずれにしても、#3の回答に対するお礼のご様子では、手動でされたほうがよいのではありませんか？しょせん、こういう掲示板で発表されるのは、完璧というような作りのコードではなく、ある程度、ユーザーに、その使用を託されているものですから、その理解の度合いに関わらず、VBAの利用は、良く考えてお使いになるのが懸命かと思います。

回答No.3

Wendy02

こんにちは。

エラーが出るのは、
Workbooks("Book2.xls") とファイル名が入っていないからだと思います。

私も作ってみました。「移動元のシート」の標準モジュールに貼り付けたら、保存して、そのブックを閉じたら、再度、立ち上げます。

メニューの右端に[電球]アイコンがつくと思いますから、それをクリックしてください。
なお、以下は、「実際のファイル名」、「シート名」を必ず入れてください。

また、マクロを起動させずに立ち上げる場合は、シフトキーを押しながら開くと、ボタンが設定されません。その登録したブックを閉じると、[電球]もなくなります。

'------------------------------------------------------
Option Explicit
Sub AddButton()
　Dim cnt As Integer
　On Error Resume Next
　Application.CommandBars("Worksheet Menu Bar").Controls("シート移動").Delete
　On Error GoTo 0
　cnt = CommandBars("Worksheet Menu Bar").Controls.Count
　With Application.CommandBars("Worksheet Menu Bar").Controls.Add( _
　　Type:=msoControlButton, ID:=2950, Before:=cnt + 1, _
　　Temporary:=True)
　　.Caption = "シート移動"
　　.FaceId = 351
　　.OnAction = "ShCopy"
　End With
End Sub
Private Sub ShCopy()
　Dim BkName As String, ShName As String, wb As Workbook, flg As Boolean
　'===========================
　'要設定:コピーされる側のブック名とシート名
　BkName = "Book2.xls"
　ShName = "Sheet2"
　'===========================
　If ActiveWorkbook.Name <> ThisWorkbook.Name Then MsgBox _
　"コピー元のブックを開いてください": Exit Sub
　For Each wb In Workbooks
　　If wb.Name = BkName Then
　　　flg = True
　　　Exit For
　　End If
　Next wb
　If flg = False Then
　　On Error GoTo ErrHandler
　　Workbooks.Open (BkName)
　End If
　Application.ScreenUpdating = False
　ActiveWorkbook.ActiveSheet.Move _
　Before:=Workbooks(BkName).Worksheets(ShName)
　Application.ScreenUpdating = True
　Exit Sub
ErrHandler:
　MsgBox "Err: " & BkName & "が開くことができません。"
End Sub
Sub DelButton()
On Error Resume Next
Application.CommandBars("Worksheet Menu Bar"). _
　Controls("シート移動").Delete
End Sub
Sub Auto_Open()
　Call AddButton
End Sub
Sub Auto_Close()
　Call DelButton
End Sub
'------------------------------------------------------

お礼

ありがとう御座います。しかし初心者の私にはこれが何を意味するVBAなのかよく分かりません。いずれ使わせて頂くと思います。勉強してから。

回答No.2

masa_019

No.1さんに補足しますが、
ActiveSheet.Move Sheet2
だと、同じブック内の移動になります。

移動させるためのマクロがBook1に書いてあるなら、

ActiveSheet.Move Before:=Workbooks("Book2").Sheet2

のようになりますね。

お礼

ありがとう御座います。記載頂いたものを入力しましたが、
「インデックスが有効範囲にありません」と表示されてしまいます。何がいけないのでしょう。
それから、「移動させるためのマクロがBook1に書いてあるなら」とはどういう意味ですか？

回答No.1

shkwta

シート「あ」をシート「い」の前に移動するなら、
Sheets("あ").Move Sheets("い")

ということで、現在参照しているシートをSheet2の前に移すなら、
ActiveSheet.Move Sheet2
となります。