アクセス。レポートを最新版状態を表示させたい

質問

アクセス2000を使用しています。
チェックを入れてチェックが入った品名のみレポートで表示するようにしています。
チェックが入った品名のみのレポートを常に見れるようにしたいのですがどうしたらいいでしょうか？
レポートだけを開くと全ての商品がでる状態です。
１ヶ月に1.2回ほどチェックの入った品名が変わるので常に最新版を見れるようにしたいです。
レポートが表示されるまでの文です。

Private Sub コマンド_Click()
If Me.チェック Then
Me.品名リスト = Replace(Me.品名リスト & ",", "," & Me.品名 & ",", ",")
Me.品名リスト = Left(Me.品名リスト, Len(品名リスト) - 1)
Else
Me.品名リスト = Me.品名リスト & "," & Me.品名
End If
End Sub

Private Sub 実行_Click()
Dim strFilter As String
If Me.品名リスト <> "" Then
strFilter = "品名 In(" & Mid(Replace(Me.品名リスト, ",", "','"), 3) & "')"
DoCmd.OpenReport "R_カタログ", acViewPreview, , strFilter
Else
MsgBox "選択されたデータはありません。"
End If
End Sub

初心者ですので分かりやすく教えて頂けると助かります。

回答No.7

piroin654 · ベストアンサー

ボタン名を「cmdReShowRepot」として、
ボタンを設定し、クリックイベントの内容を以下のように
してください。「テーブル2」にYes/No型のフィールドが
あるものとしています。レポート名は「RRR」になっています。
テーブル名、レポート名は実際にあわせて変更してください。

'レポートの再表示
Private Sub cmdReShowReport_Click()
　　Dim db As DAO.Database
　　Dim rs As DAO.Recordset
　　Dim strFilter As String

　　If MsgBox("レポートを再表示しますか？", vbYesNo) = vbNo Then
　　　　Exit Sub
　　Else

　　　　Set db = CurrentDb
　　　　Set rs = db.OpenRecordset("テーブル2")

　　　　rs.MoveFirst
　　　　Do Until rs.EOF
　　　　　　'各レコードの「チェック」がTrueになっているものを検索
　　　　　　If rs!チェック = True Then
　　　　　　　　'変数strFilterに「品名」を「,」で区切り、「'」で囲みながら格納します
　　　　　　　　strFilter = strFilter & "," & "'" & rs!品名 & "'"
　　　　　　End If
　　　　　　rs.MoveNext
　　　　Loop
　　　　'文字列strFilterの先頭にいらない「,」がくっついているので取り除きます
　　　　strFilter = Right(strFilter, Len(strFilter) - 1)
　　　　'strFilterをフィルター用のIn句に整形します
　　　　strFilter = "品名 In(" & strFilter & ")"
　　　　'フィルタをかけてレポートを開きます
　　　　DoCmd.OpenReport "RRR", acViewPreview, , strFilter
　　　　'後始末
　　　　rs.Close: Set rs = Nothing
　　　　db.Close: Set db = Nothing
　　End If
End Sub

補足

何回もすごくご丁寧にありがとうございます。
助かります！すごいです！
レポートの表示ですがメインスイッチボードに
フィルターがかかったレポート表示のボタンを設定したいのですが
それをするにはどうしたらいいでしょうか？
既にスイッチボードがあるので編集でするのは分かるのですが
モジュールの実行でしたらいいのですか？
やろうと思ってモジュールに同じようなプロシージャをしてみて
モジュールを実行しようとしたらメインスイッチボード自体にエラーが出てしまいました。
お手数ですがメインスイッチボードでフィルターのかかったレポートを開く方法を
教えて下さい。よろしくお願いします。

回答No.9

piroin654

＞やろうと思ってモジュールに同じようなプロシージャをしてみて
＞モジュールを実行しようとしたらメインスイッチボード自体に
＞エラーが出てしまいました。

どのようなエラーが出たのでしょうか？

「メインスイッチボード」と言っても普通のいわゆる
「メインフォーム」でボタンなどを設定している
のでしょうから、フォームにボタンを一つ設定して、
Private Sub cmdReShowReport_Click()　の中身をコピーして貼り付けて
実行するだけだと思いますが。どうでしょうか。

お礼

メニュー用フォームビルダからしていて通常のフォームのように上手くいきませんでしたが
モジュールの実行の関数名が違ってたみたいです。。。
やりたい事が全てかないました！！また初心者の私には難題なリクエストがあるかもしれませんが。。。
本当に助かりました。ありがとうございました。

回答No.8

piroin654

No7に追加です。
何らかの拍子に「チェック」をすべてはずしてしまった
ことに気が付かずレポートを再表示しようとしたときの
エラー処理を、

　　　　Do Until rs.EOF
　　　　　　If rs!チェック = True Then
　　　　　　　　strFilter = strFilter & "," & "'" & rs!品名 & "'"
　　　　　　End If
　　　　　　rs.MoveNext
　　　　Loop

　　　　If strFilter = "" Then
　　　　　　MsgBox ("チェックがすべてはずれています。レポートを表示できません。")
　　　　　　Exit Sub
　　　　End If

　　　　strFilter = Right(strFilter, Len(strFilter) - 1)
　　　　strFilter = "品名 In(" & strFilter & ")"
　　　　DoCmd.OpenReport "Rカタログ", acViewPreview, , strFilter

のように、

　　　　If strFilter = "" Then
　　　　　　MsgBox ("チェックがすべてはずれています。レポートを表示できません。")
　　　　　　Exit Sub
　　　　End If

を、
Loop
と
strFilter = Right(strFilter, Len(strFilter) - 1)
の間にいれておいてください。

お礼

ご丁寧にありがとうございます！
Ｎｏ.7の細くのメインスイッチボードの件、宜しくお願い致します。

回答No.6

piroin654

＞なお、フォームでチェックをいれてもレコードの
＞左側に「鉛筆マーク」が出ている間にcmdMakeList
＞をクリックしても、・・・・・・・・
に準拠しているのだろうと思いますが。
レコードを強制的に確定させるために、

'品名リストへの登録
Private Sub cmdMakeList_Click()
　　Dim rs As DAO.Recordset
　　Set rs = Me.RecordsetClone

　　DoCmd.RunCommand acCmdSaveRecord
　　rs.MoveFirst
　　Do Until rs.EOF

のように、
DoCmd.RunCommand acCmdSaveRecord
を追加してください。

なお、「品名リストへの登録」フォームで、データを
誤って書き換えないようにするには、「チェック」
以外はプロパティで「編集ロック」を「はい」に
しておきます。

補足

親切に教えて頂きありがとうございます。
フォームを閉じてしまうと品名リストが消えてしまいもう一度cmdMakeListを押して
cmdShowReportを押さないとダメな状態なのですがメインスイッチボードに
チェックされてるレポートを開けるようなボタンを設置するようには出来ますでしょうか?
宜しくお願い致します。

回答No.5

piroin654

DAOはAccess2000ならば、Microsoft DAO 3.6 Object Librayです。
作成して確認してみてください。提案に必要な部分です。

質問ですが。
「チェック」というフィールドは、「テーブル1」に設定して
いるのですか、あるいは「テーブル2」ですか？さらに
「チェック」はテキスト型ですか、あるいはYes/No型ですか。

また、
＞チェックのコントロールソースに
＞=InStr([品名リスト] & ",","," & [品名] & ",")
＞の式が入っています。
のところが不可思議なのですが、これからすると
「チェック」はテキストボックスですか？

＞チェックを入れて選んだ商品がレパートに出るまでは上手くいくのですが
チェックはフォームでいれることができるのですか？
＞クエリで品名をグループ化サイズと重量などののそれぞれの平均、
＞最小、最大をクエリで
ならば、このクエリは更新できないのでは、と思うのですが。

提案として。

＞クエリで品名をグループ化サイズと重量などののそれぞれの平均、最小、
＞最大をクエリで計算しています。
＞クエリを元にフォームを作成しています。

この部分を、クエリを基にレポートを作成し、
フォームは「テーブル2」にYes/No型のフィールドを
設定し、それを基に作成するようにしたらどうですか。
作成方法はNo3での方法です。

補足

フォームフッターに非連結のテキストボックス”品名リスト”を配置してます。
フォームの詳細にチェックボックスを配置していて非連結です。これが”チェック”です。
そのチェックボックスのコントロールソースに
=InStr([品名リスト] & ",","," & [品名] & ",")
このチェックボックスの上に透明でコマンドボタン”コマンド”を配置しています。

クエリが更新されないというのはどういう意味での更新でしょうか？
データを入力しても反映されないという事でしょうか？
日々入力しても反映はされています。見当違いのことを言っていたらすいません＞＿＜

ＤＡＯの設定がゆうこうになってなかったみたいです。
有効にしてしてみたのですが、チェックした商品全てがレポートにでてきません。
チェックが数個あるのに3つぐらいしかでないみたいです。。。

回答No.4

piroin654

No3です。もし、チェックを入れない場合に
すべて表示するならば、以下のように。

'レポートの表示
Private Sub cmdShowReport_Click()
Dim strFilter As String

If Me!品名リスト <> "" Then
　　strFilter = "品名 In(" & Me!品名リスト & ")"
　　DoCmd.OpenReport "RRR", acViewPreview, , strFilter
Else
　　'ここを変更
　　MsgBox "すべて表示します。"
　　DoCmd.OpenReport "RRR", acViewPreview
End If
End Sub

回答No.3

piroin654

＞チェックを入れた品名だけをレポートに出すようにしたくて

ということであれば、Private Sub コマンド_Click()　の
中身から変更する必要があるのでは、と思いますが。

質問に出てくる「品名リスト」、「品名」が何者なのか
あるいはフォームがどのような構造なのか「チェック」
ってどこに・・・・？
一切情報がないので話を追っていった感じから、一度
以下のような要領でフォームを作ってみてください。
その上で、質問の内容にフォームやレポートの
レコードソースなどを変更しても遅くはないと思います。

(1)
テーブルを一つ作成します。名前を「テーブル100」とします。
ID　　オートナンバー
品名　テキスト型
チェック　Yes/No型
品名に適当にデータを入力してください。
（これは補足にあるテーブル2でいいのでは）

(2)
「テーブル100」をレコードソースとして、「フォームの新規作成」
から、「表形式」を選択し、適当な名前で保存します。

(3)
保存したフォームをデザインビューで開き、「詳細」部分に
カーソルを当て下にずイーーっと引き下げ、ついでに
ラベルも引き下げておきます。

(4)
フォームに出来たスペースにボタンを三つ、大き目の
テキストボックスを一つ設定します。
テキストボックスの名前を「品名リスト」とします。

(5)
三つのボタンの名前をそれぞれ、cmdMakeList、
cmdShowReport、cmdCheckRefreshとします。
それぞれのボタンのクリックイベントに
以下を設定してください。
なお、DAOをシヨウしているので、コード表で
DAOへのチェックを確認しておいてください。
Microsoft DAO XX Object Libray
のようなものです。

(6)

'品名リストへの登録
Private Sub cmdMakeList_Click()
　　Dim rs As DAO.Recordset
　　Set rs = Me.RecordsetClone

　　rs.MoveFirst
　　Do Until rs.EOF
　　　　'チェックがされているレコードがあった場合
　　　　If rs!チェック = True Then
　　　　　　'品名リストにデータが登録されている場合
　　　　　　If Not IsNull(Me!品名リスト) Then
　　　　　　　　Me!品名リスト = Me!品名リスト & "," & "'" & rs!品名 & "'"
　　　　　　'品名リストにデータが登録されていない場合
　　　　　　Else
　　　　　　　　Me!品名リスト = "'" & rs!品名 & "'"
　　　　　　End If
　　　　End If
　　　　rs.MoveNext
　　Loop
rs.Close: Set rs = Nothing
End Sub

(7)

'レポートの表示
Private Sub cmdShowReport_Click()
Dim strFilter As String

If Me!品名リスト <> "" Then
　　strFilter = "品名 In(" & Me!品名リスト & ")"
　　DoCmd.OpenReport "RRR", acViewPreview, , strFilter
Else
　　MsgBox "選択されたデータはありません。"
End If
End Sub

(8)

'チェックの初期化(チェックをはずします）
'SQL文を投げてもいいのですが、このままで。
Private Sub cmdCheckRefresh_Click()
　　Dim rs As DAO.Recordset

　　Set rs = Me.RecordsetClone
　　rs.MoveFirst
　　Do Until rs.EOF
　　　　rs.Edit
　　　　rs!チェック = False
　　　　rs.Update
　　　　rs.MoveNext
　　Loop
　　'これはいれなくても大丈夫だと思いますが、念のために
Me.Requery
　　rs.Close: Set rs = Nothing
End Sub

(9)
レポートを作成します。便宜上レポートの
レコードソースは「テーブル100」とします。
レポートの新規作成で、「表形式」を選択し、
レコードソースを「テーブル100」を選択し、
名前を「RRR」としてください。レポートを
表示するコードの中でレポート名を「RRR」
としています。

以上で、質問の意図に沿ったものが出来るか
確認してみてください。

なお、フォームでチェックをいれてもレコードの
左側に「鉛筆マーク」が出ている間にcmdMakeList
をクリックしても、鉛筆マークのついたレコードは
確定したものとは見なされないので、どこか別の
レコードのフィールドをクリックして「鉛筆マーク」
を消して、レコードを確定してください。

補足

コンパイルエラーでユーザー定義型は定義されていません。となります。
ＤＡＯの部分で引っかかってる感じです。

分かりにくいかもしれませんがもう少し詳しく説明したいと思います。
テーブルが２つあります。
テーブル１には日々入力してるデータを保存しています。
フィールドに日付、品名、サイズ、重量などの項目があります。
テーブル2に品名の規格値などを保存しています。
フィールドに品名、サイズの規格値、重量の規格値、などなどがあります。
クエリで品名をグループ化サイズと重量などののそれぞれの平均、最小、最大をクエリで
計算しています。
クエリを元にフォームを作成しています。
チェックのコントロールソースに
=InStr([品名リスト] & ",","," & [品名] & ",")
の式が入っています。
チェックを入れて選んだ商品がレパートに出るまでは上手くいくのですが
その状態を維持させる事ができません。
ずっとそのままではなく、ちぇっくは１ヶ月に数回変わります。
自分で説明してても分かりにくいのできっともっと分かりにくいですよね。

すいませんがご教授お願い致します。

回答No.2

nicotinism

#1です。何度か補足を読み返してみたのですが。。。
「チェック」フィールド？の説明が無いのですが、
パラメータの入力を促されるのは、「R_カタログ」レポートのレコードソースになっている
クエリ？に「チェック」フィールドが含まれていないためかと思います。
レポート内に配置する必要はありませんが、レコードソース中には入れて試してみてください。
私の勘違いならゴメン。

補足

チェックのフィールドを作成し再度してみましたがパラメータの入力はなくなりましたが
チェックが入っていても入ってるようにならず１つも品名がでてきません。
クエリでグループ化してるのでできないのでしょうか？

回答No.1

nicotinism

Private Sub 実行_Click()
Dim strFilter As String
If Me.品名リスト <> "" Then
strFilter = "品名 In(" & Mid(Replace(Me.品名リスト, ",", "','"), 3) & "')"
'DoCmd.OpenReport "R_カタログ", acViewPreview, , strFilter 'を↓
DoCmd.OpenReport "R_カタログ", acViewPreview,wherecondition:= "[チェック] = true"
'で良さそうに思えますけど。
'そちらの状況が分かりづらいですね
Else
MsgBox "選択されたデータはありません。"
End If
End Sub

補足

教えて頂いたコードに変更するとパラメータの入力で「チェック」が出てきます。

別フォームでテーブル1に日付やその都度のサイズなどを入力しています。
テーブル2には商品別の規格値などが入ってます。
今回のフォームにはクエリを使って商品の平均値や最小値、最大値が表示されてます。
今回のフォームにレポートに表示させたい品名部分にチェックを入れると
レポートに表示させ、その表示されたレポートをチェックしなくても見れる状態にしたいです。

チェック部分は月に数回変わりますので簡単に変更できるようにしたいです。

分かりにくい説明ですが宜しくお願い致します。