ShellでEXCEL2002を起動する場合

質問

VB6のコーディングで、Shell関数を使用してEXCELを起動しているのですが、EXCEL2002では、他のバージョンと表示方法が変わってしまいました。

コーディングは
Shell(PATHつきのEXCEL.EXE, vbMinimizedFocus)
としているのですが、
EXCEL2000までは、正常にアイコン化されたEXCELが起動できていたのに、EXCEL2002からは最後に使用した大きさ（最大化した状態でEXCEL2002を終了していたら最大化、アイコン化した状態で終了していたらアイコン化）で起動されてしまいます。
また、EXCEL2000までは表示されなかったロゴマーク？も表示されてしまいます。

ちなみにWORD2002はアイコン化して起動可能でした。
（但し、こちらもロゴマークは表示されます。）

動作として、ひっそりとEXCELを起動してマクロを使用した帳票を出力する。
としたいのですが、なにかいい方法がありましたら教えてください。
（ShellExeCuteもうまく動作しませんでした。）

回答No.5

TAGOSAKU7 · ベストアンサー

解決したのでしょうか？
それとも反則技で怒ったのでしょうか？

もし別方法で解決したのであれば教えてください。
今後の参考にしたいです。。。m(__)m

お礼

お返事送れてすみません。(^^;)
解決しました。

こんな方法があるとは...
反則技なんてとんでもない、いい方法を教わりました。
ありがとうございました。
今後ともよろしくお願いします。m(__)m

回答No.4

TAGOSAKU7

そーですかー。Shellのオプションを受け入れてくれませんかー。。。

おそらく、Windowsから送られてくるメッセージをSpyで見てみたら、正確な方法がわかるのでしょうが・・・環境がないと実験ができないので、原因追求をしたくてもできないのです。。。

なので、こちらの方でも唯一可能な方法で作成しました。
もろ反則技です。

処理内容
１．ピクチャボックスを創生
２．ピクチャボックスの親ハンドルをデスクトップに変更
３．ピクチャボックスのサイズを画面サイズに変更し、最前面固定
４．デスクトップの状態をピクチャボックスに描画
５．ピクチャボックスを表示
６．エクセルを起動
７．エクセルを最小化
８．ピクチャボックスの破棄

ねっ反則でしょ？（笑）

関数creDmyPicで１～５の処理を行っています。
関数openExcelで６～７の処理を行っています。

ちなみに・・・
この方法は、どうしても見せたくない処理があるけど、いちいち制御するのが面倒な時に使ってます。

これがダメなら・・・すいません・・・回答不能です。。。

Option Explicit
Private Const HWND_TOPMOST = (-1)
Private Type RECT
　　Left As Long
　　Top As Long
　　Right As Long
　　Bottom As Long
End Type

Private Declare Function SetForegroundWindow Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function StretchBlt Lib "gdi32" (ByVal hdc As Long, ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hSrcDC As Long, ByVal xSrc As Long, ByVal ySrc As Long, ByVal nSrcWidth As Long, ByVal nSrcHeight As Long, ByVal dwRop As Long) As Long
Private Declare Function GetDC Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function GetDesktopWindow Lib "user32" () As Long
Private Declare Function GetWindowRect Lib "user32" (ByVal hwnd As Long, lpRect As RECT) As Long
Private Declare Function SetParent Lib "user32" (ByVal hWndChild As Long, ByVal hWndNewParent As Long) As Long
Private Declare Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal x As Long, ByVal y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long

Private Sub Command1_Click()
　　Dim dmyPic　As PictureBox

　　'ピクチャボックスを作成して、一時画面描画を視覚的にとまったように見せる
　　Set dmyPic = creDmyPic("picDammy")
　　If dmyPic Is Nothing Then
　　　　Call MsgBox("ダミー作成失敗")
　　End If

　　'エクセルブックのオープン
　　Call openExcel("c:\test.xls")

　　'アクティブウィンドウを自分自身に設定
　　Call SetForegroundWindow(Me.hwnd)

　　'ピクチャボックスウィンドウの破棄
　　Controls.Remove dmyPic
End Sub

'【機　能】エクセルを最小化で起動する
'【引　数】エクセルブックのフルパス
'【注意点】エラーチェックを使用してない
Private Sub openExcel(inOpenXlsBookPath As String)
　　Dim xlApp　 As Excel.Application

　　'エクセル起動
　　Call Shell("C:\Program Files\Microsoft Office\Office\EXCEL.exe /e")
　　Set xlApp = GetObject("", "Excel.Application")

　　'エクセル最小化
　　xlApp.WindowState = xlMinimized

　　'ワークブックオープン
　　xlApp.Workbooks.Open inOpenXlsBookPath

　　'開放
　　xlApp.Visible = True
　　Set xlApp = Nothing
End Sub

'【機　能】ピクチャボックスを創生して、現在のデスクトップ状態を描画し、最前面で表示を行う
'【引　数】創生するピクチャボックスの名称（任意）
'【注意点】パラメータには既存のピクチャボックスと重複しない名称を使用すること
Private Function creDmyPic(inPicBoxName As String) As PictureBox
　　Dim picWork　　　　 As PictureBox　 'ピクチャボックスオブジェクト
　　Dim lngDeskTopWnd　 As Long　　　　 'ハンドル(デスクトップ)
　　Dim rcDeskTop　　　 As RECT　　　　 '領域座標(デスクトップ)
　　Dim lngDeskTopDC　　As Long　　　　 'デバイスコンテキスト(デスクトップ)

　　'左位置/上位置/幅/高
　　Dim lngL As Long, lngT As Long, lngW As Long, lngH As Long

　　'失敗したら終了
　　On Error GoTo PGMEND

　　'ピクチャボックスを作成
　　Set picWork = Controls.Add("VB.PictureBox", inPicBoxName)

　　'ピクチャボックスの初期設定
　　With picWork
　　　　.Appearance = 0
　　　　.AutoRedraw = True
　　　　.AutoSize = False
　　　　.BorderStyle = 0
　　End With

　　'デスクトップのハンドルを取得
　　lngDeskTopWnd = GetDesktopWindow
　　'デスクトップ領域の座標を取得
　　Call GetWindowRect(lngDeskTopWnd, rcDeskTop)
　　'デスクトップのデバイスコンテキストを取得
　　lngDeskTopDC = GetDC(lngDeskTopWnd)

　　'左位置/上位置/幅/高を取得
　　With rcDeskTop
　　　　lngL = .Left: lngT = .Top: lngW = .Right - .Left: lngH = .Bottom - .Top
　　End With

　　With picWork
　　　　'親ハンドルの変更（ピクチャボックスをフォームから飛び出させる）
　　　　Call SetParent(.hwnd, lngDeskTopWnd)

　　　　'デスクトップの領域にピクチャボックスのサイズをあわし、画面Zオーダーを最前面固定にする
　　　　Debug.Print SetWindowPos(.hwnd, HWND_TOPMOST, lngL, lngT, lngW, lngH, 0)

　　　　'描画実行
　　　　Call StretchBlt(.hdc, lngL, lngT, lngW, lngH, lngDeskTopDC, lngL, lngT, lngW, lngH, vbSrcCopy)

　　　　'ピクチャボックスの表示
　　　　.Visible = True
　　End With

　　'ピクチャボックスオブジェクトを返す
　　Set creDmyPic = picWork
PGMEND:
End Function

回答No.3

TAGOSAKU7

ShellでvbMinimizedFocusなどが無効なのですよね？
もしかしたら、vbHideも無効なのかな？

さっきのは [Set xlApp = New Excel.Application] で起動してましたが、今度は[Shell]で起動して、[GetObjectでxlAppをセット]してます。これでもダメですか？
こちらに環境がないので、すいませんがそちらでテストしてください。
できたら、結果報告もお願いします。

Private Sub Command1_Click()
　　Dim xlApp　 As Excel.Application

　　Call Shell("C:\Program Files\Microsoft Office\Office\EXCEL.exe", vbHide)

　　Set xlApp = GetObject("", "Excel.Application")
　　xlApp.Workbooks.Add

　　xlApp.WindowState = xlMinimized

　　xlApp.Visible = True
　　Set xlApp = Nothing
End Sub

お礼

結果報告です。無理でした（T_T)
shellのウィンドウスタイルの指定がまったく無視されるみたいです。
APIで色々試してみます。

回答No.2

TAGOSAKU7

ツールバーから
[プロジェクト]の[参照設定]より
Microsoft Excel x.x Object Library
をチェック入れて使用してください。
x.xの部分は、環境によって違います。

Private Sub Command1_Click()
　　Dim xlApp　 As Excel.Application

　　'Ecxel起動
　　Set xlApp = New Excel.Application
　　xlApp.Workbooks.Open "C:\TEST.xls"

　　'Ecxel最小化
　　xlApp.WindowState = xlMinimized

　　'表示する
　　xlApp.Visible = True

　　'Ecxel開放
　　Set xlApp = Nothing
End Sub

お礼

ありがとうございます。見事にアイコン化されました。
ただ、Shellでなくても構いませんといったのに申し訳ございませんが、
EXCEL2000とEXCEL2002を両方インストールした端末で、バージョンを指定して起動する必要があったので、やはりできればファイル名を指定できるShellの方を使用できればと思います。
（バージョンの指定とは単純にインストールしているフォルダの指定です。）
この回答は、参考になりました、ありがとうございました。

回答No.1

TAGOSAKU7

EXCEL2002は未経験ですが・・・
Ｓｈｅｌｌのオプション値がうまく動作しないのですね？

Ｓｈｅｌｌじゃなきゃダメですか？
Excel2000しか手元にないので、動作環境は保証できませんが、別方法なら何とか最小化で起動できると思いますよ。

補足

Shellでなくても構いません。
ちなみにロゴマーク（起動画面）の問題は、起動スイッチ(/e)で解決しました。