エクセルＶＢＡで Cancel=Trueの使い方

質問

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address <> "$A$1" Then Exit Sub
Cancel = True
MsgBox "キャンセルしました"
End Sub

Private Sub Worksheet_Deactivate()
Cancel = True
MsgBox "キャンセルしました"
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Cancel = True
MsgBox "キャンセルしました"
End Sub

以上のように使ってみましたが、どれも「キャンセルしました」とメッセージは出るものの、直前の操作（入力、シート切替、セル移動）はキャンセルされませんでした。
どこが間違っているのでしょうか？

回答No.5

shishishishi · ベストアンサー

> セルへの入力を取り消す場合でいいです。
> たとえば、A１に５と入っていたのに３を入力されたので、５（というか以前の値）にもどす。

それでしたらこれが一番簡単な方法ではないでしょうか？3が入力されたらUndoしちゃうんです。

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address <> "$A$1" Then Exit Sub
If Target.Value = 3 Then
Application.Undo
'MsgBox "キャンセルしました"
End If
End Sub

お礼

これこそ求めていた答えです。
ありがとうございました。

回答No.6

taocat

No5shishishishi殿

そうか、Undoがありましたね。
思い出させてくれて感謝します。
これからも目から鱗の回答期待しております。

それから、この質問あってのこと、
ということでerror123さんにも感謝せねば。

お礼

> ということでerror123さんにも感謝せねば。

あははは。
質問して感謝されちゃった♪

回答No.4

taocat

こんばんは。

簡単の為に、
Ａ１に、３を入力したらそれをキャンセルして、
Ａ１の値を元に戻すコードです。

Option Explicit

Dim W

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address = "$A$1" Then
If Target.Value = 3 Then
MsgBox "３は入力禁止。キャンセルします"
Application.EnableEvents = False
Target.Value = W
Target.Activate
Application.EnableEvents = True
End If
End If
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Target.Address = "$A$1" Then
W = Target.Value
End If
End Sub

上記のコードをSheet1（どのSheetでも可）のモジュールにコピペし、

（１）先ず、Ａ１に、３以外の数字を入力
（２）次に、３を入力すると「３は禁止」のメッセージ
（３）その後、Ａ１の値が元に戻る

こんなんでええですか？

お礼

ありがとうございました。

回答No.3

taocat

おはようござりまする。

＞Worksheet_Changeイベントをキャンセルするには
＞どのようにコーディングしなければならないのでしょうか？

ただ単にWorksheet_Changeイベントをキャンセルするコードと言われても、意図するキャンセルの動作が具体的に分からないとコーティングはできませぬ。

例えば、
どのセルに対して、どういった条件の時に、
また、単に入力値を取り消すだけでいいのか等々、

補足

お返事ありがとうございます♪

セルへの入力を取り消す場合でいいです。
たとえば、A１に５と入っていたのに３を入力されたので、５（というか以前の値）にもどす。

よろしくお願いしま～す。

回答No.2

taocat

snoopy64さんの回答にちょと補足しますと。
例を挙げるとブックを閉じる（×ボタン等）前には
下記のイベントが発生するわけですが、
引数を見てみると、Cancelがありますよね。
こういう場合に、Cancel=Trueが使えるわけです。
下記のコードをThisWorkbookに貼り付けて
ブックの閉じるボタン（×）をクリックしてみてください。

Option Explicit

Private Sub Workbook_BeforeClose(Cancel As Boolean)
MsgBox "×ボタンが押されましたが、その動作をキャンセルします"
Cancel = True
End Sub

で、質問のように引数にCancelがない場合は
その動作を自分でコーディングしなければなりません。

それから、老婆心で一言。
変数の宣言は必ずするようにしましょう。
Option Explicitステートメントは必須です。
これがあれば、CANCEL=TRUE、のところで
変数未定義のエラーが発生し質問も別なもの
になったかも知れませんね。
以上。

お礼

>　引数を見てみると、Cancelがありますよね。
>　こういう場合に、Cancel=Trueが使えるわけです。

大変良くわかりました♪

> で、質問のように引数にCancelがない場合は
> その動作を自分でコーディングしなければなりません。

そうなんですか。では、たとえばWorksheet_Changeイベントをキャンセルするにはどのようにコーディングしなければならないのでしょうか？

回答No.1

snoopy64

キャンセルできるイベントとできないイベントがあって、できるイベントでは引数にCancelがあります。
・・・って理解してます。

お礼

な～るほど！

Cancel As Boolean　ってのが「引数」なのかな？
ありがとうございました。