ACCESSで自動でメールをおくる時に任意のアドレスに送りたい

質問

工場にてACCESS97を使い、営業からの発注に対して納期の回答やもろもろのデータをメールにて任意のアドレスに送りたいのですが、当方VBAはまったく使えず、クエリーの使い倒しとマクロにて、結構ややこしい処理をしています。
マクロにてオブジェクトの送信で行うと、
マクロの記述内でアドレスを書きこむかあるいはブランクにしておき、送信時に送り先を入力するかしか手がないのでしょうか？
該当する営業にその人に関わるデータのみ送りたいので
営業全員におくるわけもゆかないのです。
VBを使うしか手がないのでしょうか？

回答No.1

ARC

真剣に取り組んだわけではないので、確かな答えではありませんが、多分、できません。

マクロで使える機能のほとんどはVBAからも扱えるので、ここは一つVBAに取り組まれてはいかがでしょうか。
ちなみに、「オブジェクトの送信」と同等の機能は、
DoCmd.SendObject
ですね。

ヘルプでDoCmdの項目をごらんになれば、マクロで使えるほとんどの機能が、DoCmd.XXX と記述するだけで使えることが分かると思います。

Accessを思い通りに使うためには、VBAの記述は避けては通れないことですので、今後ともAccessを使っていくんであれば、さわりの部分だけでも覚えておけばいいんじゃないでしょうか。

ちょっと作ってみましょうか。(どうせヒマですし)
「宛先一覧クエリー」(フィールド名"e-mail")の全員に、「送信内容クエリー」で抽出されたデータを送りたい時は、下記のようにします。

Sub SendMail()
　　Dim AtesakiRST As Recordset
　　Dim AtesakiStr As String
　　Dim MailAddress As String

　　On Error GoTo HandleErr

'宛先の一覧を、コンマ区切りで生成する
　　'宛先の一覧を取得
　　Set AtesakiRST = CurrentDb.OpenRecordset("宛先一覧クエリー")
　　Do Until AtesakiRST.EOF
　　　　MailAddress = Nz(AtesakiRST![e-mail], "")
　　　　If MailAddress <> "" Then
　　　　　　'コンマ区切で、文字列を生成
　　　　　　AtesakiStr = AtesakiStr & "," & MailAddress
　　　　End If
　　　　AtesakiRST.MoveNext
　　Loop
　　'先頭のコンマを削除
　　If Left$(AtesakiStr, 1) = "," Then
　　　　AtesakiStr = Right(AtesakiStr, Len(AtesakiStr) - 1)
　　End If

'メッセージの送信
　　DoCmd.SendObject acSendQuery, "送信内容クエリー", acFormatXLS, , , AtesakiStr, "題名", "メッセージ"

'終了
ExitHere:
　　Exit Sub

'エラー処理
HandleErr:
　　MsgBox "エラー発生!!" & vbNewLine & Err.Description
　　Resume ExitHere
End Sub

5分で作って5分でバグ取りしただけのものなんで、「ちゃんと使える」かどうかは疑問ですが、まぁ、参考程度にはなると思います。
(ちなみに著作権うんぬんは主張しません。勝手に使ってくださって結構です。)

お礼

早速のご回答有難うございます。
お書き頂いたVBAの記述なんとなく、ほんの少し
わかるような気がします。
当方、中堅製造メーカーで現場のあわただしさの中で
夜まではほとんど静かにプログラムをかじれるような環境ではなく、おまけに年齢的に頭もなかなか回らなくなりVBA（VB）にはずっと踏み込む勇気がない状態です。
かといってすべてシステム会社にお願いする予算もない
というありさまです。
VBA（VB）を基礎から分かりやすく解説しているような
お勧めの書籍には何がありますか。
本屋には余りにも多すぎて選択が困難です。
今から約20年前ですけどBASIC、FORTRANは学生時代に
かじりました。
しかし、その後はまったく空白です。
脳みそもかなり腐ってきていると感じていますが、、
そういう人間向けの書籍がありましたら宜しくお願いします。

補足

このシステム初めて使うのですが、
どうやって、回答頂いた方に点数を入れるのですか？