Excelで22バイトの文字を数えたい

質問

Excel2002です。
VBAでセルの文字列を取得する時に全角制御文字（2バイト）を含めて22バイトの制限を考慮したいのですがその方法がわかりません。

全角文字だけなら10文字、　
半角文字だけなら22文字の取得ができます。

その後の作業の都合上、22バイトを基準に条件判断したいのですが現在はその方法がわからないためLEN()で10を上限としています。LENB()でも同じ結果（文字数が返される）になります。

対象のセルには全角文字/半角文字が混在しており、全角-半角-全角-半角のような混在であれば制御文字を２回考慮する必要があります。

最悪その文字が全角か半角かの区別がつけば対応できると思います。
よい方法をご教授いただきたくお願いいたします。

回答No.1

lark_0925 · ベストアンサー

>最悪その文字が全角か半角かの区別がつけば対応できると思います。
↑これを判断する方法を二つほど・・・。
'==========================================================
Sub test()
　　Dim idx As Long
　　Dim aa As String
　　Dim result As String
　　Range("a1").Value = "私はhungryです"
　　MsgBox "セルＡ１の文字列の全角。半角を判断します"
　　aa = Range("a1").Value
　　For idx = 1 To Len(aa)
　　　result = "「" & Mid(aa, idx, 1) & "」は、"
　　　If LenB(StrConv(Mid(aa, idx, 1), vbFromUnicode)) = 2 Then
　　　　　result = result & "全角文字です"
　　　Else
　　　　　result = result & "半角文字です"
　　　　　End If
　　　MsgBox result
　　　Next
End Sub
'==========================================================
Sub test2()
　　Dim idx As Long
　　Dim aa As String
　　Dim result As String
　　Range("a1").Value = "私はhungryです"
　　MsgBox "セルＡ１の文字列の全角。半角を判断します"
　　aa = Range("a1").Value
　　For idx = 1 To Len(aa)
　　　result = "「" & Mid(aa, idx, 1) & "」は、"
　　　If Evaluate("LenB(""" & Mid(aa, idx, 1) & """)") = 2 Then
　　　　　result = result & "全角文字です"
　　　Else
　　　　　result = result & "半角文字です"
　　　　　End If
　　　MsgBox result
　　　Next
End Sub

検討してみてください。

お礼

LenB(StrConv(Mid(aa, idx, 1), vbFromUnicode)) を利用し以下のような文字列検査で目的を得ました。ありがとうございました。

※変数"文字列"に検査したい文字列を代入し、本体マクロから"文字列検査"マクロを呼び出し　バイト数・　調整文字　を得て本体に戻ります。

Sub 文字列検査()
ReDim 文字長(Len(文字列)) As Integer
バイト数 = 0
調整文字 = ""
For 文字回数 = 1 To Len(文字列)
文字長(文字回数) = LenB(StrConv(Mid(文字列, 文字回数, 1), vbFromUnicode))

If バイト数 > 0 And 文字長(文字回数) <> 文字長(文字回数 - 1) Then バイト数 = バイト数 + 1

Select Case 文字長(文字回数)
Case 1
If バイト数 < 22 Then
バイト数 = バイト数 + 文字長(文字回数)
調整文字 = 調整文字 + Mid(文字列, 文字回数, 1)
End If
Case 2
Select Case バイト数
Case 20
バイト数 = バイト数 + 1
Case 0, 19
バイト数 = バイト数 + 文字長(文字回数) + 1
調整文字 = 調整文字 + Mid(文字列, 文字回数, 1)
Case 1 To 18
バイト数 = バイト数 + 文字長(文字回数)
調整文字 = 調整文字 + Mid(文字列, 文字回数, 1)
If 文字回数 = Len(文字列) Then バイト数 = バイト数 + 1
End Select
End Select
Next 文字回数

End Sub

回答No.5

Wendy02

こんにちは。

#3の回答者です。ご質問者はイチゲンの方なので、戻ってくるのかわかりませんが、もう一度読み直してみました。

実際問題として、VBA自体で、インターネットを使わない限りは、全角制御文字（IN/OUT）を必要とされることはないはずですし、VBAは、Unicode ですから、半角全角自体のIN/OUT を要求されることはありませんね。使用目的がわからないと、やっぱり分かりません。

私は、今まで、#3の回答(四捨五入ではなくて切り捨て）の方法で考えてきましたし、それでよいとは思っていたのですが、IN/OUT を加算するなら、以下のように、出入りをチェックすればよいと思います。細かい点で違っているかもしれませんけれどね。

Sub Test2()
Const mText = "豆1個コーヒー2杯"
　MsgBox ByteCheck(mText) & " Byte Include IN/OUT"
　MsgBox LenB(StrConv(mText, vbFromUnicode))　'参考
End Sub

Function ByteCheck(mText As String)
　　Dim cnt As Long
　　Dim n As String
　　Dim flg As Boolean
　　For i = 1 To Len(mText)
　　　　n = Mid(mText, i, 1)
　　　　If Abs(Asc(n)) < 127 Then
　　　　　　cnt = cnt + 1
　　　　　　a = Asc(n)
　　　　　　flg = False
　　　　Else
　　　　　　If LenB(StrConv(n, vbFromUnicode)) > 1 And flg = False Then
　　　　　　　　cnt = cnt + 4
　　　　　　　　flg = True
　　　　　　ElseIf flg = False Then
　　　　　　　　cnt = cnt + 3
　　　　　　Else
　　　　　　　　cnt = cnt + 2
　　　　　　End If
　　　　End If
　　Next i
　　ByteCheck = cnt
End Function

お礼

質問を締め切りに来てご回答を拝見しました。舌足らずな質問に何度も検討していただきありがとうございます。

私の結論は＃１へのお礼に記載しております。よろしければご覧ください。

回答No.4

fumufumu_2006

後処理でJISに変換するためのようにも思えるんですが、JISの漢字IN/OUTは3文字づつだから・・・
とりあえず、文字列をJISとSJISに変換して、JISの漢字IN/OUTが1文字づつだった場合の文字数を出す方法です。
[ツール] [参照設定] で、[Microsoft ActiveX Data Objects *.* Object Library] への参照を設定してください。
シフトJISに変換するのはstrconvでもできるんですが、同じ処理系で変換した方が安全だと思うので、両方ADODB.Streamに任せます。

Function checkLength(str As String) As Integer
Dim lenJIS As Integer
Dim lenSJIS As Integer
Dim stm As New ADODB.Stream
With stm
'jis文字長
.Open
.Type = adTypeText
.Charset = "ISO-2022-JP"
.WriteText str
.Position = 0
.Type = adTypeBinary
lenJIS = UBound(.Read()) + 1
.Close
'sjis文字長
.Open
.Position = 0
.Type = adTypeText
.Charset = "Shift_JIS"
.WriteText str
.Position = 0
.Type = adTypeBinary
lenSJIS = UBound(.Read()) + 1
.Close
End With
Set stm = Nothing
checkLength = lenSJIS + (lenJIS - lenSJIS) / 3 '漢字IN/OUTが1文字づつとして計算
End Function

Sub test()
MsgBox checkLength("亜AA亜亜AA") & "文字"
End Sub

p.s.
JIS中のESCの数から出す方が早いか・・・

回答No.3

Wendy02

こんにちは。

なんとなく、話が分からないですね。

キーワードとして出ている

・22バイトの制限
>全角文字だけなら10文字、
>半角文字だけなら22文字の取得ができます。

それはありえないです。全角は、11文字です。

>全角制御文字（2バイト）を含めて22バイト

全角制御文字って聞いたことがありません。例えば、CrLf は、全角ではなくて、２つの制御コードです。

全角・半角混在の場合で、文字列を区切る場合は、切り捨てするか、四捨五入して、最短21バイト、最長23バイトになるはずです。

Sub Macro1()
Dim Str1 As String
Str1 = "ソフトウェアエクセル"　　'全角10文字
MsgBox Str1 & "は、" & vbCrLf & LenB(StrConv(Str1, vbFromUnicode)) & "バイトです。"
End Sub

Unicode を、JISに戻して、上記なら、20バイトにはなりますが、こんな単純な話なのでしょうか？

全角・半角判定なら、

Sub Macro()
Dim Str1 As String
　Str1 = "その名前はMicroSoft" & vbcl & "・EXCEL"
If StrConv(Str1, vbNarrow) = Str1 Then
　 MsgBox "半角です。"
ElseIf StrConv(Str1, vbWide) = Str1 Then
　 MsgBox "すべて全角です。"
Else
　　 MsgBox "全角・半角混ざっています。"
End If
End Sub

回答No.2

imogasi

>制限を考慮したいのですがその
制限とは。システムにはそういう制限はないと思うが
自分が制限をかけたいということかな。質問の意味不明。
ーーー
文字コードがShiftJISと違うようですね。なんと言うコードですか。
全角文字の前後にシフトイン・シフトアウトのコードが入る文字コードかな。
さる大型機のコードでで昔苦労したが、みんな最近そんなの意識してないと思うので、質問にはっきり書かないと判りにくいのでは。
ーー
A.物理的に制御文字も含めてバイト数が取れればよいのかな。
B.意味的に全角何文字＋半角何文字を知りたいのかな。
A.はLENBではダメなんですか。
Bはシフト関係の文字（２種？）を空白””でSUBSTITUTEして、長さの減り具合から全角文字数は割り出せないのかな。
＞LENB()でも同じ結果（文字数が返される
Lenbでも制御コードの長さは省かれるということですか。聡だった毛な。