EXCELで複数のシートからデータを別シートに出す方法

質問

EXCELで複数のシートからデータを別シートに出す方法

EXCEL2007でデータが1シートに100行/10列ある物が10シートあります。
この10シートの任意の行にA～Dを付けて、別シート（Aシート～Dシート）に
A～Dを付けた行を表示させたいのですが、方法がわかりませんでした。
ご教示お願いします。

また、可能なら別シートに表示させる時、10列ある物を4列にしたいのですが。
よろしくお願いします。

回答No.3

merlionXX · ベストアンサー

No2 merlionXXです。
他にも疑問点は多いのですが、いちいち確認するのも面倒なので、とりあえずVBAのコードを作成してみました。
回答者はあなたの作ったデータを見ることができないのですから、本来この程度の前提条件は質問者側で最初に提示すべきことです。
以下の前提で作成していますので違ったら言ってください。

○データのあるシート（名前はなんでもOK）10枚はそのファイルの一番左から１０枚目までに並んでおり、その途中に余分なシートは入っていない。
○100行10列のデータの範囲は10枚のシート全部が、A1～J100であり、A列には途中に空白セルがない。（B～J列にはあってもOK）
○A～Dの識別符号を入力するのは各シートのZ1～Z100の範囲である。（ここが空白やA～D以外の記入があれば、その行は転記の対象外となる）
○別シート（Aシート～Dシート）の名前は半角英字で SheetA　SheetB～SheetD　である。
○SheetA　SheetB～SheetD　はデータのあるシートより右側（11枚目以降）にある。
○SheetA　SheetB～SheetD　のA～J列に該当のデータを上から順に転記させる。

以上の前提が正しければ以下の手順をお試しください。
簡単ですよ。

1.そのBOOKを開き、AltキーとF11キー同時に押し（以下Alt+F11キーと記述）て Visual Basic Editor 画面を呼び出します。
2.Visual Basic Editor のメニューから「挿入」、「標準モジュール」で出てきたコードウィンド（右側の白い広い部分）に以下のコード（Sub～End Sub）をコピペします。

'********これより下**********

Sub test01()
　　Dim i As Long, r As Long, y As Long, z As Long, x As String '変数宣言
　　For i = 1 To 10　　'左の1枚目から10枚目まで
　　　　With Worksheets(i) '各シートにつき
　　　　　　For r = 1 To 100 '1～100行目まで
　　　　　　　　x = StrConv(Trim(.Cells(r, "Z").Value), vbNarrow) 'Z列文字を取得して半角化しxに代入
　　　　　　　　If x <> "" Then 'xが空白でなければ
　　　　　　　　　　If InStr("ABCD", x) > 0 Then 'xがA～Dに該当すれば
　　　　　　　　　　　　y = Sheets("Sheet" & x).Cells(Rows.Count, 1).End(xlUp).Row '転記先シートの最終行取得
　　　　　　　　　　　　z = IIf(Sheets("Sheet" & x).Cells(y, "A") = "", y, y + 1) '転記先シートの転記先の行を判断
　　　　　　　　　　　　Sheets("Sheet" & x).Cells(z, "A").Resize(, 10).Value = .Cells(r, "A").Resize(, 10).Value '転記
　　　　　　　　　　End If
　　　　　　　　End If
　　　　　　Next r '行繰り返し
　　　　End With
　　Next i 'シート繰り返し

End Sub

'********これより上**********

3.Alt+F11キーでワークシートへもどります。
4.Alt+F8キーで出てきたマクロ名（test01）を選択して実行します。

お礼

回答ありがとうございました。

回答No.2

merlionXX

> 10シートの任意の行にA～Dを付けて

ここがよくわからないのですが、データのある10のシートで、Aをつけた行はAシート、Bをつけた行はBシート～Dをつけた行はDシートへ転記するということですね？

そうであれば、ご希望のことはエクセルのVBAを使えば十分できると思います。

このA～Dは、データのあるシートのどの列に入力するのですか？

補足

回答ありがとうございます。
説明不足でした。

＞ここがよくわからないのですが、・・・ということですね？
・はい、そうです。

＞このA～Dは、・・・どの列に入力するのですか？
・空いている列ならどこでもいいのですが、
便宜上「Ｚ」とさせて頂きます。

上手く説明できていませんが、よろしくおねがいします。

回答No.1

noname#192382

あなたがやろうとされていることは、データベース的な仕事です。エクセルのデータはアクセスに簡単に移せますから、この仕事はアクセスの世界でなさったらいかがですか。アクセスでは楽に操作ができます。

補足

回答ありがとうございます。

エクセルでは無理でしょうか？
業務用に支給されたパソコンでアクセスは入っておらず、
フリーソフトを入れるのは許可されていないので。

アクセスなら簡単にできるとは知りませんでした。