エクセルで出力時にページ数を表示させる方法

質問

エクセルで1シートに1ページ分ずつのデータがあり、それを出力する時に「△/○ページ」と言うように表示させたいと思っています。

ヘッダーかフッターに「＆[ページ番号]/＆[総ページ数]ページ」と入力し、出力したいシート名を全て選択し、
連続印刷（？というのでしょうか）すればできる方法は知っています。
この「シート名を全て選択して連続印刷」という手順を踏まずにできる方法が知りたいです。
例えば後である1ページだけを出力しても、正しく分母と分子が表示されるようにしたいのです。
分母となる総ページ数はその時によってまちまちで、作られたシート数＝総ページ数になってほしいです。

実際にデータ入力を行い、出力をする者のパソコンスキルにかなりの個人差があり、出力方法を統一するのが困難な状況です。
ですから、フォーマットを渡す時点でこれらができる状態にしておきたいです。

これは無理な話なのでしょうか？

どなたかよろしくお願いします。

回答No.6

merlionXX · ベストアンサー

nknnnkさん、こんにちは。merlionXXです。

> ロックされていないセルに全く入力されていない状態でプレビューを表示

なるほど・・・
それはまったく想定外でした。他人のためにコードを書くということはそういう想定外の事態に耐え得るものにしなければいけないということですね。
nknnnkさんのおかげでわたしも大いに勉強になりました。

ということで、これではいかがでしょう？

Private Sub Workbook_BeforePrint(Cancel As Boolean)
Dim ar() As Variant
Dim s As Worksheet
Dim Rng As Range, c As Range
Dim i As Integer, n As Integer

For Each s In Worksheets
On Error Resume Next
Set Rng = s.Cells.SpecialCells(xlCellTypeConstants, 3)
On Error GoTo 0
If Not Rng Is Nothing Then
For Each c In Rng
If c.Locked = False Then
ReDim Preserve ar(i)
ar(i) = s.Name
i = i + 1
Exit For
End If
Next c
End If
Set Rng = Nothing
Next s

If i > 0 Then
For n = LBound(ar) To UBound(ar)
Sheets(ar(n)).PageSetup.CenterFooter = n + 1 & "/" & UBound(ar) + 1
Next
Else
MsgBox "すみません・・・・" _
& vbCr & "" _
& vbCr & "番号ふるシートが見つからないんですぅ。", , " 。o゜o(´□｀*)o゜o゜о"
End If
End Sub

お礼

すばらしいです！！！
こんなこともできちゃうんですね！！！

この書類は会社で使うものですが、うちは30人くらいしかいない小さな会社なので、
これくらい愛嬌があった方がみんなうれしいと思います。

merlionXXさん、本当にありがとうございました。
いろいろと考えてくださり、とても感謝しています。

また新たな疑問が生まれたら、こちらでお世話になるかもしれませんが、どうか懲りずによろしくお願いします。

回答No.5

merlionXX

Σ（￣ロ￣lll)　失敗！
ごめんなさい。下のコード、上から４行目の修正です。
Dim c As Rangeとなってますが、
Dim Rng As Range, c As Range
に変えてください。

お礼

ありがとうございます！！今やっと完成しました！！感激です！！

念のため確認なんですが、教えていただいたコードを入力し、ロックされていないセルに全く入力されていない状態でプレビューを表示しようとすると

実行時エラー'92':
For ループが初期化されていません。

というメッセージが出ました。（メッセージの「終了」を選択すると、プレビュー画面は表示されます）
それでしばらく試行錯誤していたのですが、いくつかのシートのロックされていないセルに数値を入力したところ、
プレビュー画面がエラーなしで表示され、その上きちんと「○/入力されているシート総数」となっていました。

このメッセージの意味を少し調べたけどよくわからなかったのですが、
そもそも「入力されているシート」をカウントさせているのに、それが1枚もなければ、プレビューでページ数表示のしようがないですよね。
だからだったのだろうと理解したのですが、これはだいたい合っていますか？

現段階でもともとの質問+αの回答を得られているので、
「私の理解が間違っていて、教えていただいたコードを変更しないと不具合が生じる」ということがなければ、
私としてはこのままで十分です。

とても助かりました！本当にありがとうございました！！

回答No.4

merlionXX

nknnnkさん、おはようございます。
条件付きでのページ番号付与ＶＢＡのサンプル、簡単なものを一つ作成してみました。
・・・といってもちょっと梃子摺りましたよ (*´∇｀*)

各ページのロックされていないセルの一つにでも入力があれば、そのページをカウントしてページ番号を振ります。合計ページ数はカウントされるページの合計数です。

Private Sub Workbook_BeforePrint(Cancel As Boolean)
Dim ar() As Variant
Dim s As Worksheet
Dim c As Range
Dim i As Integer, n As Integer

For Each s In Worksheets
On Error GoTo line
Set Rng = s.Cells(1, 1).SpecialCells(xlCellTypeConstants, 3)
For Each c In Rng
If c.Locked = False Then
ReDim Preserve ar(i)
ar(i) = s.Name
i = i + 1
Exit For
End If
Next c
Set Rng = Nothing
line:
Next s

For n = LBound(ar) To UBound(ar)
Sheets(ar(n)).PageSetup.CenterFooter = n + 1 & "/" & UBound(ar) + 1
Next
End Sub

回答No.3

merlionXX

> 1)現在、フッターにページ数を表示する式（？コードなんでしょうか？）を入れてあるのですが、これは消した方がいいのでしょうか？

中央のフッターであれば、このマクロを実行すれば消えますから別に消さなくともOKです。

> (2)最初の質問の時点で、詳しく説明していなかったのですが～

これって、説明が足らないなんてレベルじゃないですね。
すべてのシートに一律同じ操作をするのと、個別のシートに個別の条件で操作するのではまったく異なった要求ですよ。
やろうと思えば出来なくはないですが、それだけでは上方不足です。
カウントしない条件として、たとえば、「各シートA1セルが空白だったら」とか「各シートのロックされていないセルのすべてに入力がなかった場合」とか、該当するシートを他のシートと判別できるキーがないとマクロの書き様がないとは思いませんか？

> (3)以前他の方の質問から同じようなコードをコピーして使ったのですが、　メールに添付して送ったところ、メールを受け取った者のパソコンでは同じように機能しません～

マクロの設定が「高」とか「低」というのが問題のようだったとわかっているのであれば、これもマクロですから同じですよ。先方に、マクロを有効にして開くように言ってください。
マクロで先方のセキュリティーレベルをいじることはできません。というか、それをやる「マクロウィルス」を防ぐためにセキュリティが設定されているのです。

お礼

迅速な回答、ありがとうございます。
そして、説明不足等、大変申し訳ありません。
今まで使っていた会社の書類を、現在順番に使いやすく作り直しているところで、
最初にご回答いただいた方法でできあがる書類もあり、「これができるなら・・・」とつい甘えてしまいました。
merlionXXさんの回答（どういう条件か、など）を参考にさせていただき、もう一度新しく質問を投稿します。

マクロについても全く知識がなく、セキュリティレベルもよくわからなくてとりあえず「中」にしてました。
また、受け取った者（こちらもマクロの知識がない）が今日はお休みしているので、
最初に開いたときにどんなエラーメッセージが出たのかはきちんと把握していません。
もう一度こちらも確認してから新規の質問として投稿します。

せっかくご回答下さったのに、二度手間のようになってしまってすいません。
色々教えていただき、ありがとうございました。

回答No.2

merlionXX

#2のmerlionXXです。

先ほど、自分で書きながらまだ改良の余地があるなあと思い、考えたところ、もっと簡単なコードで実現できました。

Private Sub Workbook_BeforePrint(Cancel As Boolean)
Dim a As Integer, b As Integer
a = ThisWorkbook.Worksheets.Count
b = ActiveSheet.Index
ActiveSheet.PageSetup.CenterFooter = b & "/" & a
End Sub

お礼

できました！！ありがとうございます！助かりました！

私はVBAが全くわからなくて、今回も手順の通りに入力しただけなのですが、もしよければ関連して3つほどさらに教えて欲しいです。

(1)現在、フッターにページ数を表示する式（？コードなんでしょうか？）を入れてあるのですが、これは消した方がいいのでしょうか？

(2)最初の質問の時点で、詳しく説明していなかったのですが、
　現在全部で10シートあり、全てに表は作られていて、計算式にはロックがかけてあるので、入力できる範囲は限られています。
　その内5シートのみに入力されていた場合、分母を「△/10ページ」ではなく、「△/5ページ」と表示するのは無理でしょうか？
　シートは存在しても、ある決められた範囲に数値などが入力されていないシートはカウントから外したいのです。
　これができるとベストです。

(3)以前他の方の質問から同じようなコードをコピーして使ったのですが、
　メールに添付して送ったところ、メールを受け取った者のパソコンでは同じように機能しませんでした。
　マクロの設定が「高」とか「低」というのが問題のようだったのですが、解決方法がわかりませんでした。
　このコードも同じようになってしまいませんか？
　それを解決するために必要な作業があれば教えてください。
　ちなみに以前コピーしたのは、シートの内容を変更した時だけ更新日が更新されるようにするコードでした。

以上です。
よろしくお願いします。

回答No.1

merlionXX

VBAを使えば可能でしょうね。
BOOKを開いたら、以下の手順でやってみてください。

1.Alt+F11キーでVisualBasicEditorを呼び出します。

2.左側のプロジェクトウィンドウの中のVBAProject(ブック名)をクリック

3.シート名の下にあるThisWorkbookをクリックし、出てきたコードウィンド（右側の白い広い部分）に以下のコードをコピペします。

Private Sub Workbook_BeforePrint(Cancel As Boolean)
Dim a As Integer, b As Integer, n As Integer
a = ThisWorkbook.Worksheets.Count
For n = 1 To a
If Worksheets(n).Name = ActiveSheet.Name Then b = n
Next
ActiveSheet.PageSetup.CenterFooter = b & "/" & a
End Sub

4.Alt+F11キーでワークシートへもどります。