FLASHサウンドの同期を取った音のOFFボタンは作れますか？

質問

FLASH初心者です・・・どうか助けてください。

FLASHで、アニメーションに合わせて音を鳴らすように作りました。
アニメーションの動きに音がピタリと合うようにしたいので、
サウンドをタイムライン上に乗っけて、プロパティの設定で
「同期：ストリーミング」にしてあります。
ここまでは良かったのですが、音のOFFボタンを付けたいのですが、
たくさん調べましたがやり方がわかりません！！（涙）

アニメーションの動きに合わさず、ただただBGMとして音を鳴らした場合は
リンゲージなどを使ってOFFボタンが付けられるのだな、と
調べているとわかりました。

今回の私のような、アニメーションの動きと同期を取った音に、OFFボタンをつけることは可能なのでしょうか？
どうか、やり方を教えていただければと思います！
よろしくお願いいたします。

回答No.2

DPE · ベストアンサー

＃１です。

ON / OFF に応じて絵が変わるボタンは、ムービークリップのフレームに OFF と ON の絵を描いておいて、クリックされるたびに表示するフレームを gotoAndStop で切り替えます。
音量を if 文で判断して、OFF だった時に OFF の絵を描いたフレームを表示する・・・というように作ってもいいのですが、フレームの構成を工夫すると、if 文を使わずに表示するフレームを算出することもできます。

ON / OFF ボタンとして使うボタンを、今度は”ムービークリップシンボル”として作ります。
シンボルの編集画面になったら、フレーム１に” OFF ”の時に表示する絵、フレーム２に” ON ”の時に表示する絵を描きます。
シンボル内にもう１つレイヤーを追加し、フレーム１にキーフレームを作って stop(); アクションを記述してください。

以上でムービークリップは完成です。
次はスクリプトを書きます。

****************************

ActionScript では、変数や関数、ボタン・ムービークリップなどのインスタンスには全て、持ち主がいると考えます。
変数などを利用したりインスタンスに指示を出す時は、誰が持っているものなのか、その持ち主を正確に指定しなければなりません。
持ち主を指定するものを”ターゲットパス”といいます。

ターゲットパスは、自分が持っているものであれば省略することもできます。
ON / OFF ボタンが常にステージに存在していて、シーンをまたいだりモーショントゥイーン等でキーフレームが変化するようなこともないとすると、必要な変数などは全部このムービークリップのものにしておいた方が、ターゲットパスを省略できて簡単です。

ただし、この場合は、Sound オブジェクトで制御する対象（ new Sound に渡すパラメータ）が this ＝自分自身ではなく親のタイムラインに変わりますので、ご注意ください。
この話を真面目に説明すると難しくなるのですが、簡単に言いますと、ON / OFF ボタンをムービークリップにすると、音を鳴らしているタイムラインが、自分ではなく親のタイムラインと見なされるように変わるためです。

今回は、スクリプトは ON / OFF ボタンとして使うムービークリップのインスタンスにのみ書きます。
このムービークリップは、フレーム１に” OFF ”の絵、フレーム２に” ON ”の絵が描かれているものとします。
＃１で作成したフレームのスクリプトは、削除するか、コメントにしてください。

（↓各行頭に全角のスペースが入っています。コピーする際はご注意ください）

　//最初の１度だけ、初期設定を行う
　onClipEvent(load)
　{
　　//最大音量
　　max_vol = 100;

　　//親のタイムラインの音を制御するSoundオブジェクトの作成と
　　//音量の初期化
　　snd = new Sound( _parent );
　　snd.setVolume( max_vol );

　　//”ON”のフレームを表示
　　gotoAndStop( 2 );
　}

　//クリック時の処理
　on(release)
　{
　　//新しく設定する音量を決める
　　new_vol = max_vol - snd.getVolume();

　　//音量を設定
　　snd.setVolume( new_vol );

　　//ON/OFFに応じたフレームを表示
　　gotoAndStop( new_vol / max_vol + 1 );
　}

＃１では、current_vol という変数に getVolume メソッドで取得した音量を入れ、これを max_vol から減算することで、0 と max_vol の値を交互に取得していました。
今回は getVolume から取得する部分を直接演算の式に組み込み、設定する音量を new_vol という変数に入れています。
つまり、new_vol には＃１の max_vol - current_vol と同じ結果が入りますので、値は 0 または max_vol のどちらかになります。
この点を利用して、ムービークリップの表示フレームを決めます。

ON / OFF ボタンとして使うムービークリップのフレームは２つで、OFF の時の絵がフレーム１に描かれています。
new_vol は OFF の時に 0 、ON の時に max_vol の値になりますから、これを max_vol で除算します。
すると、答えは 0 か 1 のどちらか（ OFF の時に 0 、ON の時に 1 ）になります。
こうして求めた値に 1 を加算すると、if 文で判断しなくても ON / OFF の状況に応じたフレームの番号を求めることができます。

絵が変わるボタンとはつまり、ON / OFF の状況に応じてフレームを切り替えればいいだけの話です。
計算式やフレームの構成が思いつかない時は、if 文で

　//ON/OFFに応じたフレームを表示
　if( new_vol == 0 )
　{
　　gotoAndStop( 1 );
　}
　else
　{
　　gotoAndStop( 2 );
　}

と書いても同じです。
if 文ならフレームの番号でなくてもいいので、フレームラベルを利用すると分かりやすくなると思います。

お礼

できましたーーー（涙）！！
DPE様、このたびはとっても詳しい、しかも初心者の私にもわかるように
教えてくださり、本当に本当にありがとうございました。
何と感謝申し上げていいのかわからないくらい感激しております。
本当にありがとうございました！
心からお礼申し上げます。

回答No.1

DPE

同期をとる鳴らし方（ストリーミング再生）では、各フレームのデータの中にそのフレームで鳴らすべき音のデータが書き込まれ、フレームが再生されるたびに音の再生処理も一緒に行われます。
そのため、いわゆる” OFF にする＝音を止める”という考え方では難しくなります。

ストリーミング再生において音の ON / OFF を切り替えるとは要するに、ON の時に音量を最大に、OFF の時に最小＝ 0 にすればいいわけです。
OFF ＝停止ボタンではなく、テレビなどにあるミュート（消音）ボタンの発想ですね。
ストリーミング再生の音をスクリプトで停止させるのは難しいのですが、音量を絞って音が聞こえないようにするのなら、音量を制御するスクリプトで簡単にできます。

--------------------------------------------------------------

お使いの Flash のバージョンが書かれていませんので、とりあえず、ActionScript 1.0 の作例をご紹介します。
Flash CS3 をお使いの場合は、「パブリッシュ設定」で ActionScript のバージョンを 1.0 または 2.0 に設定してください。

音の OFF ボタンもしくは ON / OFF ボタンを、”ボタンシンボル”として作成してください。
レイヤーを１つ追加し、最初のフレームにこのボタンを配置します。
ボタンのレイヤーは、最初のフレームだけがキーフレーム（ボタンが配置されている状態）、残りはキーフレームと同様の内容を繰り返すフレームにして、ボタンを最後までステージに存在させるようにします。
もう１つ、レイヤーを追加してください。このレイヤーにはスクリプトを書きます。

以上で準備は完了です。
次はスクリプトを書きます。

****************************

スクリプトは、フレームとボタン（のインスタンス）の、両方に書きます。
フレームのスクリプトは、最初のフレームに記述してください。

（↓各行頭に全角のスペースが入っています。コピーする際は、全て半角のスペースかタブに置き換えてください。このまま使うとシンタックスエラーになります）

　●フレームに書くスクリプト

　　//最初の１度だけ、初期設定を行う
　　if( snd == undefined )
　　{
　　　//最大音量
　　　max_vol = 100;

　　　//このタイムラインの音を制御するSoundオブジェクトの作成と
　　　//音量の初期化
　　　snd = new Sound( this );
　　　snd.setVolume( max_vol );
　　};

　●ボタンのインスタンスに書くスクリプト

　　on(release)
　　{
　　　//音量を絞る
　　　snd.setVolume( 0 );
　　}

↑単純に OFF にするボタンなら、クリックした時に音量を 0 にするだけで済みます。
押すたびに ON / OFF を切り替えるボタンにするには、次のようなスクリプトに変更してみてください。

　　on(release)
　　{
　　　//現在の音量を取得
　　　current_vol = snd.getVolume();

　　　//音量を設定
　　　snd.setVolume( max_vol - current_vol );
　　}

getVolume は、音量を設定する setVolume の対になるもので、現在設定されている音量を取得する命令（メソッドといいます）です。
最初の状態ですと、変数 max_vol （最大音量）の値が返ってきます。
返ってきた値を変数 max_vol から減算し、この結果を setVolume で設定することで、音量に 0 と max_vol を交互に指定することができます。

ActionScript で扱える音量の最大値は 100 です。
音量が大きすぎる時は、max_vol に 100 より小さい値を設定して調整してください。

今回は、シーンをまたいで曲が鳴っている・ ON と OFF の時でボタンの絵を切り替える・・・などの事情は考慮していません。
絵が切り替わるボタンは、ボタンシンボルではなくムービークリップシンボルとして作ると簡単ですが、この場合は Sound オブジェクトや変数のターゲットパスに注意が必要です。
機会がありましたら、改良してみてください。

補足

とっても詳しい解説をいただき、本当にありがとうございます！！
教えていただいた方法で早速やってみました。
わかりやすい解説をいただいたお陰で、OFFにするボタン、ならびに
ONとOFFを繰り返すボタンを作ることができました。
大変感激しています。本当にありがとうございます。

ここで、いざ作ってみると、ONとOFFの時でボタンの絵を切り替えるように作ってみたいと思うのですが・・・、
Soundオブジェクトや変数のターゲットパスに注意と教えていただいたにも関わらず
やってみましたがうまくできません・・・。
何度もお手数なのですが、このときにONとOFFとでボタンの絵を切り替える方法を教えていただいてもよろしいでしょうか？？
甘えてばかりですみません！
どうかよろしくお願いいたします！！