乱数で・・・

質問

ラベル１０枚に１～１０までを乱数を入れたいのです
ただしダブらない

どうすればいいのでしょうか?？

自分で考えたのですがバグがあります

※コマンドをクリック
※クローンは用意済み

Private Sub Command1_Click()
Dim a(0 To 9)

For i = 0 To 9

a(i) = Int(Rnd * 10)+1

　For b = 0 To 9
　　If a(i) = a(b) Then

　　　　If i <> b Then

　　　　a(i) = Int(Rnd * 10) + 1

　　　　End If

　　End If

　　Next b

Next i

For c = 0 To 9

Label1(c).Caption = a(c)

Next c

End Sub

バグの原因はなんとなくわかるのですがどうすればいいのか分かりません

素人ですいません。

回答No.4

nishi6 · ベストアンサー

質問にあるコードを余り変えずに修正してみました。
質問では、既に発生させた乱数と照合してますが、一致しない乱数になるまで再度、乱数を発生させる必要があります。

Dim a(0 To 9) As Integer

Private Sub Command1_Click()
　　Dim i As Integer, b As Integer, c As Integer

　　Randomize

　　For i = 0 To 9
　　　　a(i) = Int(Rnd * 10) + 1
　　　　While RndCheck(a(i), i - 1) = False
　　　　　　a(i) = Int(Rnd * 10) + 1 '再度乱数を発生させる
　　　　Wend
　　Next i

　　For c = 0 To 9
　　　　Label1(c).Caption = a(c)
　　Next c
End Sub

'既に発生させた乱数と照合して、一致するものがあれば『False』
Function RndCheck(Ransu As Integer, idx As Integer)
　　Dim j As Integer 'カウンタ

　　RndCheck = True
　　For j = 0 To idx
　　　　If a(j) = Ransu Then
　　　　　　RndCheck = False
　　　　　　Exit For
　　　　End If
　　Next
End Function

異なるアルゴリズムで書いてみました。
乱数発生時に重複しない数値が出せます。既に発生させた乱数に対応するインデックスを次の乱数ででないようにしています。乱数の発生は10回で済みます。ご参考に。

Private Sub Command2_Click()
　　Const num = 10
　　Dim rc As Integer '乱数
　　Dim c As Integer 'カウンタ
　　Dim r(10) As Integer, idx(10) As Integer '乱数とそのインデックス

　　Randomize
　　For c = 1 To num
　　　　r(c) = c
　　　　idx(c) = c
　　Next

　　For c = 1 To num
　　　　'既に発生させた乱数は発生させないようにする。Rndに掛ける数値を小さくしていく
　　　　rc = Int(Rnd * (num - c + 1)) + 1
　　　　'間接的に数値を決定する
　　　　Label1(c - 1).Caption = r(idx(rc))
　　　　'今発生させた乱数に対するidxを計算対象の最後のidxに書き換える
　　　　idx(rc) = idx(num - c + 1)
　　Next
End Sub

お礼

いろんな考え方があるのですね・・・
回答　ありがとうございます

回答No.5

sorarisp

レスポンスを考えないのであれば

　　　　If i <> b Then

　　　　a(i) = Int(Rnd * 10) + 1
　　　　b = 0　　　　　　　　　　　　←この行でbを初期化する。

　　　　End If

でOKだと思います。

お礼

回答　ありがとうございます

回答No.3

sha-girl

ランダム数値を10個発生させ、
大小比較で決定していくのでどうでしょうか？
サンプルとして１～１０の数値をランダムにだぶらないように表示していくプログラムです。

Private Sub Command1_Click()
Dim d(10, 2) As Double
Dim wk(2) As Double
Dim i%, ii%
For i = 0 To 9
d(i, 0) = i + 1
d(i, 1) = Rnd
Next i
For i = 0 To 9
For ii = i To 9
If d(i, 1) < d(ii, 1) Then
wk(0) = d(i, 0)
wk(1) = d(i, 1)
d(i, 0) = d(ii, 0)
d(i, 1) = d(ii, 1)
d(ii, 0) = wk(0)
d(ii, 1) = wk(1)
End If
Next ii
Next i
For i = 0 To 9
MsgBox (d(i, 0))
Next i
End Sub

お礼

回答　ありがとうございます

回答No.2

yuizuian

どういったバグなのか書いておいて欲しかったです。

やり方としては、
１．1～10までの数値を取得
２．結果を配列に格納
３．1～10までの数値を取得
４．以前に出た結果でなければ配列に格納
５．３と４の繰り返し
で良いかな…と。
以前に出ているかどうかは結果を格納している配列を調べればわかります。

ところで、kennta111さんのソースでは、
毎回同じ数字がでませんか？
最初のa(i) = Int(Rnd * 10)+1 の前ででも
Randomizeして乱数を初期化しておかないと。

それから、
Int(Rnd * 10) + 1
ではなくて
Int((Rnd * 10) + 1 )
かなぁ、と。

お礼

すいません　書くの忘れていました
回答　ありがとうございます

回答No.1

ceita

方針としては、
1～10までのカード（配列）をつくって、
カードをシャッフル（ランダムに入れ替える）と
いうのがよくとられるようですよ。

お礼

回答　ありがとうございます