EXCELで時間の計算方法は？

質問

9時から1時間後、1時間半後を計算式を使ってあらわすときはどうすればいいのですか？
＝９：00＋１　では正しく表示されないのです。

回答No.5

tascany · ベストアンサー

簡単なのがあります。
1＝24時間なので、「＝9/24+1/24」でOKです。
ただし、セルの書式設定で表示形式として時刻を選んでおくこと。

お礼

ありがとうございます。これ簡単ですね。

回答No.9

maruru01

こんにちは。maruru01です。

あらかた出てるのでちょっとだけ。
A1に時間（9:00など）、B1に経過時間数（1.5など）が入力されている場合の別解。

=A1+B1*"1:0"

「*"1:0"」は、No.5の方の回答の「/24」と同じことです。

なお、今回は問題ないかも知れませんが、TIME関数とHOUR関数は、24時間超には対応出来ません。
一応、頭の片隅に置いておいて下さい。

お礼

わかりました。ありがとうございます。

回答No.8

DoragonFang

＃７のDoragonFangです。自己レスです。
済みません。
Ｂ列の式が間違ってました。
=TIME(9+A2,(A2-INT(A2))*60,0)
です。
単純には計算してくれないですね。
引数の小数点以下は切り捨てられるようです。
TIME(9.5,0,0)も9:00となるようです。

回答No.7

DoragonFang

EXCELは日付・時間も数字として内部データを持ちます。
その単位は”日”で、１は１日、２は２日に当たります。時間は２４時間ですから＃５で答えてられるように１／２４＝０．０４１６６・・・となります。
なので、数字として計算しようとすると「９：００」＋１時間は ０．３７５＋０．０４１６６・という計算をしていることになります。
＝９：００＋１ではないですよね。

従って、回答としてはすでに他の方が答えれている通りです。

例えば、
Ａ列に何時間後ということで、（２行目から）1、1.5、2、2.5、3・・・と数字が並んでいたとすると、
Ｂ列に（Ｂ２セルから）
=TIME(9,0,0)+TIME(0,A2,0)
と入力してＢ３以下にコピーすれば、９：００から、１時間後、1.5時間後、２時間後、の各時間が得られます。
もちろん、書式設定でhh:mmにすることをお忘れなく。

お礼

ありがとうございました。１時間は２４時間分の１なんですね。

回答No.6

el2368

ひとつのセルの中で、数式を入れて計算する場合、
=9:00+1は
=TIME(9,0,0)+TIME(1,0,0)
で計算できます。
1時間半後は、
=TIME(9,0,0)+TIME(1,30,0)
です。
あとは好きな表示形式に変えてください。

関数：TIME(時,分,秒)です

お礼

ありがとうございました。

回答No.4

imogasi

=9:00+"1:00"は上手く行かなかった。
="9:00"+"1:00"は10：00になる。
またはＡ１に9：00、Ｂ１に1：00なら=A1+B1で10：00
です。

お礼

ありがとうございました

回答No.3

yuu_yuu

こういうことでしょうか。。。

A1のセルに「18:45」
B1のセルに「1」(時間)

が入力されていて

D1のセルに「19:45」という計算結果を表示させたい？

だとすれば。
D1のセルに「=TIME(HOUR(A1)+B1,MINUTE(A1),)」
とすればよいと思います。

蛇足：C1のセルに「30」(分)
　　　が入力されていて分も足したい場合は、
　　　「=TIME(HOUR(A1)+B1,MINUTE(A1)+C1,)」
　　　とすれば、「20:15」という結果が得られます。

お試し下さい。

お礼

ありがとうございました

回答No.2

KenKen_SP

="9:00"+"1:00" でもOKですが、

=TIMEVALUE("9:00")+TIMEVALUE("1:00")
の方が好ましいかも。

セルで計算する場合、

A1:　9：00　B1:　1：00　C1:=A1+B1　で　10:00

すべて表示形式は時刻にして下さい。

ちなみに、1時間半後は
B1：　1：30
ですね。

お礼

ありがとうございました

回答No.1

bin-chan

一時間後：=9:00 + "1:00"
一時間半後：=9:00 + "1:30"

結果が２４時間を越える場合は表示形式を変更ください。
ユーザ設定で [h]:mm

お礼

ありがとうございました