アクセス2010 VBA 指定セルのインポート

質問

アクセス・エクセル2010を使用しています。
モジュールを用いて以下の作業を実行したいと考えていますが、
初心者につき、ご教示いただけますでしょうか。

1.ダイアログを表示させ、取り込みファイル（.xls）を指定してインポートしたい
※1シート目指定（シート名は変動の可能性アリ）
2.1で指定したファイルと同じフォルダ内にあるファイル（.xls）を全てインポートしたい
※各ファイル、インポートは1シート目のみです
3.フォームのテキスト（作成済：フォーム名（frm）・テキスト名（txt））で取り込みファイルの範囲指定をしたい
※1行目からの記載では無いです
※フィールド名行は変動しませんが値行は変動し、月によって列も変動する可能性があるため、テキストを使って範囲の変更がしたいです
※取り込みファイルの様式（形式・範囲）は全て同じです：形式はすべて倍精度浮動小数点型です）
具体的には、今月は・・
A列・1～2行目に空白があり、B列～記載がありますが、
インポート範囲としてはK列に項目・7行目にフィールド名になる名称・L8～Wに倍精度浮動小数点型の数値が入っています。

1つ1つの条件であれば、検索すれば（参考にできるものが）出てくるものもあるのですが、
それらを　どう組み合わせればうまく作動するのか
処理条件を　どう設定すれば良いのかが よくわからず、困っています。

知識不足で申し訳ありませんが、ご指導いただけますと幸いです。
よろしくお願いします！！

回答No.3

ushi2015 · ベストアンサー

こんにちは
なんか冗長で変なコードになっちゃいますけど、
Sub test_1()
　　Dim f As Object
　　Dim b As Object
　　Dim c As Object
　　Dim d As Object
　　Dim t As Variant
　　Dim e As Object
　　Dim p As String
　　Dim i As Long
　　Dim sSql As String
　　Dim フォームのテキスト As String

　　Set e = CreateObject("Excel.Application")
　　t = e.GetOpenFilename("Excel Files (*.xls*), *.xls*")
　　If t = False Then Exit Sub

　　フォームのテキスト = "K7:W78"

　　Set f = CreateObject("Scripting.FileSystemObject")
　　p = f.GetParentFolderName(t)
　　Set d = f.GetFolder(p)
　　Set b = d.Files
　　On Error Resume Next
　　sSql = "DROP TABLE テストテーブル "
　　CurrentProject.Connection.Execute CommandText:=sSql
　　sSql = "DROP TABLE 一時テーブル "
　　CurrentProject.Connection.Execute CommandText:=sSql
　　On Error GoTo 0
　　For Each c In b
　　　　If LCase(f.GetExtensionName(c)) Like "xls*" Then
　　　　　　If i = 0 Then
　　　　　　　　DoCmd.TransferSpreadsheet acImport, , "テストテーブル", c, True, フォームのテキスト
　　　　　　　　sSql = "ALTER TABLE テストテーブル ADD COLUMN ファイル名 VarChar(50);"
　　　　　　　　CurrentProject.Connection.Execute CommandText:=sSql
　　　　　　　　sSql = "UPDATE テストテーブル SET ファイル名='" & f.GetFileName(c) & "';"
　　　　　　　　CurrentProject.Connection.Execute CommandText:=sSql
　　　　　　　　i = i + 1
　　　　　　Else
　　　　　　　　On Error Resume Next
　　　　　　　　sSql = "DROP TABLE 一時テーブル "
　　　　　　　　CurrentProject.Connection.Execute CommandText:=sSql
　　　　　　　　On Error GoTo 0
　　　　　　　　DoCmd.TransferSpreadsheet acImport, , "一時テーブル", c, True, フォームのテキスト
　　　　　　　　sSql = "ALTER TABLE 一時テーブル ADD COLUMN ファイル名 VarChar(50);"
　　　　　　　　CurrentProject.Connection.Execute CommandText:=sSql
　　　　　　　　sSql = "UPDATE 一時テーブル SET ファイル名='" & f.GetFileName(c) & "';"
　　　　　　　　CurrentProject.Connection.Execute CommandText:=sSql
　　　　　　　　sSql = "INSERT INTO テストテーブル SELECT * FROM 一時テーブル"
　　　　　　　　CurrentProject.Connection.Execute CommandText:=sSql
　　　　　　　　i = i + 1
　　　　　　End If
　　　　End If
　　Next
　　On Error Resume Next
　　sSql = "DROP TABLE 一時テーブル "
　　CurrentProject.Connection.Execute CommandText:=sSql
　　On Error GoTo 0
　　e.Quit
　　Set e = Nothing
End Sub

補足

ありがとうございます！ほぼイメージした動きでした。

ただ1点、変動するインポート範囲を設定するために、
フォームのテキストボックス（txt）を用いて範囲指定を変動できるようにしたいのですが
そこのコーディングも教えていただけないでしょうか。

ここまで組んでいただいた上、ご面倒なお願いで申し訳ありませんが、
よろしくお願いします！

回答No.4

ushi2015

こんにちは
フォームのテキスト = "K7:W78"
の"K7:W78"の部分を
frm.text1.textとかに変更するとかです。

回答No.2

ushi2015

こんにちは
「2.1で指定したファイルと同じフォルダ内にあるファイル（.xls）を全てインポート」
全てのファイルのデータを一つのテーブルに集約するのですか？
それとも、一つのファイルに対して一つのテーブルを作成していくのですか？

補足

できれば、1つのテーブルでマージしたいです。
ただ、インポート基ファイル名などをフィールドで持てると良いのですが、可能でしょうか？

回答No.1

ushi2015

こんにちは
複数のExcelのデータを1つのテーブルに取り込むのですか？
取り込むテーブルのフィールド構成
取り込むExcelの実際のセル範囲の例
はどうなりますか？

補足

エクセルとしては、
7行目にフィールド名になるテキスト
今月は、K列～W列までを適用としています。

アクセス（テーブル）としては、
K列～（7行目）をフィールド名として　K8～（今回は）W（の際下段）をフィールド値としたいです。

フィールド1（K列）：項目名（にしたいフィールドなので）＝テキスト
フィールド2～13（L～W列）：値が入るので、名称は仮置きでも構いません＝倍精度浮動小数点型
です。
※今月はW列まで（フィールド13）までが適用ですが、次月以降はX列～（フィールド14以降）も適用の可能性もあります。

今月のフォーム：テキスト値としては、「K7：W78（もしくはK8～W78）」を取り込み対象として設定したいです。

よろしくお願いします！