エクセルVBAで配列の追加

質問

• エクセル2000で1行4列のセル範囲のデータを配列に取り込み、後から別の1行4列のセル範囲のデータを追加し、2次元配列として出力する方法を教えてください。
• 上記のコードでは、まず最初の範囲を配列に取り込み、次に追加範囲のデータを2次元配列の特定の位置に追加しています。
• 修正すべき点としては、配列のサイズ変更にはReDim Preserve文を使用すること、およびデータを出力するセル範囲を正確に指定することです。

回答No.5

end-u

念の為追記しておきます。
FormulaArrayプロパティを使って、一応はできますし、
2000で配列制限に引っ掛かる時、簡略化できるメリットはあります。
でもセル書き込みの効率は格段に落ちます。

VBAコーディングについてシンプルなものがイコール効率的とは限りません。
その点を理解した上で最適な手法を選択してください。

Option Explicit
'---------------------------------------------------------------------
Sub test()
　　Const rn As Long = 1000
　　Const cn As Long = 4
　　Dim i As Long
　　Dim t As Single
　　Dim w(1 To rn)

　　With Sheets.Add.Cells(1).Resize(rn, cn)
　　　　.Formula = "=ADDRESS(ROW(),COLUMN(),4)"
　　　　.Value = .Value
　　　　For i = 1 To rn
　　　　　　w(i) = .Rows(i).Value
　　　　Next
　　End With
　　t = Timer
　　test1 w
　　Debug.Print Timer - t
　　t = Timer
　　test2 w
　　Debug.Print Timer - t
　　t = Timer
　　test3 w
　　Debug.Print Timer - t
End Sub
'---------------------------------------------------------------------
Sub test1(w)
　　Dim z

　　With Application
　　　　z = .Transpose(.Transpose(w))
　　End With
　　Sheets.Add.Cells(1).Resize(UBound(z, 1), UBound(z, 2)).Value = z
End Sub
'---------------------------------------------------------------------
Sub test2(w)
　　Sheets.Add.Cells(1) _
　　　　　.Resize(UBound(w, 1), UBound(w(1), 2)).FormulaArray = w
End Sub
'---------------------------------------------------------------------
Sub test3(w)
　　Dim i As Long
　　Dim j As Long
　　Dim x As Long
　　Dim y As Long

　　y = UBound(w, 1)
　　x = UBound(w(1), 2)
　　ReDim z(1 To y, 1 To x)
　　For i = 1 To y
　　　　For j = 1 To x
　　　　　　z(i, j) = w(i)(1, j)
　　　　Next
　　Next
　　Sheets.Add.Cells(1).Resize(y, x).Value = z
End Sub

お礼

end-uさま、締め切った後までご指導いただき有難うございます。
先ほど戻ってまいりました。
さっそく試したところ、おっしゃる通りFormulaArrayだと随分遅くなるんですね、おどろきました。
ほんとにシンプルなものが効率的とは限らないんですね。
ご指導有難うございました。