オプションボタン

質問

昨日も質問させていただいたものです。
オプションボタンの使い方について質問があります。

コマンドボタン１つ、テキストボックスを１つ、ラベルを一つ、
フレームを二つ用意し、それぞれのフレームに３つずつオプションボタンを配置します（●フレームＡ、Ｂ●オプションＡ１、Ａ２、Ａ３、オプションＢ１、Ｂ２、Ｂ３とする）。
オプションＡ１～３には１～３年生というキャプションを、
オプションＢ１～３には１～３組というキャプションを設定します。
テキストに名前を打ちこんでコマンドボタンを押すと、
ラベルに（テキストが太郎の場合）"太郎は３年１組です"
と表示されるようなものを作ろうと考えています。

コマンドボタンを使用せずに、オプションボタンのみで作ると
Privat Sub OptionA1_Click()
If OptionB2.Valrue=True Then
Label1.Caption=""

と言うような感じで何個も書けば良いと思うのですが、
これにをコマンドボタンで実行させようとすると方法がわかりません。

アドバイスお願いします。

回答No.1

hd77 · ベストアンサー

とりあえず、基本的な命令で書くとこんなかんじになると思います。
Private Sub CommandButton1_Click()
Dim nen As String
Dim kumi As String
If TextBox1.Text = "" Then
MsgBox ("氏名が入力されてません")
Exit Sub
End If
If op1 = True Then
nen = "１年"
Else
If op2 = True Then
nen = "２年"
Else
If op3 = True Then
nen = "３年"
Else
MsgBox ("年が指定されていません")
Exit Sub
End If
End If
End If
If op4 = True Then
kumi = "１組"
Else
If op5 = True Then
kumi = "２組"
Else
If op6 = True Then
kumi = "３組"
Else
MsgBox ("組が指定されていません")
Exit Sub
End If
End If
End If
label1 = TextBox1.Text & "は" & nen & kumi & "です"
End Sub

お礼

レスありがとうございました。
初心者の私にもとてもわかりやすかったです。
これから一生懸命勉強します。
またよろしくお願いします。

回答No.3

TAGOSAKU7

仕様ではオプションボタンを６つ必要ですが、そのボタン全てにOp1～Op6までの名前を付けていては大変です。
質問でも書いてあった通り、このままではコーディングの時、一つ一つのボタンについてのTrue/Falseの調査ロジックが必要です。なので、Op1とOp2で済むようにしましょう。

コントロールを配列にしてしまうのです。
オプションボタンのプロパティに[Index]っていうのがありますよね？それを使用します。
以下の処理を手順どおりにデザインで行ってください。

フレーム１の中で・・・
１．[Name]Option1を、[Index]を'0'にしてください。
２．[Name]Option2を、[Name]をOption1、[Index]を'1'にしてください。
３．[Name]Option3を、[Name]をOption1、[Index]を'2'にしてください。
[
フレーム２の中で・・・
４．[Name]Option4を、[Name]をOption2、[Index]を'0'にしてください。
５．[Name]Option5を、[Name]をOption2、[Index]を'1'にしてください。
６．[Name]Option6を、[Name]をOption2、[Index]を'2'にしてください。

できたら、それぞれのキャプションを設定してください。
７．[Name]Option1・[Index]0を、[Caption]を'１年生'
８．[Name]Option1・[Index]1を、[Caption]を'２年生'
９．[Name]Option1・[Index]2を、[Caption]を'３年生'
10．[Name]Option2・[Index]0を、[Caption]を'１組'
11．[Name]Option2・[Index]1を、[Caption]を'２組'
12．[Name]Option2・[Index]2を、[Caption]を'３組'

13.コマンドボタンを用意してください[Name]Command1

で次のプログラムを実行してみてください
Private Sub Command1_Click()
Dim wkGAKUNEN As String '学年
Dim wkKUMI As String '組

With Me
'フレーム１（学年）についての調査
wkGAKUNEN = getSelectOptionButtonCaption(.Option1)
If wkGAKUNEN = "" Then
MsgBox "学年が選択されてない"
Exit Sub
End If

'フレーム２（組）についての調査
wkKUMI = getSelectOptionButtonCaption(.Option2)
If wkKUMI = "" Then
MsgBox "組が選択されてない"
Exit Sub
End If

'イミディエイトウィンドウへ出力
Debug.Print wkGAKUNEN & ":" & wkKUMI
End With
End Sub

'【機能】コントロール配列のオプションボタンの中で選択されているボタンのキャプションを得る
'【注意】制限として、オプションボタンはコントロール配列(インデックスを持つコントロール)であること
Private Function getSelectOptionButtonCaption(inOptionButton As Object) As String
Dim OpBtn As OptionButton

For Each OpBtn In inOptionButton
If OpBtn Then
'もし選択されていたら、その学年を記憶しループを抜ける
getSelectOptionButtonCaption = OpBtn.Caption
Exit For
End If
Next OpBtn

End Function

お礼

レスありがとうございます。
私はまだ、配列とかループとかってのを
勉強してないので、チョト難しかったです。
でも、これからがんばります。
丁寧な回答ありがとうございました。

回答No.2

ayucat

# まず、これってVBですかね？

>Privat Sub OptionA1_Click()
^
　eがないのは入力ミスかな？

>If OptionB2.Valrue=True Then
^
　Valueですよね。

>Label1.Caption=""

　ここで、Label1を空文字列にすることって何か意図が
あるのですか？

お礼

レスありがとうございます。
＞まず、これってVBですかね？
　はい、そうです。書いてませんでしたね。すいません。
　それにしてもタイプミスばかりで・・・・・・