エクセル 数式を表示させるには？

質問

win2000　エクセル2000を使用しています。

下記のようにセルAとBに数字が入ってるセルがあり、
Cに合計結果、Dに数式の内容を表示させたいのです。

=A1+B1という表示ならツール→オプションでできるみたいなのですが、数式の内容を表示させるやりかたがわかりません。
どなたかご教授をお願いします；；

　　A　　 B C D
1 数字　数字　合計　式
2 30 　 15 　 45　 30+15=45
3

回答No.4

maruru01 · ベストアンサー

こんにちは。maruru01です。

以下の方法で。
まず、D2を選択して、メニューの[挿入]→[名前]→[定義]で、
[名前]：適当な名前（仮に「数式」とする）
[参照範囲]：「=SUBSTITUTE(GET.CELL(6,C2),"$",)&LEFT(NOW(),0)」
として、[OK]します。
次に、D2に、

=REPLACE(SUBSTITUTE(SUBSTITUTE(数式,SUBSTITUTE(CELL("address",A2),"$",),A2),SUBSTITUTE(CELL("address",B2),"$",),B2),1,1,)&"="&C2

と入力します。
これで、実際の数値を用いた数式が表示されます。
これを下の行へコピーすれば、各行のC列の数式が実際の数値で表示されます。

お礼

できました！！
希望どおりの結果です！＞＜

本当にありがとうございました_(__)_

回答No.5

subri

私もこんな時にマクロ関数はよく使います。
#4の方と似ているかな、と思いますが、一応書かせていただきます。

1行目が見出しだとします。
D2を選択し（この位置関係は大切です）、
挿入→名前→定義
名前　　　　sushiki　　　
参照範囲　　=GET.CELL(6, !C2)&TEXT(NOW(),"")

=GET.CELL(6, !セル番地)　で、そのシートのそのセル番地に入っている数式が
文字として戻ります。
TEXT(NOW(),""　は、どこかの値が書き換えられた時にすぐ再計算が行われるための仕掛けです。

D2に
=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(sushiki,"A"&ROW(),A2),"B"&ROW(),B2),"=","")&"="&C2

C2の数式の「A＆行番号」という文字を「A＆行番号」のセルに入っている数値に置き換え、
更にその結果の「B＆行番号」という文字を「B＆行番号」のセルに入っている数値に置き換え、
最後にその結果の「=」という文字を「""」に置き換える。

こんな感じです。

回答No.3

kappa_neko

最初に「'」を入れると、それ以降はそのまま表示されますよ。

例：
'30+15=45

補足

式は手入力ではなく、自動でセルC3に入っている数式を表示させたいのです。

件数が膨大なため、手入力すると時間がかかりすぎるので。。。；

回答No.2

nice-guy7762

=TEXT(A2,0)&"+"&TEXT(B2,0)&"="&TEXT(C2,0)
TEXTは数字を文字列に変換します。＆は文字列をつなぐ演算子、””で囲まれた文字はそのまま表示されます。

補足

下記補足のとおりです。
せっかくお答えいただきましたのに、申し訳ありません。

回答No.1

taocat

こんにちは。

　D2　に以下の式を

　= A2 & "+" & B2 & "=" & C2

以上です。

補足

説明不足が悪くて申し訳ありません。

数式は必ずしも、足し算とはかぎらないので、
"+"を＆でつなげることはできないのです。

掛け算なら、30*15=450
足し算なら、30+15=45
引き算なら、30-15=15

という風に表示させたいのです。。。