EXCEL マクロでファイルサーバーを指定する

質問

現在、Cドライブ内でファイルを選択していますが、共有のファイルサーバー上のフォルダー内のファイルを選択できるようにしたいと考えています。色々とネット等で検索してみましたが、自分に合ったものが見つからず質問させて頂いた次第です。
下記をどの様に直したら良いのでしょうか？
宜しくお願い致します。
因みに
ファイルサーバーのパスは
Y:
￥￥fileserver￥AN￥IT￥91_Users￥700_Create￥その他業務￥Excelファイル類
です。

MsgBox "挿入する「ファイル」を選択してください"
Dim OpenFileName As Variant

ChDir "C:"

OpenFileName = Application.GetOpenFilename("挿入ファイル,*.*")
If VarType(OpenFileName) = vbBoolean Then
MsgBox "キャンセルされました"
Else
MsgBox OpenFileName & " が選択されました"
End If

回答No.3

eden3616 · ベストアンサー

失礼しました。
No1のコードに誤りがありますので差し替えてください。

Sub sample()
Dim strCdir As String
Dim strFname As String
With CreateObject("WScript.Shell")
　　'カレントディレクトリ控え
　　strCdir = CurDir
　　'カレントネットワークパスの設定
　　.currentdirectory = "\\fileserver\AN\IT\91_Users\700_Create\その他業務\Excelファイル類"
　　'ファイルを開くダイアログ表示
　　strFname = Application.GetOpenFilename("挿入ファイル,*.*")
　　If strFname <> "False" Then
　　　　MsgBox "選択したファイル名は" & strFname & "です。"
　　Else
　　　　MsgBox "キャンセルされました。"
　　End If
　　'カレントディレクトリ復元
　　.currentdirectory = strCdir
End With
End Sub

お礼

有難うございました。やっと希望したものになりました。今まで、私のわがままに付き合ってくれて有難うございました。感謝、感謝の気持ちでいっぱいです。

回答No.2

eden3616

>お答え頂いたstrFpathが生きていないのか、
>パスを設定してもC:￥が表示されてしまいます。

どのようなパスを指定されていますか？

>ファイルサーバーのパスは
>Y:
>￥￥fileserver￥AN￥IT￥91_Users￥700_Create￥その他業務￥Excelファイル類
>です。

C、Dなどドライブレターが割り振られていれば「C:￥」のように英字１字の後ろに「:￥」がつきます。ネットワークパスであれば、円マーク2つ「￥￥」から始まります。
ご提示のサーバーパスは、ネットワークパスの「￥￥fileserver～」が
「Y」ドライブとして設定してあるということでしょうか？

strFpath = "\\サーバー名\フォルダパス\"
　　　　　↓
strFpath = "\\fileserver\AN\IT\91_Users\700_Create\その他業務\Excelファイル類\"

のように指定してください。
ブラウザの特性上、半角の「￥」マークはバックスラッシュ「\」として表示されますが、
上記のままコピーして使用してください。

回答No.1

eden3616

ファイルを開くディレクトリの初期フォルダパスをサーバーのネットワークパスとして設定したいということでしょうか？
通常ChDirではドライブレターの振られていないドライブは扱うことができません。
WSHを用いてネットワークパスをカレントディレクトリとして設定するサンプルを以下に掲示します。
また、ファイル指定前後にカレントディレクトリの控え及び復元処理も入れています。

Sub sample()
Dim strCdir As String
Dim strFname As String
Dim strFpath As String
With CreateObject("WScript.Shell")
　　'カレントディレクトリ控え
　　strCdir = CurDir
　　'カレントネットワークパスの設定
　　strFpath = "\\サーバー名\フォルダパス\"
　　'ファイルを開くダイアログ表示
　　ChDir strFpath
　　strFname = Application.GetOpenFilename("挿入ファイル,*.*")
　　If strFname <> "False" Then
　　　　MsgBox "選択したファイル名は" & strFname & "です。"
　　Else
　　　　MsgBox "キャンセルされました。"
　　End If
　　'カレントディレクトリ復元
　　ChDir strCdir
End With
End Sub

補足

御助力有難うございます。ただ、お答え頂いたstrFpathが生きていないのか、パスを設定してもC:￥が表示されてしまいます。
もし良しければ、再度確認をして頂ければ幸いです。
質問続きで申し訳ございませんが、何卒、宜しくお願い致します。