[VBA]Like演算子における複数条件の指定

質問

こちらの識者の方々にはいつもお世話になっております。
VBAの質問です。

環境は下記になります。
OS=windows7 Pro SP1
Office=Excel2010(14.0.7128.5000)

掲題のとおり、Like演算子を使って、1列目のセルの値に"ABC"か"JJJ"か"QQQ"を含む場合2列目の値を"○"にする、などの複数条件を指定したいのですが可能でしょうか？

　For i = 1 To 10000
　　If Cells(i, 1).Value Like "*[ABC,JJJ,QQQ]*" Then Cells(i, 2).Value = "○"
　Next i

[]内のcharlistは一文字単位で判定されるため、上記コードですと、"BDE"がマッチされてしまうかと思います。

Orを使用すれば可能であることは理解していますが、やりたいことを厳密に言えば、上記のような場合のコードを1行（For~next分を除いて）で表記したいのです。
（逆に言えばLike演算子にこだわっているわけではありません。Instrでもなんでもかまいません）

このようなことは可能でしょうか？
質問に不備不足等ございましたらご指摘ください。
ご面倒お掛けしますがよろしくお願いします。

回答No.6

real beatin（@realbeatin） · ベストアンサー

回答No.5、一部修正と補足、追記です。

' ' === RegExp 正規表現 ===
Sub ReW9074325j()
Dim i As Long
　　With CreateObject("VBScript.RegExp")
　　　　.Pattern = "ABC|JJJ|QQQ"
　　　　For i = 1 To 10000
　　　　　　If .Test(Cells(i, 1)) Then Cells(i, 2) = "○"
　　　　Next i
　　End With
End Sub
' ' === === === === ===

編集ミスで余計な変数宣言が残ってしまったのと、
ついいつもの癖で、今回は必要のない.Global = Trueを書いてしまったのと、
２行分、余計でしたので、トルツメです。

> >>　.Pattern = "(ABC|JJJ|QQQ)"
> のようにOR条件にする単語を"("～")"の内側に
実は、必ずしも、"("と")"の内側に単語を列挙しなくても、
>>　.Pattern = "ABC|JJJ|QQQ"
で成立しているので、こちらも簡素化したものを再掲しますが、
この括弧については、慣習として、書いてあった方が、
読む人の通りが良い、というか、無いと違和感を覚える向きもあるかも知れませんので、
括弧で括っておくことをお奨めします。（という説明があった方が良かったのでした。）
少なくとも今回のようにリテラルな文字列を指定するような場合は、私は括弧を必ず付けます。
もっとも、各単語を文字列の配列変数に取得してある場合なんかでは、
　　.Pattern = Join(strArray(), "|")
みたいな扱いで、特に括弧で括らなくても、スッキリしていていいかなぁ、とも思います。

　　.Pattern = "(ABC|JJJ|QQQ)"
に、単語 "VVV" "XYZ" を追加する例を一応示しておきますが、、
　　.Pattern = "(ABC|JJJ|QQQ|VVV|XYZ)"
のようにただ列挙するだけ、です。

> （記号を含む場合は別途対応が必要ですが）
単語の中に、RegExpのパターンとして特別な意味を持つ記号文字
　?*+.|{}\[]()　等
が含まれる場合は、文字列として読込ませる為に、それぞれ、
　\? \* \+ \. \| .....
等の様に、記号文字の頭に"\"を付けてエスケープする必要があります。
https://msdn.microsoft.com/ja-jp/library/ms974570.aspx
（ＶＢＡのLike 演算子にもエスケープが必要な記号文字はありますけれど、
　例外なく"\"だけで一様に対処できる分、RegExpの方が単純ではあります。）

///
また、既出の方法以外についても考えてみました。余談に終るかも知れない参考程度の話ですが。

とりあえず、RegExpに関してですが、
もしも、例示されたのが部分的な処理内容であって、
示された処理の前にＡ列のセル内容を外部の一連のテキストデータから読み込んで出力している、
なんて場合は、読み込みの段階で、RegExpを使って一連のテキストを置換処理してしまえば、
わざわざセル単位のループをせずとも一気に処理させることも出来るケースもあります。
同様に、示された処理の前にＡ列のセル内容を外部のテーブルを読み込んで出力している、
なんて場合は、ADODB等でSQLが使える場合もあるのかも知れません。

ループさせるしかないにしても、行数がもっと多い場合などでは、
セル範囲の値を配列変数に読込んで、メモリ上で処理して、配列変数をセル範囲に出力する、
ようなやり方で、処理を速められる場合もあるかも知れません。

条件にマッチする割合が極端に低いこと
（例えば数万行のデータの中で各単語数件ずつしかマッチしないとか）
が予想される場合では、Excelの検索機能（range.Find メソッド）を使った方が
案外、能率的になる場合もあるのかな、とか。

全体像として、
どのようなソースで、どのような結果を求めているか、諸々の条件、
具体的な事例に副って、今回と回答No.5の中で紹介した方法の中から選ぶことになるのかな、
（、、、私の場合は）と思いますが、そういう意味では、
候補として可能性を排除できないものだけを挙げたつもりです。
もし、実際のニーズに合いそうで興味を持たれたものがあるようでしたらば、
こちらでもあらためて検討します。
///

以上です。永、失礼しました。

お礼

仰るように条件が多いので、できればOr演算子は使いたくなかったのです。
例の通り、Like演算子よりはInstr関数のほうがすっきり見えますね。
しかしやはり本命は正規表現ですか。
とっつきにくい印象があり、Like演算子でなんとかと思っていたんですが、教えていただいた内容を見る限り（本件については）簡単そうなので、チャレンジしてみます。
回答ありがとうございました！

回答No.5

real beatin（@realbeatin）

こんにちは。お邪魔します。

直接の回答としては以下のような感じです。
' ' === Like 演算子 ===
Sub ReW9074325a()
Dim i As Long
　　For i = 1 To 10000
　　　　If Cells(i, 1) Like "*ABC*" Or Cells(i, 1) Like "*JJJ*" Or Cells(i, 1) Like "*QQQ*" Then Cells(i, 2) = "○"
　　Next i
End Sub
' ' === === === === ===
> Like演算子を使って、1列目のセルの値に"ABC"か"JJJ"か"QQQ"を含む場合2列目の値を"○"にする、
> などの複数条件を指定したいのですが可能でしょうか？
Like演算子では、ひとつの構文で複数の単語をOR条件でマッチングさせることは不可能ですので、
複数のLike演算子構文を Or 演算子で結ぶよりありません。
似たような記述が繰り返しになることから、多少読み難く、書き損じも増えそうですね。

例題のように「○○を含む」という条件でしたら、
InStr()関数を用いる方が有利になる場合も多いので、
広く用いられる書式として、以下のような方法もあります。
' ' === InStr()関数 ===
Sub ReW9074325c()
Dim tmp
Dim i As Long
　　For i = 1 To 10000
　　　　tmp = Cells(i, 1)
　　　　If InStr(tmp, "ABC") Or InStr(tmp, "JJJ") Or InStr(tmp, "QQQ") Then Cells(i, 2) = "○"
　　Next i
End Sub
' ' === === === === ===
スクリプト的には、Like演算子に比べて、
ワイルドカードを省略出来たり、構文がより平易になるなど、
多少マシにはなります。
処理速度はInStr()関数が速いです。

「○○を含む」という複数のOR条件の数が多くなると、
上に挙げたふたつの例では、対応が難しくなりますので、
正規表現（VBScript.RegExp）を使った例を以下。
' ' === RegExp 正規表現 ===
Sub ReW9074325j()
Dim tmp
Dim i As Long
　　With CreateObject("VBScript.RegExp")
　　　　.Global = True
　　　　.Pattern = "(ABC|JJJ|QQQ)"
　　　　For i = 1 To 10000
　　　　　　If .Test(Cells(i, 1)) Then Cells(i, 2) = "○"
　　　　Next i
　　End With
End Sub
' ' === === === === ===
>>　.Pattern = "(ABC|JJJ|QQQ)"
のようにOR条件にする単語を"("～")"の内側に
"|"区切りで列挙するだけ（記号を含む場合は別途対応が必要ですが）
なので、条件の追加への対応が楽です。
より複雑なパターンマッチングを得意とするのが一般に知られている正規表現ですが、
複数の単語をOR条件で含む、という程度の複雑さでも、実力を発揮してくれます。

その他、「複数の単語にOR条件で完全に一致する」（"含む"ではない)
というような場合なら、range.AutoFilter メソッド等のExcelフィルター機能
が重宝する場合もあります。

蛇足になりますが、
If ... Then ステートメント
であれば、条件に合わない場合は、何もしません。
対して、＃1-4の方々がお答えになっているIIf()関数の扱いは、
条件に合わない場合にも、Empty値を出力するように書かれています。
　そもそも"○"出力先のＢ列は空の状態から実行するとか、
　条件に合わないセル範囲の値はそのまま保持するとか、
　条件に合わないセル範囲を消去する必要があるとか、（←IIf()関数）
実際のニーズは様々あるとは思いますが、
私は、ご提示のコードを元に If ... Then ステートメントでお応えしています。
もっとも、これらは応用とか運用も範疇だと思いますし、
私の記述をIIf()関数や If ... Then ... Else ... ステートメントに換えるのも容易なことですが、
違いを意識した上で使い分けてあげてくださいませ。

とりあえず、以上です。
もし何か不足や疑問があったら、補足欄にでも書いてみて下さい。

回答No.4

kagakusuki

OR演算子を使って良いのでしたら[ ]は使わずに済ます事が出来ます。

Sub test()
Dim I As Integer

For I = 1 To 8
Cells(I, 2).Value = IIf((Cells(I, 1).Value Like "*ABC*") + (Cells(I, 1).Value Like "*JJJ*") + (Cells(I, 1).Value Like "*QQQ*"), "○", "")
Next I
End Sub

お礼

やはりLike演算子を使う場合はOr演算子との組み合わせが必要ですね。
回答ありがとうございます。

回答No.3

山田 太郎（@f_a_007）

補足: OR演算子を使われる場合

Sub test()
　　Dim I As Integer
　　Dim V As String

　　For I = 1 To 4
　　　　V = Cells(I, 1).Value
　　　　Cells(I, 2).Value = IIf((V Like "*[A][B][C]*") + (V Like "*[J][J][J]*") + （V Like "*[Q][Q][Q]*"), "○", "")
　　Next I
End Sub

なお、OR演算子を使われる場合には、一文に拘る必要はないと思います。こういうコードですと、多分、変数Vはメモリではなくスタックに記憶されるかも知れません。加えて、シートの参照は１回で済むので、多分、こっちの方が高速で処理されます。

回答No.2

山田 太郎（@f_a_007）

【お詫び】見事に外していましたね。

バグ："1AJQ1"もヒットする。

で、結局は先のアイデアでは OR演算子を使うしかないようです。

Sub test()
　　Dim I As Integer

　　For I = 1 To 4
　　　　Cells(I, 2).Value = IIf((Cells(I, 1).Value Like "*[A][B][C]*") + (Cells(I, 1).Value Like "*[J][J][J]*") + (Cells(I, 1).Value Like "*[Q][Q][Q]*"), "○", "")
　　Next I
End Sub

　なお、IIF()を使ったのはヒットしなかった場合に”〇”を空に置換するためです。

PS、EXCELのVBAを書いたこともないのに誤回答してしまって陳謝。正答が付かなき場合は再質問されてください。

お礼

やはりLike演算子を使う場合はOr演算子との組み合わせが必要ですね。
しかし[]の使い方は参考になりました。
ありがとうございます。

回答No.1

山田 太郎（@f_a_007）

ExcelのVBAは扱ったことがないので外しているかもしれませんが・・・。一応、以下のコードで添付図のような結果が得られました。

Option Explicit

Sub test()
　　Dim I As Integer

　　For I = 1 To 4
　　　　Cells(I, 2).Value = IIf(Cells(I, 1).Value Like "*[A,J,Q][B,J,Q][C,J,Q]*", "○", "×")
　　Next I
End Sub